mainunit.pas

unit mainunit;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, process, Forms, Controls, Graphics, Dialogs, LCLTranslator, DefaultTranslator,StdCtrls,
  EditBtn, ButtonPanel, ExtCtrls, Menus, Spin, IniFiles, FileUtil,
  UniqueInstance, LCLIntf, Buttons, resstr, IdHTTP, IdComponent, IdSSLOpenSSL, IdSSLOpenSSLHeaders;


type

  { TMainForm }

  TMainForm = class(TForm)
    BitBtn1: TBitBtn;
    ButtonPanel1: TButtonPanel;
    CheckBoxRunGiteaStartup: TCheckBox;
    CheckBoxStopGiteaWhenClose: TCheckBox;
    CheckBoxOpenPageAfterLaunch: TCheckBox;
    CheckBoxCheckUpdateStartup: TCheckBox;
    CoBoxProtocol: TComboBox;
    CoBoxBrow: TComboBox;
    CoBoxLang: TComboBox;
    EditHost: TEdit;
    EditBrowsPath: TFileNameEdit;
    EditGiteaPatch: TFileNameEdit;
    GroupBox1: TGroupBox;
    GroupBox2: TGroupBox;
    GroupBox3: TGroupBox;
    ImageList1: TImageList;
    Label1: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    MenuItem1: TMenuItem;
    MenuAbout: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem4: TMenuItem;
    MenuUpdate: TMenuItem;
    MenuSetting: TMenuItem;
    MenuStartStop: TMenuItem;
    MenuItem3: TMenuItem;
    MenuOpenGitea: TMenuItem;
    MenuItem5: TMenuItem;
    MenuClose: TMenuItem;
    PopupMenu1: TPopupMenu;
    RButtDefPort: TRadioButton;
    RButtSpecPort: TRadioButton;
    RButtDefBrows: TRadioButton;
    RButtSelBrows: TRadioButton;
    RButtOterBrows: TRadioButton;
    EditPort: TSpinEdit;
    TrayIcon1: TTrayIcon;
    UniqueInstance1: TUniqueInstance;
    procedure CheckBoxRunGiteaStartupChange(Sender: TObject);
    procedure CoBoxLangChange(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: boolean);
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure MenuAboutClick(Sender: TObject);
    procedure MenuCloseClick(Sender: TObject);
    procedure MenuUpdateClick(Sender: TObject);
    procedure MenuOpenGiteaClick(Sender: TObject);
    procedure MenuSettingClick(Sender: TObject);
    procedure MenuStartStopClick(Sender: TObject);
    procedure BtnUpdSettingClick(Sender: TObject);
    procedure OKButtonClick(Sender: TObject);
    procedure RButtPortChange(Sender: TObject);
    procedure RButtBrowsChange(Sender: TObject);
    procedure TrayIcon1DblClick(Sender: TObject);

  private
    function GetSetupBrowser: TStringList;
    function GetLangNameOfCode(ALangPatch, ALangCode: String): String;
    function GetLangCodeOfName(ALangPatch, AlangName: String): String;
    function IsReady(aGiteaUrl: String): Boolean;

    procedure PathDefinition;
    procedure FillLangCoBox(aLangPatch: String);
    procedure ReadIniFile;
    procedure WriteIniFile;
    procedure SetMainVar;
    procedure ReRunApp;
    function CheckHosts(aHost: String): Boolean;

  public
    function IsRuning(AProcName: String): Boolean;
    procedure SetTrayIcon(aGiStatus: Boolean);
    procedure StopGiteaServer;
    procedure RunGiteaServer;
    procedure OpenGiteaServer;

  end;


procedure OpenLink(aLink: String);

var
  MainForm: TMainForm;

  UseProxyStatus: Boolean;
  OSIdent: String;
  ProxyHost: String;
  ProxyPort: Integer;
  ProxyUser: String;
  ProxyPass: String;

  SelPort: Boolean;
  SelBrows: Integer;
  CloseFlag: Boolean;
  LangCode: String;
  LangName: String;
  GiPort: String;
  GiPath: String;      // Full Gitea path
  GiFileName: String;  // Ony Gitea filename
  GiProtocol: String;
  GiHost: String;
  BrowsPath: String;
  BrowsInst: String;
  LangPath: String;
  ConfPath: String;
  WebBrowser: String;

  RunWitchStartup: Boolean;
  StopWhenClose: Boolean;
  OpenPageAfter: Boolean;
  CheckUpdateStartup: Boolean;

implementation

uses aboutunit, updatesetting, updategitea;

