From c8f69a1dc8dadb6a772da1bb3855ec83a4f59c52 Mon Sep 17 00:00:00 2001
From: Koichi Murase <myoga.murase@gmail.com>
Date: Tue, 6 Jul 2021 00:32:47 +0900
Subject: [PATCH 1/4] refactor(make): Use awk to extract target names

---
 completions/make | 175 ++++++++++++++++++++++++-----------------------
 1 file changed, 88 insertions(+), 87 deletions(-)

diff --git a/completions/make b/completions/make
index 5952bd5e3ca..85978a38d44 100644
--- a/completions/make
+++ b/completions/make
@@ -1,91 +1,92 @@
 # bash completion for GNU make                             -*- shell-script -*-
 
-# TODO: rename per API conventions, rework to use vars rather than outputting(?)
-_make_target_extract_script()
+# Extract the valid target names starting with PREFIX from the output of
+# `make -npq'
+# @param mode    If this is `-d', the directory names already specified in
+#                PREFIX are omitted in the output
+# @param prefix  Prefix of the target names
+_comp_cmd_make__extract_targets()
 {
-    local mode="$1"
-    shift
-
-    local prefix="$1"
-    local prefix_pat=$(command sed 's/[][\,.*^$(){}?+|/]/\\&/g' <<<"$prefix")
-    local basename=${prefix##*/}
-    local dirname_len=$((${#prefix} - ${#basename}))
-    # Avoid expressions like '\(.\{0\}\)', FreeBSD sed doesn't like them:
-    # > sed: 1: ...: RE error: empty (sub)expression
-    local dirname_re=
-    ((dirname_len > 0)) && dirname_re="\(.\{${dirname_len}\}\)"
-
-    if [[ ! $dirname_re ]]; then
-        local output="\1"
-    elif [[ $mode == -d ]]; then
-        # display mode, only output current path component to the next slash
-        local output="\2"
-    else
-        # completion mode, output full path to the next slash
-        local output="\1\2"
-    fi
-
-    cat <<EOF
-    1,/^# * Make data base/           d;        # skip any makefile output
-    /^# * Finished Make data base/,/^# * Make data base/{
-                                      d;        # skip any makefile output
-    }
-    /^# * Variables/,/^# * Files/     d;        # skip until files section
-    /^# * Not a target/,/^$/          d;        # skip not target blocks
-    /^${prefix_pat}/,/^$/!            d;        # skip anything user dont want
-
-    # The stuff above here describes lines that are not
-    #  explicit targets or not targets other than special ones
-    # The stuff below here decides whether an explicit target
-    #  should be output.
-
-    /^# * File is an intermediate prerequisite/ {
-      s/^.*$//;x;                               # unhold target
-      d;                                        # delete line
-    }
-
-    /^$/ {                                      # end of target block
-      x;                                        # unhold target
-      /^$/d;                                    # dont print blanks
-      s|^${dirname_re-}\(.\{${#basename}\}[^:]*\):.*$|${output}|p;
-      d;                                        # hide any bugs
-    }
-
-    # This pattern includes a literal tab character as \t is not a portable
-    # representation and fails with BSD sed
-    /^[^#	:%]\{1,\}:/ {         # found target block
-      /^\.PHONY:/                 d;            # special target
-      /^\.SUFFIXES:/              d;            # special target
-      /^\.DEFAULT:/               d;            # special target
-      /^\.PRECIOUS:/              d;            # special target
-      /^\.INTERMEDIATE:/          d;            # special target
-      /^\.SECONDARY:/             d;            # special target
-      /^\.SECONDEXPANSION:/       d;            # special target
-      /^\.DELETE_ON_ERROR:/       d;            # special target
-      /^\.IGNORE:/                d;            # special target
-      /^\.LOW_RESOLUTION_TIME:/   d;            # special target
-      /^\.SILENT:/                d;            # special target
-      /^\.EXPORT_ALL_VARIABLES:/  d;            # special target
-      /^\.NOTPARALLEL:/           d;            # special target
-      /^\.ONESHELL:/              d;            # special target
-      /^\.POSIX:/                 d;            # special target
-      /^\.NOEXPORT:/              d;            # special target
-      /^\.MAKE:/                  d;            # special target
-EOF
-
-    # don't complete with hidden targets unless we are doing a partial completion
-    if [[ ! ${prefix_pat} || ${prefix_pat} == */ ]]; then
-        cat <<EOF
-      /^${prefix_pat}[^a-zA-Z0-9]/d;            # convention for hidden tgt
-EOF
-    fi
-
-    cat <<EOF
-      h;                                        # hold target
-      d;                                        # delete line
-    }
-
-EOF
+    local mode=$1
+    local -x prefix=$2
+
+    # display mode, only output current path component to the next slash
+    local -x prefix_replace=$prefix
+    [[ $mode == -d && $prefix == */* ]] &&
+        prefix_replace=${prefix##*/}
+
+    awk '
+      BEGIN {
+        prefix = ENVIRON["prefix"];
+        prefix_replace = ENVIRON["prefix_replace"];
+        is_target_block = 0;
+        target = "";
+      }
+      function starts_with(str, prefix) {
+        return substr(str, 1, length(prefix)) == prefix;
+      }
+
+      NR == 1, /^# +Make data base/ { next; }     # skip any makefile output
+      /^# +Finished Make data base/,/^# +Make data base/ { next; } # skip any makefile output
+      /^# +Variables/, /^# +Files/ { next; }      # skip until files section
+      /^# +Not a target/, /^$/     { next; }      # skip not target blocks
+
+      # The stuff above here describes lines that are not
+      #  explicit targets or not targets other than special ones
+      # The stuff below here decides whether an explicit target
+      #  should be output.
+
+      starts_with($0, prefix) { is_target_block = 1; }
+      !is_target_block { next; }
+
+      /^# +File is an intermediate prerequisite/ { # cancel the block
+        is_target_block = 0;
+        target = "";
+        next;
+      }
+
+      /^$/ {                                      # end of target block
+        is_target_block = 0;
+        if (target != "") {
+          print target;
+          target = "";
+        }
+        next;
+      }
+
+      # only process the targets the user wants.
+      /^[^#\t:%]+:/ {                             # found target block
+        if (/^\.PHONY:/               ) next;     # special target
+        if (/^\.SUFFIXES:/            ) next;     # special target
+        if (/^\.DEFAULT:/             ) next;     # special target
+        if (/^\.PRECIOUS:/            ) next;     # special target
+        if (/^\.INTERMEDIATE:/        ) next;     # special target
+        if (/^\.SECONDARY:/           ) next;     # special target
+        if (/^\.SECONDEXPANSION:/     ) next;     # special target
+        if (/^\.DELETE_ON_ERROR:/     ) next;     # special target
+        if (/^\.IGNORE:/              ) next;     # special target
+        if (/^\.LOW_RESOLUTION_TIME:/ ) next;     # special target
+        if (/^\.SILENT:/              ) next;     # special target
+        if (/^\.EXPORT_ALL_VARIABLES:/) next;     # special target
+        if (/^\.NOTPARALLEL:/         ) next;     # special target
+        if (/^\.ONESHELL:/            ) next;     # special target
+        if (/^\.POSIX:/               ) next;     # special target
+        if (/^\.NOEXPORT:/            ) next;     # special target
+        if (/^\.MAKE:/                ) next;     # special target
+
+        # dont complete with hidden targets unless we are doing a partial completion
+        if (prefix == "" || prefix ~ /\/$/)
+          if (substr($0, length(prefix) + 1, 1) ~ /[^a-zA-Z0-9]/)
+            next;
+
+        target = $0;
+        sub(/:.*/, "", target);
+        if (prefix_replace != prefix)
+          target = prefix_replace substr(target, 1 + length(prefix))
+
+        next;
+      }
+    '
 }
 
 # Truncate the non-unique filepaths in COMPREPLY to only generate unique
@@ -224,11 +225,11 @@ _comp_cmd_make()
         #     mode=-d # display-only mode
         # fi
 
-        local IFS=$' \t\n' script=$(_make_target_extract_script $mode "$cur")
+        local IFS=$' \t\n'
         COMPREPLY=($(LC_ALL=C \
             $1 -npq __BASH_MAKE_COMPLETION__=1 \
             ${makef+"${makef[@]}"} "${makef_dir[@]}" .DEFAULT 2>/dev/null |
-            command sed -ne "$script"))
+            _comp_cmd_make__extract_targets "$mode" "$cur"))
 
         _comp_cmd_make__truncate_non_unique_paths
 

From 178f51879c02d6cb69cee014ec5b0a712e63dea1 Mon Sep 17 00:00:00 2001
From: Koichi Murase <myoga.murase@gmail.com>
Date: Mon, 20 Nov 2023 05:51:10 +0900
Subject: [PATCH 2/4] refactor(make): separate out the awk script

---
 completions/make                 | 73 +------------------------
 helpers/Makefile.am              |  2 +-
 helpers/make-extract-targets.awk | 93 ++++++++++++++++++++++++++++++++
 3 files changed, 95 insertions(+), 73 deletions(-)
 create mode 100644 helpers/make-extract-targets.awk

diff --git a/completions/make b/completions/make
index 85978a38d44..64c4de1db49 100644
--- a/completions/make
+++ b/completions/make
@@ -15,78 +15,7 @@ _comp_cmd_make__extract_targets()
     [[ $mode == -d && $prefix == */* ]] &&
         prefix_replace=${prefix##*/}
 
-    awk '
-      BEGIN {
-        prefix = ENVIRON["prefix"];
-        prefix_replace = ENVIRON["prefix_replace"];
-        is_target_block = 0;
-        target = "";
-      }
-      function starts_with(str, prefix) {
-        return substr(str, 1, length(prefix)) == prefix;
-      }
-
-      NR == 1, /^# +Make data base/ { next; }     # skip any makefile output
-      /^# +Finished Make data base/,/^# +Make data base/ { next; } # skip any makefile output
-      /^# +Variables/, /^# +Files/ { next; }      # skip until files section
-      /^# +Not a target/, /^$/     { next; }      # skip not target blocks
-
-      # The stuff above here describes lines that are not
-      #  explicit targets or not targets other than special ones
-      # The stuff below here decides whether an explicit target
-      #  should be output.
-
-      starts_with($0, prefix) { is_target_block = 1; }
-      !is_target_block { next; }
-
-      /^# +File is an intermediate prerequisite/ { # cancel the block
-        is_target_block = 0;
-        target = "";
-        next;
-      }
-
-      /^$/ {                                      # end of target block
-        is_target_block = 0;
-        if (target != "") {
-          print target;
-          target = "";
-        }
-        next;
-      }
-
-      # only process the targets the user wants.
-      /^[^#\t:%]+:/ {                             # found target block
-        if (/^\.PHONY:/               ) next;     # special target
-        if (/^\.SUFFIXES:/            ) next;     # special target
-        if (/^\.DEFAULT:/             ) next;     # special target
-        if (/^\.PRECIOUS:/            ) next;     # special target
-        if (/^\.INTERMEDIATE:/        ) next;     # special target
-        if (/^\.SECONDARY:/           ) next;     # special target
-        if (/^\.SECONDEXPANSION:/     ) next;     # special target
-        if (/^\.DELETE_ON_ERROR:/     ) next;     # special target
-        if (/^\.IGNORE:/              ) next;     # special target
-        if (/^\.LOW_RESOLUTION_TIME:/ ) next;     # special target
-        if (/^\.SILENT:/              ) next;     # special target
-        if (/^\.EXPORT_ALL_VARIABLES:/) next;     # special target
-        if (/^\.NOTPARALLEL:/         ) next;     # special target
-        if (/^\.ONESHELL:/            ) next;     # special target
-        if (/^\.POSIX:/               ) next;     # special target
-        if (/^\.NOEXPORT:/            ) next;     # special target
-        if (/^\.MAKE:/                ) next;     # special target
-
-        # dont complete with hidden targets unless we are doing a partial completion
-        if (prefix == "" || prefix ~ /\/$/)
-          if (substr($0, length(prefix) + 1, 1) ~ /[^a-zA-Z0-9]/)
-            next;
-
-        target = $0;
-        sub(/:.*/, "", target);
-        if (prefix_replace != prefix)
-          target = prefix_replace substr(target, 1 + length(prefix))
-
-        next;
-      }
-    '
+    awk -f "${BASH_SOURCE[0]%/*}/../helpers/make-extract-targets.awk"
 }
 
 # Truncate the non-unique filepaths in COMPREPLY to only generate unique
diff --git a/helpers/Makefile.am b/helpers/Makefile.am
index 2a0a18d7469..fb3c0c8d4ee 100644
--- a/helpers/Makefile.am
+++ b/helpers/Makefile.am
@@ -1,4 +1,4 @@
 helpersdir = $(datadir)/$(PACKAGE)/helpers
-helpers_DATA = perl python
+helpers_DATA = perl python make-extract-targets.awk
 
 EXTRA_DIST = $(helpers_DATA)
diff --git a/helpers/make-extract-targets.awk b/helpers/make-extract-targets.awk
new file mode 100644
index 00000000000..b0ce10ea4d9
--- /dev/null
+++ b/helpers/make-extract-targets.awk
@@ -0,0 +1,93 @@
+# helper AWK script for GNU make                                    -*- awk -*-
+
+# This AWK script is used by the function `_comp_cmd_make__extract_targets` in
+# `completions/make`.  This script receives the output of `make -npq' as the
+# input file or stdin and outputs the list of targets matching the prefix.
+#
+# @env prefix         Specifies the prefix to match.
+# @env prefix_replace Specifies the string that replaces the prefix in the
+#   output.  This is used when we want to omit the directory name in showing
+#   the list of the completions.
+#
+
+BEGIN {
+  prefix = ENVIRON["prefix"];
+  prefix_replace = ENVIRON["prefix_replace"];
+  is_target_block = 0;
+  target = "";
+}
+
+function starts_with(str, prefix) {
+  return substr(str, 1, length(prefix)) == prefix;
+}
+
+# skip any makefile outputs
+NR == 1, /^# +Make data base/ { next; }
+/^# +Finished Make data base/,/^# +Make data base/ { next; }
+
+# skip until files section
+/^# +Variables/, /^# +Files/ { next; }
+
+# skip not-target blocks
+/^# +Not a target/, /^$/     { next; }
+
+# The stuff above here describes lines that are not
+#  explicit targets or not targets other than special ones
+# The stuff below here decides whether an explicit target
+#  should be output.
+
+# only process the targets the user wants.
+starts_with($0, prefix) { is_target_block = 1; }
+is_target_block == 0 { next; }
+
+/^# +File is an intermediate prerequisite/ { # cancel the block
+  is_target_block = 0;
+  target = "";
+  next;
+}
+
+# end of target block
+/^$/ {
+  is_target_block = 0;
+  if (target != "") {
+    print target;
+    target = "";
+  }
+  next;
+}
+
+# found target block
+/^[^#\t:%]+:/ {
+  # special targets
+  if (/^\.PHONY:/               ) next;
+  if (/^\.SUFFIXES:/            ) next;
+  if (/^\.DEFAULT:/             ) next;
+  if (/^\.PRECIOUS:/            ) next;
+  if (/^\.INTERMEDIATE:/        ) next;
+  if (/^\.SECONDARY:/           ) next;
+  if (/^\.SECONDEXPANSION:/     ) next;
+  if (/^\.DELETE_ON_ERROR:/     ) next;
+  if (/^\.IGNORE:/              ) next;
+  if (/^\.LOW_RESOLUTION_TIME:/ ) next;
+  if (/^\.SILENT:/              ) next;
+  if (/^\.EXPORT_ALL_VARIABLES:/) next;
+  if (/^\.NOTPARALLEL:/         ) next;
+  if (/^\.ONESHELL:/            ) next;
+  if (/^\.POSIX:/               ) next;
+  if (/^\.NOEXPORT:/            ) next;
+  if (/^\.MAKE:/                ) next;
+
+  # dont complete with hidden targets unless we are doing a partial completion
+  if (prefix == "" || prefix ~ /\/$/)
+    if (substr($0, length(prefix) + 1, 1) ~ /[^a-zA-Z0-9]/)
+      next;
+
+  target = $0;
+  sub(/:.*/, "", target);
+  if (prefix_replace != prefix)
+    target = prefix_replace substr(target, 1 + length(prefix));
+
+  next;
+}
+
+# ex: filetype=awk

From cdd6da9c77c7c99cab0aed7b9d7a5e4c0c5e0c78 Mon Sep 17 00:00:00 2001
From: Koichi Murase <myoga.murase@gmail.com>
Date: Mon, 20 Nov 2023 06:12:39 +0900
Subject: [PATCH 3/4] fix: use XPG4 awk in Solaris
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Solaris awk lacks many POSIX features as listed below.  When any of
them is used, we use XPG4 awk at /usr/xpg4/bin/awk instead of Solaris
awk at /usr/bin/awk.

- Solaris awk does not support ENVIRON.
- Solaris awk does not support the function `tolower`.
- Solaris awk does not support user-defined functions.
- Solaris awk does not support `-F ERE' but only supports -F<char>.
- Solaris awk does not accept an option argument for `-F` in a
  separate word.  The option argument needs to be specified in the
  same command-line word as `-F<char>`.
- Solaris awk does not support the command-line option `-v var=value`

Co-authored-by: Ville Skyttä <ville.skytta@iki.fi>
---
 bash_completion         | 16 ++++++++++++++++
 completions/_nmcli      |  8 ++++----
 completions/convert     |  2 +-
 completions/dpkg        |  4 ++--
 completions/iwconfig    |  4 ++--
 completions/make        |  2 +-
 completions/portinstall |  2 +-
 test/runLint            |  2 +-
 8 files changed, 28 insertions(+), 12 deletions(-)

diff --git a/bash_completion b/bash_completion
index 87521404dc3..747b0bd05d4 100644
--- a/bash_completion
+++ b/bash_completion
@@ -3207,6 +3207,22 @@ _comp_xfunc()
     "$xfunc_name" "${@:3}"
 }
 
+# Call a POSIX-compatible awk.  Solaris awk is not POSIX-compliant, but Solaris
+# provides a POSIX-compatible version through /usr/xpg4/bin/awk.  We switch the
+# implementation to /usr/xpg4/bin/awk in Solaris if any.
+# @since 2.12
+if [[ $OSTYPE == *solaris* && -x /usr/xpg4/bin/awk ]]; then
+    _comp_awk()
+    {
+        /usr/xpg4/bin/awk "$@"
+    }
+else
+    _comp_awk()
+    {
+        command awk "$@"
+    }
+fi
+
 # source compat completion directory definitions
 _comp__init_compat_dirs=()
 if [[ ${BASH_COMPLETION_COMPAT_DIR-} ]]; then
diff --git a/completions/_nmcli b/completions/_nmcli
index 816c9c7320a..835db9924f3 100644
--- a/completions/_nmcli
+++ b/completions/_nmcli
@@ -6,25 +6,25 @@
 _comp_cmd_nmcli__con_id()
 {
     _comp_compgen_split -l -- "$(nmcli con list 2>/dev/null |
-        tail -n +2 | awk -F ' {2,}' '{print $1 }')"
+        tail -n +2 | _comp_awk -F ' {2,}' '{print $1}')"
 }
 
 _comp_cmd_nmcli__con_uuid()
 {
     _comp_compgen_split -- "$(nmcli con list 2>/dev/null |
-        tail -n +2 | awk -F ' {2,}' '{print $2}')"
+        tail -n +2 | _comp_awk -F ' {2,}' '{print $2}')"
 }
 
 _comp_cmd_nmcli__ap_ssid()
 {
     _comp_compgen_split -l -- "$(nmcli dev wifi list 2>/dev/null |
-        tail -n +2 | awk -F ' {2,}' '{print $1}')"
+        tail -n +2 | _comp_awk -F ' {2,}' '{print $1}')"
 }
 
 _comp_cmd_nmcli__ap_bssid()
 {
     _comp_compgen_split -- "$(nmcli dev wifi list 2>/dev/null |
-        tail -n +2 | awk -F ' {2,}' '{print $2}')"
+        tail -n +2 | _comp_awk -F ' {2,}' '{print $2}')"
 }
 
 _comp_cmd_nmcli()
diff --git a/completions/convert b/completions/convert
index 96091178861..b01633bae49 100644
--- a/completions/convert
+++ b/completions/convert
@@ -49,7 +49,7 @@ _comp_cmd_convert__common_options()
             return
             ;;
         -format)
-            _comp_compgen_split -- "$(convert -list format | awk \
+            _comp_compgen_split -- "$(convert -list format | _comp_awk \
                 '/ [r-][w-][+-] / { sub("[*]$","",$1); print tolower($1) }')"
             return
             ;;
diff --git a/completions/dpkg b/completions/dpkg
index c0674d78017..b51ee10f33f 100644
--- a/completions/dpkg
+++ b/completions/dpkg
@@ -7,7 +7,7 @@ _comp_xfunc_dpkg_compgen_installed_packages()
         grep-status -P -e "^${cur-}" -a \
             -FStatus 'ok installed' \
             -n -s Package 2>/dev/null ||
-            command awk -F '\n' -v RS="" "
+            _comp_awk -F '\n' -v RS="" "
             index(\$1, \"Package: ${cur-}\") == 1 &&
             \$2 ~ /ok installed|half-installed|unpacked|half-configured|^Essential: yes/ {
                 print(substr(\$1, 10));
@@ -22,7 +22,7 @@ _comp_xfunc_dpkg_compgen_purgeable_packages()
         grep-status -P -e "^${cur-}" -a \
             -FStatus 'ok installed' -o -FStatus 'ok config-files' \
             -n -s Package 2>/dev/null ||
-            command awk -F '\n' -v RS="" "
+            _comp_awk -F '\n' -v RS="" "
             index(\$1, \"Package: ${cur-}\") == 1 &&
             \$2 ~ /ok installed|half-installed|unpacked|half-configured|config-files|^Essential: yes/ {
                 print(substr(\$1, 10));
diff --git a/completions/iwconfig b/completions/iwconfig
index c57f15b7892..4c0bf894cee 100644
--- a/completions/iwconfig
+++ b/completions/iwconfig
@@ -15,7 +15,7 @@ _comp_cmd_iwconfig()
             _comp_compgen -- -W 'on off any'
             if [[ ${BASH_COMPLETION_CMD_IWCONFIG_SCAN-${COMP_IWLIST_SCAN-}} ]]; then
                 _comp_compgen -a split -- "$(iwlist "${words[1]}" scan |
-                    awk -F'\"' '/ESSID/ {print $2}')"
+                    _comp_awk -F '\"' '/ESSID/ {print $2}')"
             fi
             return
             ;;
@@ -38,7 +38,7 @@ _comp_cmd_iwconfig()
             _comp_compgen -- -W 'on off any'
             if [[ ${BASH_COMPLETION_CMD_IWCONFIG_SCAN-${COMP_IWLIST_SCAN-}} ]]; then
                 _comp_compgen -a split -- "$(iwlist "${words[1]}" scan |
-                    awk -F ': ' '/Address/ {print $2}')"
+                    _comp_awk -F ': ' '/Address/ {print $2}')"
             fi
             return
             ;;
diff --git a/completions/make b/completions/make
index 64c4de1db49..2f07b67146e 100644
--- a/completions/make
+++ b/completions/make
@@ -15,7 +15,7 @@ _comp_cmd_make__extract_targets()
     [[ $mode == -d && $prefix == */* ]] &&
         prefix_replace=${prefix##*/}
 
-    awk -f "${BASH_SOURCE[0]%/*}/../helpers/make-extract-targets.awk"
+    _comp_awk -f "${BASH_SOURCE[0]%/*}/../helpers/make-extract-targets.awk"
 }
 
 # Truncate the non-unique filepaths in COMPREPLY to only generate unique
diff --git a/completions/portinstall b/completions/portinstall
index fa658e74ec7..dc1a933e219 100644
--- a/completions/portinstall
+++ b/completions/portinstall
@@ -16,7 +16,7 @@ _comp_cmd_portinstall()
         indexfile=$portsdir/INDEX
     [[ -f $indexfile && -r $indexfile ]] || return
 
-    _comp_compgen_split -l -- "$(awk -F '|' '
+    _comp_compgen_split -l -- "$(_comp_awk -F '|' '
         BEGIN { portsdir = ENVIRON["portsdir"]; len = length(portsdir) }
         { print $1 }
         substr($2, 1, len) == portsdir { print substr($2, len + 1) }
diff --git a/test/runLint b/test/runLint
index a50421d3042..e364a8841e2 100755
--- a/test/runLint
+++ b/test/runLint
@@ -21,7 +21,7 @@ filter_out=
 gitgrep $cmdstart"awk\b.*-F([[:space:]]|[[:space:]]*[\"'][^\"']{2,})" \
     'awk with -F char or -F ERE, use -Fchar instead (Solaris)'
 
-gitgrep $cmdstart"awk\b.*\[:[a-z]*:\]" \
+gitgrep $cmdstart"(_comp_)?awk\b.*\[:[a-z]*:\]" \
     'awk with POSIX character class not supported in mawk (Debian/Ubuntu)'
 
 gitgrep $cmdstart'sed\b.*\\[?+]' \

From 302dc52b9b02dc9a8fa9b1833012b3c4f96b6d7b Mon Sep 17 00:00:00 2001
From: Koichi Murase <myoga.murase@gmail.com>
Date: Mon, 20 Nov 2023 06:46:16 +0900
Subject: [PATCH 4/4] fix(perl): fix ineffective condition in an awk script

The condition `$NF=2` in the awk script actually assigns a value `2`
to the last field instead of comparing it to `2` and always evaluates
to true.  I suspect it to be `NF >= 2`.

This could possibly be intended as `NF == 2` or `$NF == 2`, but
neither seems to work correctly.  The input contains the names of man
entries of the form ` perlxx <description>`, but the description is
usually given by more than one words, so restricting them by `NF == 2`
would be unreasonable.  On the other hand, there are no entries ending
with the word `2` so `$NF == 2` would produce no results.  This
condition was introduced from the beginning when the related code was
introduced in commit 4254f3a4.  There does not seem to be any hints on
the background of `$NF=2`.
---
 completions/perl | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/completions/perl b/completions/perl
index 0938d736ae3..f4eebd4fff4 100644
--- a/completions/perl
+++ b/completions/perl
@@ -132,7 +132,7 @@ _comp_cmd_perldoc()
             if [[ $cur == p* ]]; then
                 _comp_compgen -a split -- "$(PERLDOC_PAGER=cat "$1" -u perl |
                     command sed -ne '/perl.*Perl overview/,/perlwin32/p' |
-                    awk '$NF=2 && $1 ~ /^perl/ { print $1 }')"
+                    awk 'NF >= 2 && $1 ~ /^perl/ { print $1 }')"
             fi
         fi
         _comp_compgen -a filedir 'p@([lm]|od)'