build.gradle

plugins {
    id "java-library"
    id "maven-publish"
    id 'signing'
}

group = 'net.sargue'
version = '2.0.2'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
    withJavadocJar()
    withSourcesJar()
}

allprojects {
    tasks.withType(Javadoc) {
        options.addBooleanOption('Xdoclint:none', true)
    }
}

repositories {
    mavenCentral()
    // for snapshot release of spring that includes jakarta classes
    maven {
      url "https://repo.spring.io/milestone"
    }    
}

dependencies {
    compileOnly(group: "jakarta.servlet.jsp", name: "jakarta.servlet.jsp-api", version: "3.0.0")
    compileOnly(group: "jakarta.servlet.jsp.jstl", name: "jakarta.servlet.jsp.jstl-api", version: "2.0.0")

    testImplementation(group: "jakarta.servlet.jsp", name: "jakarta.servlet.jsp-api", version: "3.0.0")
    testImplementation(group: "jakarta.servlet.jsp.jstl", name: "jakarta.servlet.jsp.jstl-api", version: "2.0.0")
    testImplementation(group: "junit", name: "junit", version: "4.13.2")
    testImplementation(group: "org.springframework", name: "spring-test", version: "6.0.0-M2")
}

jar {
    manifest {
        attributes('Implementation-Title': 'Java 8 java.time JSP tags',
                   'Implementation-Version': archiveVersion)
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            pom {
                name = 'Java 8 java.time JSP tags'
                description = 'JSP tag support for Java 8 java.time (JSR-310)'
                url = 'https://github.com/sargue/java-time-jsptags'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'sargue'
                        name = 'Sergi Baila'
                        email = 'sergibaila@protonmail.com'
                    }
                }
                scm {
                    connection = 'scm:git:git@github.com:sargue/java-time-jsptags.git'
                    developerConnection = 'scm:git:git@github.com:sargue/java-time-jsptags.git'
                    url = 'git@github.com:sargue/java-time-jsptags.git'
                }
            }
        }
    }
    repositories {
        maven {
            def releasesRepoUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
            def snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
            url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }
}

signing {
    useGpgCmd()
    sign publishing.publications.mavenJava
}