procedure OpenLink(aLink: String);
var aWebBrowser, aFile: String;
    fAttr: LongInt;
begin
  case SelBrows of
    0: aWebBrowser:= 'xdg-open';
    1: aWebBrowser:= BrowsInst;
    2: aWebBrowser:= BrowsPath;
  end;

  aFile:= FindDefaultExecutablePath(aWebBrowser);
  fAttr:= FileGetAttr(aFile);
  if ((fAttr <> -1) and ((fAttr and faDirectory) <> 0)) or not FileExists(aFile) then
    MessageDlg('Gitea Panel', Format(i18_Msg_Err_NoFindBrowser, [aWebBrowser]), mtError, [mbOK], 0)
  else
    with TProcess.Create(nil) do
      try
        Executable:= aWebBrowser;
        Parameters.Add(aLink);
        Execute;
      finally
        Free;
      end;
end;

{$R *.frm}

{ TMainForm }

function TMainForm.IsRuning(AProcName: String): Boolean;
var s: String;
begin
  s:= '';
  Result:= False;
  Sleep(500);
  if RunCommand('pgrep',['-x',AProcName],s,[poWaitOnExit]) then Result:= s <> '';
end;

function TMainForm.GetSetupBrowser: TStringList;
begin
  Result:= FindAllFiles('/usr/bin', WBROWSER, False, faDirectory);
  Result.Text:= StringReplace(Result.Text, '/usr/bin/', '', [rfIgnoreCase, rfReplaceAll]);
end;

function TMainForm.GetLangNameOfCode(ALangPatch, ALangCode: String): String;
var LngList: TStringList;
begin
  Result:= '';
  LngList:= TStringList.Create;
  LngList.NameValueSeparator:= '=';
  try
    LngList.LoadFromFile(ALangPatch + '/lang.list');
    Result:= LngList.Values[ALangCode];
  finally
    LngList.Free;
  end;
end;

function TMainForm.GetLangCodeOfName(ALangPatch, AlangName: String): String;
var LngList: TStringList;
    i: Integer;
begin
  Result:= '';
  LngList:= TStringList.Create;
  LngList.NameValueSeparator:= '=';
  try
    LngList.LoadFromFile(ALangPatch + '/lang.list');
    for i:= 0 to LngList.Count - 1 do
      if LngList.ValueFromIndex[i] = ALangName then
        begin
          Result:= LngList.Names[i];
          Break;
        end;
  finally
    LngList.Free;
  end;
end;

function TMainForm.IsReady(aGiteaUrl: String): Boolean;
var HCSSL: TIdSSLIOHandlerSocketOpenSSL;
    i: Integer;
begin
  HCSSL:= TIdSSLIOHandlerSocketOpenSSL.Create;
  HCSSL.SSLOptions.Method:= sslvSSLv23;
  with TIdHTTP.Create do
    try
      HandleRedirects:= True;
      Request.UserAgent:= 'GiteaPanel';
      IOHandler:= HCSSL;
      ConnectTimeout:= 300;
      ReadTimeout:= 300;
      i:= 0;
      repeat
        Inc(i);
        try
          Head(aGiteaUrl);
          Result:= ResponseCode = 200 ;
        except
          on Err: Exception do Result:= False;
        end;
        Application.ProcessMessages;
        Sleep(400);
      until Result or (i > 15);
    finally
      HCSSL.Free;
      Free;
    end;
end;

procedure TMainForm.PathDefinition;
var aMyDir: String;
    aUserDir: String;
begin
  aMyDir:= ExtractFilePath(ParamStr(0));
  aUserDir:= GetUserDir;
  if Pos('/usr/bin', aMyDir) > 0 then
    begin
      SetCurrentDir(aMyDir);
      LangPath:= ExpandFileName('../share/giteapanel/locale');
      if DirectoryExists(aUserDir + '.config') then ConfPath:= aUserDir + '.config'
      else ConfPath:= aUserDir;
    end
  else
    begin
      LangPath:= aMyDir + 'locale';
      ConfPath:= aMyDir;
    end;
end;

procedure TMainForm.FillLangCoBox(aLangPatch: String);
var LngList: TStringList;
    ResSearsh: TSearchRec;
    LaCode: String;
begin
  CoBoxLang.Clear;
  LngList:= TStringList.Create;
  LngList.NameValueSeparator:='=';
  try
    LngList.LoadFromFile(ALangPatch + '/lang.list');
    if FindFirst(ALangPatch + '/giteapanel.*.po', faAnyFile, ResSearsh) <> -1 then
      repeat
        LaCode:= String(ResSearsh.Name).Split('.')[1];
        if LngList.Values[LaCode] <> '' then CoBoxLang.Items.Add(LngList.Values[LaCode]);
      until FindNext(ResSearsh) <> 0;
    FindClose(ResSearsh);
  finally
    LngList.Free;
  end;
