-
-
Notifications
You must be signed in to change notification settings - Fork 193
/
client.cljs
185 lines (147 loc) · 6.58 KB
/
client.cljs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
(ns example.client
"Official Sente reference example: client"
{:author "Peter Taoussanis (@ptaoussanis)"}
(:require
[clojure.string :as str]
[cljs.core.async :as async :refer (<! >! put! chan)]
[taoensso.encore :as encore :refer-macros (have have?)]
[taoensso.timbre :as timbre :refer-macros (tracef debugf infof warnf errorf)]
[taoensso.sente :as sente :refer (cb-success?)]
;; Optional, for Transit encoding:
[taoensso.sente.packers.transit :as sente-transit])
(:require-macros
[cljs.core.async.macros :as asyncm :refer (go go-loop)]))
;; (timbre/set-level! :trace) ; Uncomment for more logging
;;;; Util for logging output to on-screen console
(def output-el (.getElementById js/document "output"))
(defn ->output! [fmt & args]
(let [msg (apply encore/format fmt args)]
(timbre/debug msg)
(aset output-el "value" (str "• " (.-value output-el) "\n" msg))
(aset output-el "scrollTop" (.-scrollHeight output-el))))
(->output! "ClojureScript appears to have loaded correctly.")
;;;; Define our Sente channel socket (chsk) client
(def ?csrf-token
(when-let [el (.getElementById js/document "sente-csrf-token")]
(.getAttribute el "data-csrf-token")))
(if ?csrf-token
(->output! "CSRF token detected in HTML, great!")
(->output! "CSRF token NOT detected in HTML, default Sente config will reject requests"))
(let [;; For this example, select a random protocol:
rand-chsk-type (if (>= (rand) 0.5) :ajax :auto)
_ (->output! "Randomly selected chsk type: %s" rand-chsk-type)
;; Serializtion format, must use same val for client + server:
packer :edn ; Default packer, a good choice in most cases
;; (sente-transit/get-transit-packer) ; Needs Transit dep
{:keys [chsk ch-recv send-fn state]}
(sente/make-channel-socket-client!
"/chsk" ; Must match server Ring routing URL
?csrf-token
{:type rand-chsk-type
:packer packer})]
(def chsk chsk)
(def ch-chsk ch-recv) ; ChannelSocket's receive channel
(def chsk-send! send-fn) ; ChannelSocket's send API fn
(def chsk-state state) ; Watchable, read-only atom
)
;;;; Sente event handlers
(defmulti -event-msg-handler
"Multimethod to handle Sente `event-msg`s"
:id ; Dispatch on event-id
)
(defn event-msg-handler
"Wraps `-event-msg-handler` with logging, error catching, etc."
[{:as ev-msg :keys [id ?data event]}]
(-event-msg-handler ev-msg))
(defmethod -event-msg-handler
:default ; Default/fallback case (no other matching handler)
[{:as ev-msg :keys [event]}]
(->output! "Unhandled event: %s" event))
(defmethod -event-msg-handler :chsk/state
[{:as ev-msg :keys [?data]}]
(let [[old-state-map new-state-map] (have vector? ?data)]
(if (:first-open? new-state-map)
(->output! "Channel socket successfully established!: %s" new-state-map)
(->output! "Channel socket state change: %s" new-state-map))))
(defmethod -event-msg-handler :chsk/recv
[{:as ev-msg :keys [?data]}]
(->output! "Push event from server: %s" ?data))
(defmethod -event-msg-handler :chsk/handshake
[{:as ev-msg :keys [?data]}]
(let [[?uid ?csrf-token ?handshake-data] ?data]
(->output! "Handshake: %s" ?data)))
;; TODO Add your (defmethod -event-msg-handler <event-id> [ev-msg] <body>)s here...
;;;; Sente event router (our `event-msg-handler` loop)
(defonce router_ (atom nil))
(defn stop-router! [] (when-let [stop-f @router_] (stop-f)))
(defn start-router! []
(stop-router!)
(reset! router_
(sente/start-client-chsk-router!
ch-chsk event-msg-handler)))
;;;; UI events
(when-let [target-el (.getElementById js/document "btn1")]
(.addEventListener target-el "click"
(fn [ev]
(->output! "Button 1 was clicked (won't receive any reply from server)")
(chsk-send! [:example/button1 {:had-a-callback? "nope"}]))))
(when-let [target-el (.getElementById js/document "btn2")]
(.addEventListener target-el "click"
(fn [ev]
(->output! "Button 2 was clicked (will receive reply from server)")
(chsk-send! [:example/button2 {:had-a-callback? "indeed"}] 5000
(fn [cb-reply] (->output! "Callback reply: %s" cb-reply))))))
(when-let [target-el (.getElementById js/document "btn3")]
(.addEventListener target-el "click"
(fn [ev]
(->output! "Button 3 was clicked (will ask server to test rapid async push)")
(chsk-send! [:example/test-rapid-push]))))
(when-let [target-el (.getElementById js/document "btn4")]
(.addEventListener target-el "click"
(fn [ev]
(->output! "Button 4 was clicked (will toggle async broadcast loop)")
(chsk-send! [:example/toggle-broadcast] 5000
(fn [cb-reply]
(when (cb-success? cb-reply)
(let [loop-enabled? cb-reply]
(if loop-enabled?
(->output! "Async broadcast loop now enabled")
(->output! "Async broadcast loop now disabled")))))))))
(when-let [target-el (.getElementById js/document "btn5")]
(.addEventListener target-el "click"
(fn [ev]
(->output! "Disconnecting")
(sente/chsk-disconnect! chsk))))
(when-let [target-el (.getElementById js/document "btn6")]
(.addEventListener target-el "click"
(fn [ev]
(->output! "Reconnecting")
(sente/chsk-reconnect! chsk))))
(when-let [target-el (.getElementById js/document "btn-login")]
(.addEventListener target-el "click"
(fn [ev]
(let [user-id (.-value (.getElementById js/document "input-login"))]
(if (str/blank? user-id)
(js/alert "Please enter a user-id first")
(do
(->output! "Logging in with user-id %s" user-id)
;;; Use any login procedure you'd like. Here we'll trigger an Ajax
;;; POST request that resets our server-side session. Then we ask
;;; our channel socket to reconnect, thereby picking up the new
;;; session.
(sente/ajax-lite "/login"
{:method :post
:headers {:X-CSRF-Token (:csrf-token @chsk-state)}
:params {:user-id (str user-id)}}
(fn [ajax-resp]
(->output! "Ajax login response: %s" ajax-resp)
(let [login-successful? true ; Your logic here
]
(if-not login-successful?
(->output! "Login failed")
(do
(->output! "Login successful")
(sente/chsk-reconnect! chsk))))))))))))
;;;; Init stuff
(defn start! [] (start-router!))
(defonce _start-once (start!))