-
Notifications
You must be signed in to change notification settings - Fork 1
/
build.gradle
136 lines (117 loc) · 5.18 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
plugins {
id 'de.undercouch.download' version '4.1.1'
id 'maven-publish'
}
import de.undercouch.gradle.tasks.download.Download
group 'com.jetbrains.jdk'
def supportedPlatforms = ['osx', 'windows', 'linux']
def distroTypes = ['jbr_jcef', 'jbr', 'jbrsdk']
for (platform in supportedPlatforms) {
def capitalizedPlatform = platform.capitalize()
for (distroType in distroTypes) {
def capitalizedDistroType = distroType.capitalize()
def supportedArchitectures = supportedArch(platform, distroType)
for (platformClassifier in supportedArchitectures) {
def downloadTask = tasks.create(name: downloadTaskName(capitalizedDistroType, capitalizedPlatform, platformClassifier), type: Download) {
def fileName = "${distroType}-${jdk_version}-${platformClassifier}-${jdk_build}.tar.gz"
logger.warn("https://cache-redirector.jetbrains.com/intellij-jbr/$fileName")
src "https://cache-redirector.jetbrains.com/intellij-jbr/$fileName"
//src "https://cache-redirector.jetbrains.com/intellij-jbr/$fileName"
dest "$buildDir/$fileName"
overwrite false
}
}
}
}
publishing {
for(distroType in distroTypes) {
publications.create(distroType, MavenPublication) {
for(platform in supportedPlatforms) {
for(platformClassifier in supportedArch(platform, distroType)) {
def downloadTask = tasks.getByName(downloadTaskName(distroType.capitalize(),platform.capitalize(), platformClassifier))
artifact(downloadTask.dest) {
classifier platformClassifier
builtBy downloadTask
extension 'tgz'
}
}
}
artifactId distroType
version "${jdk_version}-${jdk_build}"
pom {
licenses {
// official SPDX identifier
// see https://spdx.org/licenses/ for list
license {
name = "GPL-2.0-only"
url = "https://github.com/JetBrains/JetBrainsRuntime/blob/jb${jdk_version}-${jdk_build}/LICENSE"
comments = "GNU GENERAL PUBLIC LICENSE Version 2, June 1991"
distribution = "repo"
}
license {
name = "WITH Classpath-exception-2.0"
url = "https://github.com/JetBrains/JetBrainsRuntime/blob/jb${jdk_version}-${jdk_build}/ADDITIONAL_LICENSE_INFO"
comments = "Oracle Classpath exception 2.0"
distribution = "repo"
}
license {
name = "WITH OpenJDK-assembly-exception-1.0"
url = "https://github.com/JetBrains/JetBrainsRuntime/blob/jb${jdk_version}-${jdk_build}/ASSEMBLY_EXCEPTION"
comments = "OpenJDK Assembly exception 1.0"
distribution = "repo"
}
}
organization {
name = "JetBrains s.r.o"
url = "https://www.jetbrains.com"
}
scm {
tag = "jb${jdk_version}-${jdk_build}"
url = "https://github.com/JetBrains/JetBrainsRuntime.git"
}
}
}
}
}
private String downloadTaskName(capitalizedDistroType, capitalizedPlatform, platformClassifier) {
'get' + capitalizedDistroType + capitalizedPlatform + platformClassifier
}
private List<String> supportedArch(platform, distroType) {
if(platform == 'osx')
{
return ["${platform}-x64", "${platform}-aarch64"]
} else if (platform == 'windows') {
return ["${platform}-x64"]
} else if (platform == 'linux') {
return ["${platform}-x64", "${platform}-aarch64"]
}
throw new GradleException("unsupported platform")
}
publishing {
repositories {
repositories {
maven {
name = "itemisCloud"
url = project.version.contains("SNAPSHOT")
? uri("https://artifacts.itemis.cloud/repository/maven-mps-snapshots/")
: uri("https://artifacts.itemis.cloud/repository/maven-mps-releases/")
if (project.hasProperty("artifacts.itemis.cloud.user") && project.hasProperty("artifacts.itemis.cloud.pw")) {
credentials {
username = project.findProperty("artifacts.itemis.cloud.user")
password = project.findProperty("artifacts.itemis.cloud.pw")
}
}
}
maven {
name = "GitHubPackages"
url = uri("https://maven.pkg.github.com/mbeddr/build.publish.jdk")
if(project.hasProperty("gpr.token")) {
credentials {
username = project.findProperty("gpr.user")
password = project.findProperty("gpr.token")
}
}
}
}
}
}