end;

procedure TMainForm.ReadIniFile;
begin
  with TIniFile.Create(ConfPath + '/giteapanel.conf') do
    try
      LangCode         := ReadString('DATA','Language','en');
      GiPath           := ReadString('GITEA','GiteaPath','');
      BrowsInst        := ReadString('BROWSER','BrowserInst','');
      GiPort           := ReadString('GITEA','GiteaPort','8080');
      SelBrows         := ReadInteger('BROWSER','SelctedBrowser',0);
      SelPort          := ReadBool('BROWSER','SelectedPort',False);
      BrowsPath        := ReadString('BROWSER','BrowserPath','');
      GiProtocol       := ReadString('GITEA','GiteaProtocol','http://');
      GiHost           := ReadString('GITEA','GiteaHost','localhost');

      UseProxyStatus   := ReadBool('UPDATE','ProxyStatus', false);
      OSIdent          := ReadString('UPDATE','My_OS','');
      ProxyHost        := ReadString('UPDATE','ProxyHost','');
      ProxyPort        := ReadInteger('UPDATE','ProxyPort',80);
      ProxyUser        := ReadString('UPDATE','ProxyUser','');
      ProxyPass        := ReadString('UPDATE','ProxyPass','');

      RunWitchStartup     := ReadBool('DATA','RunWitchStartup', false);
      OpenPageAfter       := ReadBool('DATA', 'OpenPageAfter', false);
      StopWhenClose       := ReadBool('DATA', 'StopWhenClose', false);
      CheckUpdateStartup  := ReadBool('DATA', 'CheckUpdateStartup', false);

      Top                 := ReadInteger('DATA','TopPosition',0);
      Left                := ReadInteger('DATA', 'LeftPosition',0);
    finally
      Free;
    end;

  LangName:= GetLangNameOfCode(LangPath,LangCode);
  if GiPath='' then GiFileName:= 'gitea' else GiFileName:=ExtractFileName(GiPath);

  if Not FileExists(GiPath,False) then Show;
end;

procedure TMainForm.WriteIniFile;
begin
  with TIniFile.Create(ConfPath + '/giteapanel.conf') do
    try
      WriteString('GITEA','GiteaPath',GiPath);
      WriteString('GITEA','GiteaPort',GiPort);
      WriteString('GITEA','GiteaProtocol',GiProtocol);
      WriteString('GITEA','GiteaHost',GiHost);
      WriteBool('GITEA','SelectedPort',SelPort);
      WriteInteger('BROWSER','SelctedBrowser',SelBrows);
      WriteString('BROWSER','BrowserInst', BrowsInst);
      WriteString('BROWSER','BrowserPath',BrowsPath);

      WriteBool('UPDATE','ProxyStatus', UseProxyStatus);
      WriteString('UPDATE','My_OS',OSIdent);
      WriteString('UPDATE','ProxyHost',ProxyHost);
      WriteInteger('UPDATE','ProxyPort',ProxyPort);
      WriteString('UPDATE','ProxyUser',ProxyUser);
      WriteString('UPDATE','ProxyPass',ProxyPass);

      WriteBool('DATA','RunWitchStartup', RunWitchStartup);
      WriteBool('DATA', 'OpenPageAfter', OpenPageAfter);
      WriteBool('DATA', 'StopWhenClose', StopWhenClose);
      WriteBool('DATA', 'CheckUpdateStartup', CheckUpdateStartup);

      if LangCode = '' then LangCode:= 'en';
      WriteString('DATA','Language',LangCode);
    finally
      Free;
    end;
end;

procedure TMainForm.SetTrayIcon(aGiStatus: Boolean);
begin
  if aGiStatus then
     begin
       TrayIcon1.Icon.LoadFromResourceName(HINSTANCE, 'GITEAGREEN');
       MenuStartStop.Caption:= i18_StopGitea;
       MenuStartStop.ImageIndex:=1;
       MenuOpenGitea.Enabled:=True;
       TrayIcon1.Hint:= i18_GiteaRunig;
     end
  else
     begin
       TrayIcon1.Icon.LoadFromResourceName(HINSTANCE, 'GITEARED');
       MenuStartStop.Caption:= i18_StartGitea;
       MenuStartStop.ImageIndex:=0;
       MenuOpenGitea.Enabled:=False;
       TrayIcon1.Hint:= i18_GiteaStoped;
     end;
