-
Notifications
You must be signed in to change notification settings - Fork 123
/
transitivegroups.jl
223 lines (178 loc) · 5.99 KB
/
transitivegroups.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
"""
has_number_of_transitive_groups(deg::Int)
Return whether the number transitive groups groups of degree `deg` are available for
use via `number_of_transitive_groups`.
# Examples
```jldoctest
julia> has_number_of_transitive_groups(30)
true
julia> has_number_of_transitive_groups(64)
false
```
"""
has_number_of_transitive_groups(deg::Int) = has_transitive_groups(deg)
"""
has_transitive_group_identification(deg::Int)
Return whether identification of transitive groups groups of degree `deg` is available
via `transitive_group_identification`.
# Examples
```jldoctest
julia> has_transitive_group_identification(30)
true
julia> has_transitive_group_identification(64)
false
```
"""
has_transitive_group_identification(deg::Int) = has_transitive_groups(deg)
"""
has_transitive_groups(deg::Int)
Return whether the transitive groups groups of degree `deg` are available for
use. This function should be used to test for the scope of the library
available.
# Examples
```jldoctest
julia> has_transitive_groups(30)
true
julia> has_transitive_groups(64)
false
```
"""
function has_transitive_groups(deg::Int)
@req deg >= 1 "degree must be positive, not $deg"
return deg == 1 || GAP.Globals.TransitiveGroupsAvailable(deg)::Bool
end
"""
number_of_transitive_groups(deg::Int)
Return the number of transitive groups of degree `deg`,
up to permutation isomorphism.
# Examples
```jldoctest
julia> number_of_transitive_groups(30)
5712
julia> number_of_transitive_groups(64)
ERROR: ArgumentError: the number of transitive groups of degree 64 is not available
```
"""
function number_of_transitive_groups(deg::Int)
@req has_number_of_transitive_groups(deg) "the number of transitive groups of degree $(deg) is not available"
return GAP.Globals.NrTransitiveGroups(deg)::Int
end
"""
transitive_group(deg::Int, i::Int)
Return the `i`-th group in the catalogue of transitive groups over the set
`{1, ..., deg}` in GAP's Transitive Groups Library.
The output is a group of type `PermGroup`.
# Examples
```jldoctest
julia> transitive_group(5,4)
Alt(5)
julia> transitive_group(5,6)
ERROR: ArgumentError: there are only 5 transitive groups of degree 5, not 6
```
"""
function transitive_group(deg::Int, i::Int)
@req has_transitive_groups(deg) "transitive groups of degree $deg are not available"
N = number_of_transitive_groups(deg)
@req i <= N "there are only $N transitive groups of degree $deg, not $i"
return PermGroup(GAP.Globals.TransitiveGroup(deg,i), deg)
end
"""
transitive_group_identification(G::PermGroup)
Return a pair `(d,n)` such that `G` is permutation isomorphic with
`transitive_group(d,n)`, where `G` acts transitively on `d` points.
If `G` is not transitive on its moved points, or if the transitive groups of
degree `d` are not available, an exception is thrown.
# Examples
```jldoctest
julia> G = symmetric_group(7); m = transitive_group_identification(G)
(7, 7)
julia> order(transitive_group(m...)) == order(G)
true
julia> S = sub(G, [perm([1, 3, 4, 5, 2])])[1]
Permutation group of degree 7
julia> is_transitive(S)
false
julia> is_transitive(S, moved_points(S))
true
julia> m = transitive_group_identification(S)
(4, 1)
julia> order(transitive_group(m...)) == order(S)
true
julia> transitive_group_identification(symmetric_group(64))
ERROR: ArgumentError: identification of transitive groups of degree 64 are not available
julia> S = sub(G, [perm([1,3,4,5,2,7,6])])[1];
julia> transitive_group_identification(S)
ERROR: ArgumentError: group is not transitive on its moved points
```
"""
function transitive_group_identification(G::PermGroup)
moved = moved_points(G)
@req is_transitive(G, moved) "group is not transitive on its moved points"
deg = length(moved)
@req has_transitive_groups(deg) "identification of transitive groups of degree $(deg) are not available"
res = GAP.Globals.TransitiveIdentification(G.X)::Int
return deg, res
end
"""
all_transitive_groups(L...)
Return the list of all transitive groups (up to permutation isomorphism)
satisfying the conditions described by the arguments. These conditions
may be of one of the following forms:
- `func => intval` selects groups for which the function `func` returns `intval`
- `func => list` selects groups for which the function `func` returns any element inside `list`
- `func` selects groups for which the function `func` returns `true`
- `!func` selects groups for which the function `func` returns `false`
The following functions are currently supported as values for `func`:
- `degree`
- `is_abelian`
- `is_almost_simple`
- `is_cyclic`
- `is_nilpotent`
- `is_perfect`
- `is_primitive`
- `is_quasisimple`
- `is_simple`
- `is_sporadic_simple`
- `is_solvable`
- `is_supersolvable`
- `is_transitive`
- `number_of_conjugacy_classes`
- `number_of_moved_points`
- `order`
- `transitivity`
The type of the returned groups is `PermGroup`.
If no conditions beside the degree are used, one can also use the shorthand
`all_transitive_groups(degree)` where `degree` is an integer or a list or range of integers.
# Examples
```jldoctest
julia> all_transitive_groups(4)
5-element Vector{PermGroup}:
Permutation group of degree 4
Permutation group of degree 4
Permutation group of degree 4
Alt(4)
Sym(4)
julia> all_transitive_groups(degree => 3:5, is_abelian)
4-element Vector{PermGroup}:
Alt(3)
Permutation group of degree 4
Permutation group of degree 4
Permutation group of degree 5
```
returns the list of all abelian transitive groups acting on 3, 4 or 5 points.
"""
function all_transitive_groups(L...)
gapargs = translate_group_library_args(L; filter_attrs = _permgroup_filter_attrs)
K = GAP.Globals.AllTransitiveGroups(gapargs...)
return [PermGroup(x) for x in K]
end
function all_transitive_groups(deg::Integer)
return all_transitive_groups(degree => deg)
end
function all_transitive_groups(degs::Vector{<:Integer})
return all_transitive_groups(degree => degs)
end
function all_transitive_groups(degs::AbstractRange{<:Integer})
return all_transitive_groups(degree => degs)
end
# TODO: turn this into an iterator, possibly using PrimitiveGroupsIterator