build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    ext.kotlin_version = '1.3.41'
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.4.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
        classpath 'com.novoda:bintray-release:0.9.1'
    }
}

allprojects {
    repositories {
        google()
        jcenter()
    }
    tasks.withType(Javadoc) {
        options {
            encoding "UTF-8"
            charSet 'UTF-8'
            links "http://docs.oracle.com/javase/7/docs/api"
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}


def file = 'local.properties'
if (new File(file).exists()) {
    Properties properties = new Properties()
    properties.load(new FileInputStream(file))
    if ('true' == properties['bintray.enable']) {
        subprojects {
            if (name == ("library")) {
                afterEvaluate {
                    publish {
                        groupId = group
                        desc = description
                        publishVersion = version
                        artifactId = SMART_ARTIFACT
                        userOrg = properties['bintray.user']
                        bintrayKey = properties['bintray.key']
                        bintrayUser = properties['bintray.user']
                        dryRun = properties['bintray.dryRun'] ?: 'false'
                        website = "https://github.com/scwang90/${rootProject.name}"
                    }
                }
                apply plugin: 'com.novoda.bintray-release'
            }
        }

    }
}