end;

procedure TMainForm.StopGiteaServer;
begin
  with TProcess.Create(nil) do
    try
      Executable:='/bin/bash';
      Parameters.Add('-c');
      Parameters.Add('$(kill -- $(pgrep -x ' + GiFileName + '))');
      Options:=Options + [poWaitOnExit];
      Execute;
    finally
      Free;
    end;
  Sleep(1000);
  SetTrayIcon(IsRuning(GiFileName));
end;

procedure TMainForm.RunGiteaServer;
var cmd: String;
    fAtt: LongInt;
begin
  if SelPort then cmd:= ' web --port ' + GiPort
  else cmd:= ' web';

  fAtt:= FileGetAttr(GiPath);
  if ((fAtt <> -1) and ((fAtt and faDirectory) <> 0)) or not FileExists(GiPath) then
     begin
       MessageDlg('Gitea Panel', i18_Msg_Err_RunGitea, mtError, [mbOK], 0);
       Exit;
     end;

  with TProcess.Create(nil) do
     try
      InheritHandles:= False;
      Options:= [];
      Executable:= '/bin/bash';
      Parameters.Add('-c');
      Parameters.Add('(' + GiPath + cmd +' &); exit 0');
      Execute;
    finally
      Free;
    end;
    SetTrayIcon(IsRuning(GiFileName));
end;

procedure TMainForm.OpenGiteaServer;
var link: String;
begin
  if SelPort then link:= GiProtocol + GiHost + ':' + GiPort else link:= GiProtocol + GiHost + ':3000';
  if CheckHosts(GiHost) then
    if IsReady(link) then OpenLink(link)
    else MessageDlg('Gitea Panel', Format(i18_Msg_Err_CantOpenServer,[link]), mtError, [mbOK], 0)
  else MessageDlg('Gitea Panel', Format(i18_Msg_Err_MissingFromHosts, [GiHost, GiHost]), mtError, [mbOK], 0);
end;

procedure TMainForm.SetMainVar;
begin
  GiProtocol:= CoBoxProtocol.Text;
  GiHost:= EditHost.Text;
  GiPath:= EditGiteaPatch.Text;
  GiFileName:= ExtractFileName(GiPath);
  GiPort:= IntToStr(EditPort.Value);
  SelPort:= RButtSpecPort.Checked;
  BrowsInst:= CoBoxBrow.Text;
  BrowsPath:= EditBrowsPath.Text;
  LangName:= CoBoxLang.Text;
  LangCode:= GetLangCodeOfName(LangPath, LangName);
  RunWitchStartup:= CheckBoxRunGiteaStartup.Checked;
  OpenPageAfter:= CheckBoxOpenPageAfterLaunch.Checked;
  StopWhenClose:= CheckBoxStopGiteaWhenClose.Checked;
  CheckUpdateStartup:= CheckBoxCheckUpdateStartup.Checked;
end;

procedure TMainForm.ReRunApp;
begin
  FileCreate(ConfPath +'LockGiteaPanel.file');
  with TProcess.Create(nil) do
    try
      Executable:= ParamStr(0);
      Execute;
    finally
      Free;
      Application.Terminate;
    end;
end;

function TMainForm.CheckHosts(aHost: String): Boolean;
begin
  with TStringList.Create do
    try
      LoadFromFile('/etc/hosts');
      Result:= Text.Contains(aHost);
    finally
      Free;
    end;
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  //IdOpenSSLSetCanLoadSymLinks(false);
  CloseFlag:= False;
  PathDefinition;
  ReadIniFile;
  SetDefaultLang(LangCode, LangPath, 'giteapanel');
  SetTrayIcon(IsRuning(GiFileName));
  EditGiteaPatch.DialogTitle:= i18_DlgTitle_Giteapatch;
  EditBrowsPath.DialogTitle:= i18_DlgTitle_BrowsPath;
  TrayIcon1.Visible:=true;
  Application.ProcessMessages;

  if not FileExists(ConfPath + 'LockGiteaPanel.file') then
    begin
      if RunWitchStartup then
        begin
          RunGiteaServer;
          if OpenPageAfter then OpenGiteaServer;
        end;
    end
  else DeleteFile(ConfPath + 'LockGiteaPanel.file');
end;

