publish_aar.gradle

apply plugin: 'maven-publish'
apply plugin: 'signing'

def sonatypeUsername = rootProject.hasProperty('ossrhUsername')? rootProject.ossrhUsername : ''
def sonatypePassword = rootProject.hasProperty('ossrhPassword')? rootProject.ossrhPassword : ''

group = publishedGroupId
version = libraryVersion

task sourcesJar(type: Jar) {
    archiveClassifier.set("sources")
    from android.sourceSets.main.java.srcDirs
}

//task javadoc(type: Javadoc) {
//    options.addStringOption('Xdoclint:none', '-quiet')
//    source = android.sourceSets.main.java.srcDirs
//    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
//}
//
//task javadocJar(type: Jar, dependsOn: javadoc) {
//    archiveClassifier.set("javadoc")
//    from javadoc.destinationDir
//}

afterEvaluate {
    publishing {
        publications {
            release(MavenPublication) {
                artifactId = artifact
                from components.release
//                artifact javadocJar
                artifact sourcesJar
                pom {
                    name = artifact
                    description = libraryDescription
                    url = siteUrl
                    licenses {
                        license {
                            name = licenseName
                            url = licenseUrl
                        }
                    }
                    developers {
                        developer {
                            id = developerId
                            name = developerName
                            email = developerEmail
                        }
                    }
                    scm {
                        connection = gitUrl
                        developerConnection = gitUrl
                        url = siteUrl
                    }
                }
            }
        }
        repositories {
            maven {
                def releasesRepoUrl = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
                def snapshotsRepoUrl = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
                url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
                credentials {
                    username = "${sonatypeUsername}"
                    password = "${sonatypePassword}"
                }
            }
        }
    }
}

signing {
    sign publishing.publications
}

//javadoc {
//    if (JavaVersion.current().isJava9Compatible()) {
//        options.addBooleanOption('html5', true)
//    }
//}