Can I set prompt color of an aborted command to yellow?

[BrandonStudio]

Right now commands with return value 0 shows green, and all other return values shows red.

Here, I can't see any different if I abort a command.
For example, I may type

d^C

In bash it shows a ^C, but here it show nothing.

Can I set these aborted command (with exit code 130) with yellow arrow?

[romkatv]

It's technically possible but there is an even better option: press Ctrl-U instead of Ctrl-C.

[BrandonStudio]

But I would like to keep what I've typed, in case I would retrieve them

[romkatv]

Here's what I use for this purpose:

function stash-buffer() {
  builtin emulate -L zsh
  [[ -z $BUFFER ]] && builtin return
  builtin fc -R =(builtin print -r -- ${BUFFER//$'\n'/$'\\\n'})
  BUFFER=
}

builtin zle -N stash-buffer
builtin bindkey '^[o' stash-buffer  # Alt-o

Another option:

setopt interactive_comments
bindkey '^[o' pound-insert  # Alt-o

Note that pound-insert can be used not only to stash the command as a comment but also to uncomment and execute a previously stashed command. Here's its description from the docs: "If there is no # character at the beginning of the buffer, add one to the beginning of each line. If there is one, remove a # from each line that has one. In either case, accept the current line."

If you still would prefer your initial suggestion over these options, you can implement a custom prompt segment for that. It's be far from trivial, so I won't attempt to code it here. Besides, I really think it's not a good solution for the given use case.

Edit: If you are using zsh4humans, you already have Alt-o bound to the equivalent of stash-buffer that I posted above.