forked from cobbal/semantics-recursive-real-ppl
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Compatibility.v
749 lines (676 loc) · 17.6 KB
/
Compatibility.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
Require Import Coq.Program.Program.
Require Import Coq.Program.Tactics.
Require Import Coq.Classes.Morphisms.
Require Import Coq.Reals.Reals.
Require Import Coquelicot.Rbar.
Require Import Coquelicot.Lim_seq.
Require Import Coq.fourier.Fourier.
Require Import Autosubst.Autosubst.
Require Import Coq.Logic.Classical.
Require Import Coq.Logic.ClassicalDescription.
Require Import Coq.Logic.ClassicalEpsilon.
Require Import Coq.Logic.ProofIrrelevance.
Require Import Coq.omega.Omega.
Require Import Init.Wf.
Require Import Biorthogonality.Basics.
Require Import Biorthogonality.Measures.
Require Import Biorthogonality.LogRel.
Require Import Biorthogonality.Syntax.
Require Import Biorthogonality.OpSem.
Require Import Biorthogonality.MeasSem.
Set Bullet Behavior "Strict Subproofs".
Open Scope nat.
(* Lemma 3.1 *)
(* Vrel compatibility *)
(** Sub-lemma: variables are value-compatible *)
Lemma Vrel_Var_compatible :
forall Γ x,
x < Γ ->
Vrel_open Γ (Var x) (Var x).
Proof.
unfold Vrel_open, Grel.
cbn.
intuition.
Qed.
Hint Resolve Vrel_Var_compatible.
Lemma Vrel_Const_compatible_closed :
forall m r,
Vrel m (Const r) (Const r).
Proof.
intros.
rewrite Vrel_Fix_eq.
unfold Vrel_rec.
intuition constructor.
Qed.
Hint Resolve Vrel_Const_compatible_closed.
Lemma Vrel_Const_compatible :
forall Γ r,
Vrel_open Γ (Const r) (Const r).
Proof.
unfold Vrel_open, Grel.
intros.
cbn.
apply Vrel_Const_compatible_closed.
Qed.
Hint Resolve Vrel_Const_compatible.
(** Sub-lemma: λ-expressions are value-compatible *)
Lemma Vrel_Fun_compatible :
forall Γ e1 e2,
Erel_open (S Γ) e1 e2 ->
Vrel_open Γ (Fun e1) (Fun e2).
Proof.
intros.
unfold Vrel_open; intros.
inversion H0 as [? [? ?]].
cbn.
rewrite Vrel_Fix_eq.
unfold Vrel_rec at 1.
intuition idtac.
- constructor.
apply -> sub_preserves_scope_exp; eauto.
- constructor.
apply -> sub_preserves_scope_exp; eauto.
- asimpl.
eapply H.
eauto.
Qed.
Hint Resolve Vrel_Fun_compatible.
(* Pitts Lemma 4.2 part 1 *)
Lemma Krel_cons :
forall n (e1 e2 : Expr),
(forall m v1 v2, m <= n -> Vrel m v1 v2 -> Erel m (e1.[v1/]) (e2.[v2/])) ->
forall m K1 K2, m <= n -> Krel m K1 K2 -> Krel m (e1-:K1) (e2-:K2).
Proof.
intros.
destruct (Erel_closed (H m (Const 0) (Const 0) ltac:(auto) ltac:(auto)))
as [Hclosed_e1 Hclosed_e2].
apply sub_implies_scope_exp_1 in Hclosed_e1.
apply sub_implies_scope_exp_1 in Hclosed_e2.
unfold Krel, Krel'; intros.
destruct (Krel_closed H1) as [Hclosed_K1 Hclosed_K2].
split; [|split]; try solve [constructor; auto].
intros.
destruct (Vrel_closed H2) as [IsClosed_v1 IsClosed_v2].
run_μeval_for 1.
run_μeval_star_for 1.
apply H with (m:=m0); eauto.
Qed.
Hint Resolve Krel_cons.
(* Pitts Lemma 4.2 part 1 *)
Lemma Expr_cons :
forall n (e1 e2 : Expr),
(forall m (Hmn : m <= n) v1 v2,
Vrel m v1 v2 -> Erel m e1.[v1/] e2.[v2/]) ->
forall m (Hmn : m <= n) e1' e2',
Erel m e1' e2' ->
Erel m (Seq e1' e1) (Seq e2' e2).
Proof.
intros.
destruct (Erel_closed H0) as [IsClosed_e1 IsClosed_e2].
unfold Erel, Erel'.
split; [|split];
try solve [specialize (H 0 ltac:(auto) _ _ (Vrel_Const_compatible_closed 0 0));
constructor; eauto using sub_implies_scope_exp_1].
intros.
run_μeval_for 1.
run_μeval_star_for 1.
eapply H0; eauto 6.
Qed.
Hint Resolve Expr_cons.
(** Sub-lemma: e ::= v *)
Lemma Erel_Val_compatible_closed :
forall {n v v'},
Vrel n v v' ->
Erel n v v'.
Proof.
intros.
unfold Erel, Erel'.
pose proof (Vrel_possibilities H).
intuition eauto;
match goal with
| [H : Krel' _ _ _ _ |- _] => apply H; eauto
end.
Qed.
Hint Resolve Erel_Val_compatible_closed.
Lemma Erel_Val_compatible :
forall {Γ v v'},
Vrel_open Γ v v' ->
Erel_open Γ v v'.
Proof.
intros.
unfold Erel_open, Vrel_open in *.
auto.
Qed.
Hint Resolve Erel_Val_compatible.
Lemma Erel_Var_compatible :
forall Γ x,
x < Γ ->
Erel_open Γ (Var x) (Var x).
Proof.
auto.
Qed.
Hint Resolve Erel_Var_compatible.
Lemma Erel_Const_compatibile :
forall Γ r,
Erel_open Γ (Const r) (Const r).
Proof.
auto.
Qed.
Hint Resolve Erel_Var_compatible.
(* Sub-lemma: compatible under Fun *)
Lemma Erel_Fun_compatible :
forall Γ e e',
Erel_open (S Γ) e e' ->
Erel_open Γ (Fun e) (Fun e').
Proof.
auto.
Qed.
Hint Resolve Erel_Fun_compatible.
Lemma Erel_Seq_compatible :
forall Γ (e1 e2 e1' e2': Expr),
Erel_open (S Γ) e1 e2 ->
Erel_open Γ e1' e2' ->
Erel_open Γ (Seq e1' e1) (Seq e2' e2).
Proof.
intros.
unfold Erel_open.
intros.
cbn.
eapply Expr_cons; auto.
intros.
asimpl.
eauto.
Qed.
Hint Resolve Erel_Seq_compatible.
Lemma Vrel_open_Erel_open :
forall Γ v v',
Vrel_open Γ v v' -> Erel_open Γ v v'.
Proof.
eauto.
Qed.
Hint Resolve Vrel_open_Erel_open.
Lemma Erel_App_compatible_closed : forall n v1 v1' v2 v2',
Vrel n v1 v2 ->
Vrel n v1' v2' ->
Erel n (App v1 v1') (App v2 v2').
Proof.
intros.
destruct (Vrel_closed H).
destruct (Vrel_closed H0).
unfold Erel, Erel'.
split; [|split];
destruct (Vrel_possibilities H) as [[r [? ?]]|[b1 [b2 [? ?]]]];
subst;
try solve [constructor; auto];
intros;
try solve [constructor; auto;
rewrite Vrel_Fix_eq in H0;
unfold Vrel_rec at 1 in H0;
destruct v1', v2';
intuition].
- run_μeval.
- run_μeval_for 1.
run_μeval_star_for 1.
erewrite Vrel_Fix_eq in H.
unfold Vrel_rec in H at 1.
eapply H; eauto.
Qed.
Hint Resolve Erel_App_compatible_closed.
(* Sub-lemma *)
Lemma Erel_App_compatible : forall Γ v1 v1' v2 v2',
Vrel_open Γ v1 v2 ->
Vrel_open Γ v1' v2' ->
Erel_open Γ (App v1 v1') (App v2 v2').
Proof.
intros.
unfold Vrel_open in H.
unfold Vrel_open in H0.
unfold Erel_open.
asimpl.
eauto.
Qed.
Hint Resolve Erel_App_compatible.
Lemma Erel_Op1_compatible_closed : forall n o v1 v2,
Vrel n v1 v2 ->
Erel n (Op1 o v1) (Op1 o v2).
Proof.
intros.
destruct (Vrel_closed H).
unfold Erel, Erel'.
split; [|split];
destruct (Vrel_possibilities H) as [[r [? ?]]|[b1 [b2 [? ?]]]];
subst;
try solve [constructor; auto];
intros;
try solve [constructor; auto;
rewrite Vrel_Fix_eq in H0;
unfold Vrel_rec at 1 in H0;
destruct v1', v2';
intuition].
- destruct m; auto.
{ rewrite μeval_0.
apply μeval_star_nonnegative.
}
destruct o.
+ destruct (Req_EM_T 0 r); subst.
* rewrite μeval_step_Op1_Log_0.
apply μeval_star_nonnegative.
* rewrite μeval_step_Op1_Log; auto.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op1_Log; auto.
apply H2; auto.
+ rewrite μeval_step_Op1_Exp.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op1_Exp.
apply H2; auto.
+ rewrite μeval_step_Op1_Realp_1.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op1_Realp_1.
apply H2; auto.
- destruct m; auto.
{ rewrite μeval_0.
apply μeval_star_nonnegative.
}
destruct o;
try solve [unfold μeval;
unfold eval;
cbn;
repeat rewrite integrate_0;
apply μeval_star_nonnegative].
rewrite μeval_step_Op1_Realp_0.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op1_Realp_0.
apply H2; auto.
Qed.
Hint Resolve Erel_Op1_compatible_closed.
Lemma Erel_Op1_compatible : forall Γ o v1 v2,
Vrel_open Γ v1 v2 ->
Erel_open Γ (Op1 o v1) (Op1 o v2).
Proof.
intros.
unfold Vrel_open in H.
unfold Erel_open.
asimpl.
eauto.
Qed.
Hint Resolve Erel_Op1_compatible.
Lemma Erel_Op2_compatible_closed : forall n o v1 v1' v2 v2',
Vrel n v1 v2 ->
Vrel n v1' v2' ->
Erel n (Op2 o v1 v1') (Op2 o v2 v2').
Proof.
intros.
destruct (Vrel_closed H).
destruct (Vrel_closed H0).
unfold Erel, Erel'.
split; [|split];
destruct (Vrel_possibilities H) as [[r [? ?]]|[b1 [b2 [? ?]]]];
destruct (Vrel_possibilities H0) as [[r' [? ?]]|[b1' [b2' [? ?]]]];
subst;
try solve [constructor; auto];
intros;
try solve [constructor; auto;
rewrite Vrel_Fix_eq in H0;
unfold Vrel_rec at 1 in H0;
destruct v1', v2';
intuition
|replace (μeval m _ _) with (Finite 0%R);
[apply μeval_star_nonnegative|];
destruct m;
[rewrite μeval_0; auto|];
destruct o;
unfold μeval;
unfold eval;
cbn;
repeat rewrite integrate_0;
auto].
destruct m; auto.
{ rewrite μeval_0.
apply μeval_star_nonnegative.
}
destruct o.
+ rewrite μeval_step_Op2_Plus.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op2_Plus.
apply H5; auto.
+ rewrite μeval_step_Op2_Minus.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op2_Minus.
apply H5; auto.
+ rewrite μeval_step_Op2_Times.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op2_Times.
apply H5; auto.
+ destruct (Req_EM_T 0 r'); subst.
* rewrite μeval_step_Op2_Div_0.
apply μeval_star_nonnegative.
* rewrite μeval_step_Op2_Div; auto.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op2_Div; auto.
apply H5; auto.
+ destruct (Rlt_dec r r').
* rewrite μeval_step_Op2_Lt_1; auto.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op2_Lt_1; auto.
apply H5; auto.
* rewrite μeval_step_Op2_Lt_0; auto using Rnot_lt_le.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op2_Lt_0; auto using Rnot_lt_le.
apply H5; auto.
+ destruct (Rle_dec r r').
* rewrite μeval_step_Op2_Le_1; auto.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op2_Le_1; auto.
apply H5; auto.
* rewrite μeval_step_Op2_Le_0; auto using Rnot_le_lt.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Op2_Le_0; auto using Rnot_le_lt.
apply H5; auto.
+ replace (μeval m _ K1 A) with (Finite 0);
auto.
destruct m; auto.
* rewrite μeval_0; auto.
* unfold μeval.
unfold eval.
destruct o;
cbn;
repeat rewrite integrate_0;
auto.
+ replace (μeval m _ K1 A) with (Finite 0);
auto.
destruct m; auto.
* rewrite μeval_0; auto.
* unfold μeval.
unfold eval.
destruct o;
cbn;
repeat rewrite integrate_0;
auto.
+ replace (μeval m _ K1 A) with (Finite 0);
auto.
destruct m; auto.
* rewrite μeval_0; auto.
* unfold μeval.
unfold eval.
destruct o;
cbn;
repeat rewrite integrate_0;
auto.
Qed.
Hint Resolve Erel_Op2_compatible_closed.
Lemma Erel_Op2_compatible : forall Γ o v1 v1' v2 v2',
Vrel_open Γ v1 v2 ->
Vrel_open Γ v1' v2' ->
Erel_open Γ (Op2 o v1 v1') (Op2 o v2 v2').
Proof.
intros.
unfold Vrel_open in H.
unfold Erel_open.
asimpl.
eauto.
Qed.
Hint Resolve Erel_Op2_compatible.
Lemma Erel_Cond_compatible_closed : forall n vp vp' et et' ef ef',
Vrel n vp vp' ->
Erel n et et' ->
Erel n ef ef' ->
Erel n (Cond vp et ef) (Cond vp' et' ef').
Proof.
intros.
destruct (Vrel_closed H).
destruct (Erel_closed H0).
destruct (Erel_closed H1).
unfold Erel, Erel'.
split; [|split];
destruct (Vrel_possibilities H) as [[r [? ?]]|[b1 [b2 [? ?]]]];
subst;
try solve [constructor; auto];
intros;
try solve [constructor; auto;
rewrite Vrel_Fix_eq in H0;
unfold Vrel_rec at 1 in H0;
destruct v1', v2';
intuition
|replace (μeval m _ _) with (Finite 0%R);
[apply μeval_star_nonnegative|];
destruct m;
[rewrite μeval_0; auto|];
unfold μeval;
unfold eval;
cbn;
repeat rewrite integrate_0;
auto].
destruct m; auto.
{ rewrite μeval_0.
apply μeval_star_nonnegative.
}
+ destruct (Rlt_dec 0 r).
* rewrite μeval_step_Cond_true; auto.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Cond_true; auto.
apply H0; eauto.
* rewrite μeval_step_Cond_false; auto using Rnot_lt_le.
erewrite μeval_star_step_1; revgoals.
intros.
apply μeval_step_Cond_false; auto using Rnot_lt_le.
apply H1; eauto.
+ replace (μeval m _ K1 A) with (Finite 0);
auto.
destruct m; auto.
* rewrite μeval_0; auto.
* unfold μeval.
unfold eval.
cbn.
repeat rewrite integrate_0.
auto.
Qed.
Hint Resolve Erel_Cond_compatible_closed.
Lemma Erel_Cond_compatible : forall Γ vp vp' et et' ef ef',
Vrel_open Γ vp vp' ->
Erel_open Γ et et' ->
Erel_open Γ ef ef' ->
Erel_open Γ (Cond vp et ef) (Cond vp' et' ef').
Proof.
intros.
unfold Vrel_open in H.
unfold Erel_open.
asimpl.
eauto.
Qed.
Hint Resolve Erel_Cond_compatible.
(* Sub-lemma *)
Lemma Krel_Knil_refl : forall n,
Krel n Knil Knil.
Proof.
intros.
unfold Krel, Krel'.
intuition auto.
destruct (Vrel_possibilities H) as [[r [? ?]]|[b1 [b2 [? ?]]]];
subst;
auto;
run_μeval_for 1.
Qed.
Hint Resolve Krel_Knil_refl.
Instance Sup_seq_Proper_ext : Proper (pointwise_relation nat eq==>eq) Sup_seq.
Proof.
unfold Proper, respectful, pointwise_relation.
intros.
apply Sup_seq_ext.
auto.
Qed.
(* Sub-lemma: compatible under factor *)
Lemma Erel_Factor_compatible_closed : forall n r1 r2,
Vrel n r1 r2 ->
Erel n (Factor r1) (Factor r2).
Proof.
unfold Erel, Erel'.
intuition eauto.
destruct (Vrel_possibilities H) as [[r [? ?]]|[b1 [b2 [? ?]]]];
subst;
eauto;
revgoals;
try solve [run_μeval_for 1].
destruct (Rbar_lt_dec 0%R r); revgoals.
{ replace (μeval m (Factor (Const r)) K1 A)
with (Finite 0%R).
apply μeval_star_nonnegative.
unfold μeval.
rewrite <- integrate_0.
rewrite <- integrate_0.
f_equal.
extensionality σ2.
f_equal.
extensionality σ1.
destruct m; auto.
unfold eval.
cbn.
destruct Rlt_dec; try contradiction; auto.
}
run_μeval_for 1.
replace (μeval_star _ _ _) with (Rbar_mult r (μeval_star (Const r) K2 A)).
{ apply Rbar_mult_le_compat_l; cbn in *; auto.
apply H0; eauto.
}
rewrite μeval_lim_interchange with (e:=(Factor _)).
rewrite Sup_seq_incr_1; auto.
setoid_rewrite (μeval_step_Factor _ _ _ _ r0).
rewrite Sup_seq_scal_l; cbn in *; auto.
rewrite <- μeval_lim_interchange.
auto.
Qed.
Hint Resolve Erel_Factor_compatible_closed.
Lemma Erel_Factor_compatible : forall Γ r1 r2,
Vrel_open Γ r1 r2 ->
Erel_open Γ (Factor r1) (Factor r2).
Proof.
unfold Erel_open; intros.
asimpl.
eauto.
Qed.
Hint Resolve Erel_Factor_compatible.
Lemma Erel_Sample_compatible_closed : forall n,
Erel n Sample Sample.
Proof.
intros.
unfold Erel.
unfold Erel'.
intuition auto.
run_μeval_for 1; eauto.
rewrite μeval_star_step_Sample.
apply integrate_monotonic.
intros.
eapply H; auto.
Qed.
Hint Resolve Erel_Sample_compatible_closed.
Lemma Erel_Sample_compatible : forall Γ,
Erel_open Γ Sample Sample.
Proof.
unfold Erel_open.
auto.
Qed.
Hint Resolve Erel_Sample_compatible.
(* Theorem 3.2: Fundamental Theorem *)
Theorem Erel_Vrel_Fundamental_helper :
forall (e : Expr),
(forall Γ, EXP Γ ⊢ e -> Erel_open Γ e e) /\
(forall Γ, VAL Γ ⊢ e -> Vrel_open Γ e e).
Proof.
induction e;
intuition auto;
try solve_inversion.
- eapply Erel_App_compatible; eauto.
- eapply Erel_Seq_compatible; eauto.
- eapply Erel_Op1_compatible; eauto.
- eapply Erel_Op2_compatible; eauto.
- eapply Erel_Cond_compatible; eauto.
Qed.
Theorem Erel_Fundamental :
forall (e : Expr) (Γ : Env),
EXP Γ ⊢ e ->
Erel_open Γ e e.
Proof.
intros.
apply Erel_Vrel_Fundamental_helper.
auto.
Qed.
Hint Resolve Erel_Fundamental.
Theorem Vrel_Fundamental :
forall (v : Expr) (Γ : Env),
VAL Γ ⊢ v ->
Vrel_open Γ v v.
Proof.
intros.
apply Erel_Vrel_Fundamental_helper.
auto.
Qed.
Hint Resolve Vrel_Fundamental.
Theorem Krel_Fundamental_closed :
forall (K : Kont) (n : nat),
KCLOSED K ->
Krel n K K.
Proof.
induction K; intros.
- cbn.
auto.
- inversion H; subst.
apply Krel_cons with (n:=n); auto; intros; asimpl.
destruct (Vrel_closed H1) as [Hclosed_v1 Hclosed_v2].
eapply Erel_Fundamental; eauto.
unfold Grel.
intuition idtac.
+ apply cons_scope; auto.
+ apply cons_scope; auto.
+ inversion H4; subst; auto.
exfalso; auto.
Qed.
Hint Resolve Krel_Fundamental_closed.
Lemma Grel_ids : forall n, Grel n 0 ids ids.
Proof.
intros.
unfold Grel.
intuition auto using scope_ids.
exfalso; auto.
Qed.
Theorem Vrel_Fundamental_closed :
forall (v : Expr),
VCLOSED v ->
forall n, Vrel n v v.
Proof.
intros.
replace v with (v.[ids]) by autosubst.
eapply Vrel_Fundamental; eauto using Grel_ids.
Qed.
Hint Resolve Vrel_Fundamental_closed.
Theorem Erel_Fundamental_closed :
forall (e : Expr),
ECLOSED e ->
forall n, Erel n e e.
Proof.
intros.
replace e with (e.[ids]) by autosubst.
eapply Erel_Fundamental; eauto using Grel_ids.
Qed.
Hint Resolve Erel_Fundamental_closed.
Theorem Grel_Fundamental :
forall (γ : var -> Expr) (Γ : Env),
SUBSCOPE Γ ⊢ γ ∷ 0 ->
forall n, Grel n Γ γ γ.
Proof.
intros.
unfold Grel.
intuition.
Qed.
Hint Resolve Grel_Fundamental.