procedure TMainForm.FormShow(Sender: TObject);
begin
  DisableAutoSizing;
  FillLangCoBox(LangPath);
  EditGiteaPatch.Text:= GiPath;
  CoBoxProtocol.ItemIndex:= CoBoxProtocol.Items.IndexOf(GiProtocol);
  EditHost.Caption:= GiHost;
  CoBoxLang.ItemIndex:= CoBoxLang.Items.IndexOf(LangName);

  CoBoxBrow.Clear;
  CoBoxBrow.Items.AddText(GetSetupBrowser.Text);
  CoBoxBrow.ItemIndex:= CoBoxBrow.Items.IndexOf(BrowsInst);
  EditBrowsPath.Text:= BrowsPath;

  CheckBoxRunGiteaStartup.Checked:= RunWitchStartup;
  CheckBoxOpenPageAfterLaunch.Checked:= OpenPageAfter;
  CheckBoxStopGiteaWhenClose.Checked:= StopWhenClose;
  CheckBoxCheckUpdateStartup.Checked:= CheckUpdateStartup;

  case SelBrows of
    0:  RButtDefBrows.Checked:= True;
    1:  RButtSelBrows.Checked:= True;
    2:  RButtOterBrows.Checked:= True;
  end;

  RButtSpecPort.Checked:= SelPort;
  EditPort.Value:= StrToInt(GiPort);
  EnableAutoSizing;
end;

procedure TMainForm.MenuAboutClick(Sender: TObject);
begin
  RunAboutForm;
end;

procedure TMainForm.CoBoxLangChange(Sender: TObject);
var TmpLangCode: String;
begin
  if LangName <> CoBoxLang.Text then
    TmpLangCode:= GetLangCodeOfName(LangPath, CoBoxLang.Text);
    SetDefaultLang(TmpLangCode, LangPath, 'giteapanel', False);
    if MessageDlg('Gitea Panel', i18_Msg_ReRunApp, mtConfirmation, [mbYes, mbNo], 0) = mrYes then
      begin
        SetMainVar;
        WriteIniFile;
        ReRunApp;
      end
    else
      begin
        SetDefaultLang(LangCode, LangPath, 'giteapanel');
        CoBoxLang.Text:= LangName;
      end;
end;

procedure TMainForm.CheckBoxRunGiteaStartupChange(Sender: TObject);
begin
  CheckBoxOpenPageAfterLaunch.Enabled:= CheckBoxRunGiteaStartup.Checked;
end;

procedure TMainForm.FormCloseQuery(Sender: TObject; var CanClose: boolean);
begin
  with TIniFile.Create(ConfPath + '/giteapanel.conf') do
    try
      WriteInteger('DATA','TopPosition', Top);
      WriteInteger('DATA','LeftPosition', Left);
    finally
      Free;
    end;
  if Not FileExists(ConfPath + 'LockGiteaPanel.file') then
     if StopWhenClose and CloseFlag then StopGiteaServer;
  CanClose:=CloseFlag;
  if Not CloseFlag then Hide;
end;

procedure TMainForm.MenuCloseClick(Sender: TObject);
begin
  CloseFlag:=True;
  Close;
end;

procedure TMainForm.MenuUpdateClick(Sender: TObject);
begin
  RunFormUpdGitea;
end;

procedure TMainForm.MenuOpenGiteaClick(Sender: TObject);
begin
  OpenGiteaServer;
end;

procedure TMainForm.MenuSettingClick(Sender: TObject);
begin
  if MainForm.Visible then Hide
  else MainForm.Show;
end;

procedure TMainForm.MenuStartStopClick(Sender: TObject);
begin
  if IsRuning(GiFileName) then  StopGiteaServer else RunGiteaServer;
end;

procedure TMainForm.BtnUpdSettingClick(Sender: TObject);
begin
  RunUpdSettingForm;
end;

procedure TMainForm.OKButtonClick(Sender: TObject);
begin
  SetMainVar;
  WriteIniFile;
  Hide;
end;

procedure TMainForm.RButtPortChange(Sender: TObject);
begin
  SelPort:= RButtSpecPort.Checked;
  EditPort.Enabled:= Not EditPort.Enabled;
end;

procedure TMainForm.RButtBrowsChange(Sender: TObject);
begin
  with (Sender as TRadioButton) do SelBrows:= Tag;
  CoBoxBrow.Enabled:= (((SelBrows shr 0) and 1) = 1);
  EditBrowsPath.Enabled:= (((SelBrows shr 1) and 1) = 1);
end;

procedure TMainForm.TrayIcon1DblClick(Sender: TObject);
begin
  if Not IsRuning(GiFileName) then
    begin
      RunGiteaServer;
      OpenGiteaServer;
    end
  else OpenGiteaServer;
end;

end.