forked from bwaldvogel/liblinear-java
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
169 lines (141 loc) · 4.8 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
buildscript {
repositories {
mavenCentral()
}
}
plugins {
id 'java-library'
id 'maven-publish'
id 'signing'
id 'jacoco'
id 'com.github.kt3k.coveralls' version '2.10.2'
id 'de.undercouch.download' version '4.1.1'
id 'me.champeau.gradle.jmh' version '0.5.2'
}
group = "de.bwaldvogel"
version = '2.42'
sourceCompatibility = 1.8
targetCompatibility = 1.8
compileJava.options.encoding = 'UTF-8'
ext {
title = 'liblinear'
}
jar {
manifest {
attributes 'Implementation-Title': title, 'Implementation-Version': archiveVersion
}
}
task sourceJar(type: Jar) {
archiveClassifier = "sources"
from sourceSets.main.allJava
}
task javadocJar(type: Jar, dependsOn: javadoc) {
archiveClassifier = "javadoc"
from javadoc.destinationDir
}
publishing {
publications {
mavenJava(MavenPublication) {
groupId = 'de.bwaldvogel'
artifactId = 'liblinear'
version = project.version
pom {
name = title
description = 'Java port of Liblinear'
url = 'https://github.com/bwaldvogel/liblinear'
inceptionYear = '2008'
licenses {
license {
name = 'The BSD License'
url = 'http://www.opensource.org/licenses/bsd-license.php'
distribution = 'repo'
}
}
developers {
developer {
id = 'bwaldvogel'
name = 'Benedikt Waldvogel'
email = 'mail@bwaldvogel.de'
}
}
scm {
url = 'git@github.com:bwaldvogel/liblinear.git'
connection = 'scm:git:git@github.com:bwaldvogel/liblinear.git'
developerConnection = 'scm:git:git@github.com:bwaldvogel/liblinear.git'
}
}
from components.java
artifact sourceJar
artifact javadocJar
versionMapping {
usage('java-api') {
fromResolutionOf('runtimeClasspath')
}
usage('java-runtime') {
fromResolutionResult()
}
}
}
}
repositories {
maven {
url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
credentials {
username = project.hasProperty('nexusUsername') ? project.property('nexusUsername') : System.getenv('NEXUS_USERNAME')
password = project.hasProperty('nexusPassword') ? project.property('nexusPassword') : System.getenv('NEXUS_PASSWORD')
}
}
}
}
signing {
useGpgCmd()
sign publishing.publications.mavenJava
}
repositories {
mavenCentral()
}
jacocoTestReport {
reports {
html.enabled = true
xml.enabled = true
csv.enabled = false
}
dependsOn test
}
apply from: 'datasets.gradle'
test.dependsOn downloadAndVerifyDatasets
test {
useJUnitPlatform()
maxHeapSize = "256m"
}
wrapper {
gradleVersion = "6.8"
distributionType = Wrapper.DistributionType.ALL
}
jmh {
include = ['de\\.bwaldvogel\\.liblinear\\.LinearBenchmark.*']
jvmArgs = ["-Ddataset.directory=" + projectDir + "/src/test/datasets"]
}
tasks['jmh'].dependsOn downloadAndVerifyRcv1
dependencies {
testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: 'latest.release'
testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-params', version: 'latest.release'
testRuntimeOnly group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: 'latest.release'
testImplementation group: 'org.slf4j', name: 'slf4j-api', version: 'latest.release'
testImplementation group: 'org.assertj', name: 'assertj-core', version: 'latest.release'
testImplementation group: 'org.mockito', name: 'mockito-core', version: 'latest.release'
testImplementation group: 'nl.jqno.equalsverifier', name: 'equalsverifier', version: 'latest.release'
testRuntimeOnly group: 'ch.qos.logback', name: 'logback-classic', version: 'latest.release'
jmh group: 'org.apache.commons', name: 'commons-compress', version: 'latest.release'
jmh 'org.openjdk.jmh:jmh-generator-annprocess:latest.release' // for IntelliJ
// https://mvnrepository.com/artifact/org.mapdb/mapdb
compile group: 'org.mapdb', name: 'mapdb', version: '3.0.8'
components.all { ComponentMetadataDetails details ->
details.statusScheme = ['candidate', 'release']
if (details.id.version =~ /(?i).+([-.])(CANDIDATE|RC|BETA|ALPHA).*/) {
details.status = 'candidate'
} else {
details.status = 'release'
}
}
}