Save midi values to EEPROM

[Maikele1]

Hello Everyone,

I am currently working on a small MIDI fader/trim controller for an SD 833. The controller works splendidly, but it has one major issue.

The issue is that with every reboot, the MIDI values for both PitchBendSenders reset to zero. Consequently, it also resets to -inf on the mixer, which is undesirable.

I have attempted to save the value to EEPROM, but my only results are the device freezing when I switch modes. I am probably overlooking something obvious. Below is the code without any EEPROM-related stuff.

#include <Control_Surface.h> // https://github.com/tttapa/Control-Surface
#include <AH/Hardware/MultiPurposeButton.hpp>

// Instantiate a MIDI over USB interface.
USBMIDI_Interface midi;

DigitalNoteSender sender;

AHEncoder enc1{3, 2}; // Encoder 1
AHEncoder enc2{6, 5}; // Encoder 2

// Trim
BorrowedMIDIRotaryEncoder<RelativeCCSender> cc_enc1 {
  enc1,
  MCU::V_POT_7,
  1, 4, {},
};

// Fader
BorrowedMIDIAbsoluteEncoder<PitchBendSender<10>> pb_enc1 {
  enc1,
  Channel_7,
  6, 4, {},
};


// Trim
BorrowedMIDIRotaryEncoder<RelativeCCSender> cc_enc2 {
  enc2,
  MCU::V_POT_8,
  1, 4, {},
};

// Fader
BorrowedMIDIAbsoluteEncoder<PitchBendSender<10>> pb_enc2 {
  enc2,
  Channel_8,
  6, 4, {},
};

MultiPurposeButton btn1{7};
MultiPurposeButton btn2{4};
enum class EncoderMode {
  PitchBend, ControlChange
};
EncoderMode mode1 = EncoderMode::PitchBend;
EncoderMode mode2 = EncoderMode::PitchBend;

int ButtonMode1 = 0;
int ButtonMode2 = 0;

void setup() {
  Serial.begin(115200);
  btn1.setLongPressDelay(1000);
  btn1.setMultiPressDelay(400);
  btn1.begin();
  btn2.setLongPressDelay(1000);
  btn2.setMultiPressDelay(400);
  btn2.begin();
  RelativeCCSender::setMode(relativeCCmode::MACKIE_CONTROL_RELATIVE);
  // Disable the second encoder before calling Control_Surface.begin(),
  // so the encoder doesn't get initialized twice:
  cc_enc1.disable(); // Default state
  cc_enc2.disable(); // Default state

  Control_Surface.begin(); // Initialize Control Surface
  
}

void loop() {
  switch (btn1.update()) {
    case btn1.None: break;
    case btn1.LongPress:
      if(mode1 == EncoderMode::PitchBend) {
        Serial.println("cc");
        pb_enc1.disable();
        cc_enc1.resetPositionOffset();
        cc_enc1.enable();
        mode1 = EncoderMode::ControlChange;
      } else {
        Serial.println("pb");
        cc_enc1.disable();
        pb_enc1.resetPositionOffset();
        pb_enc1.enable();
        mode1 = EncoderMode::PitchBend;
      }
    break;
    case btn1.ShortPressRelease:
    sender.sendOn(MCU::SELECT_7);
    sender.sendOff(MCU::SELECT_7);
    break;
  }

  switch (btn2.update()) {
    case btn2.None: break;
    case btn2.LongPress:
      if(mode2 == EncoderMode::PitchBend) {
        Serial.println("cc");
        pb_enc2.disable();
        cc_enc2.resetPositionOffset();
        cc_enc2.enable();
        mode2 = EncoderMode::ControlChange;
      } else {
        Serial.println("pb");
        cc_enc2.disable();
        pb_enc2.resetPositionOffset();
        pb_enc2.enable();
        mode2 = EncoderMode::PitchBend;
      }
    break;
    case btn2.ShortPressRelease:
      sender.sendOn(MCU::SELECT_8);
      sender.sendOff(MCU::SELECT_8);
    break;
  }

  Control_Surface.loop(); // Update the Control Surface
}

[tttapa]

Please post the code with the EEPROM logic, including instructions on how to reproduce the crashes.

[Maikele1]

With the help of a friend I managed to get it working actually haha
Here's the working code if you're interested

#include <Control_Surface.h> // https://github.com/tttapa/Control-Surface
#include <AH/Hardware/MultiPurposeButton.hpp>
#include <EEPROM.h>

// Instantiate a MIDI over USB interface.
USBMIDI_Interface midi;

DigitalNoteSender sender;

AHEncoder enc1{3, 2}; // Encoder 1 on pins 2 and 3
AHEncoder enc2{6, 5}; // Encoder 2 on pins 5 and 6

const int EEPROM_ADDR_PB_ENC1 = 0;
const int EEPROM_ADDR_PB_ENC2 = 2;


int16_t readIntFromEEPROM(int address) {
  int16_t value = EEPROM.read(address) | (EEPROM.read(address + 1) << 8);
  return value;
}

void writeIntToEEPROM(int address, int16_t value) {
  EEPROM.write(address, value & 0xFF);
  EEPROM.write(address + 1, (value >> 8) & 0xFF);
}

// Trim
BorrowedMIDIRotaryEncoder<RelativeCCSender> cc_enc1 {
  enc1,
  MCU::V_POT_7,
  1, 4, {},
};

// Fader
BorrowedMIDIAbsoluteEncoder<PitchBendSender<10>> pb_enc1 {
  enc1,
  Channel_7,
  6, 4, {},
};

// Trim
BorrowedMIDIRotaryEncoder<RelativeCCSender> cc_enc2 {
  enc2,
  MCU::V_POT_8,
  1, 4, {},
};

// Fader
BorrowedMIDIAbsoluteEncoder<PitchBendSender<10>> pb_enc2 {
  enc2,
  Channel_8,
  6, 4, {},
};

MultiPurposeButton btn1{4}; // Button on pin 4
MultiPurposeButton btn2{7}; // Button on pin 7
enum class EncoderMode {
  PitchBend, ControlChange
};
EncoderMode mode1 = EncoderMode::PitchBend;
EncoderMode mode2 = EncoderMode::PitchBend;

void setup() {
  Serial.begin(115200);
  btn1.setLongPressDelay(1000);
  btn1.setMultiPressDelay(400);
  btn1.begin();
  btn2.setLongPressDelay(1000);
  btn2.setMultiPressDelay(400);
  btn2.begin();
  RelativeCCSender::setMode(relativeCCmode::MACKIE_CONTROL_RELATIVE);
  // Disable the second encoder before calling Control_Surface.begin(),
  // so the encoder doesn't get initialized twice:
  cc_enc1.disable(); // Default state
  cc_enc2.disable(); // Default state

  // Load Pitch Bend values from EEPROM
  int16_t pbValue1 = readIntFromEEPROM(EEPROM_ADDR_PB_ENC1);
  int16_t pbValue2 = readIntFromEEPROM(EEPROM_ADDR_PB_ENC2);
  pb_enc1.setValue(pbValue1);
  pb_enc2.setValue(pbValue2);

  Control_Surface.begin(); // Initialize Control Surface
}

void loop() {
  switch (btn1.update()) {
    case btn1.None: break;
    case btn1.LongPress:
      if (mode1 == EncoderMode::PitchBend) {
        Serial.println("cc");
        pb_enc1.disable();
        cc_enc1.resetPositionOffset();
        cc_enc1.enable();
        mode1 = EncoderMode::ControlChange;
      } else {
        Serial.println("pb");
        cc_enc1.disable();
        pb_enc1.resetPositionOffset();
        pb_enc1.enable();
        mode1 = EncoderMode::PitchBend;
      }
      break;
    case btn1.ShortPressRelease:
      sender.sendOn(MCU::SELECT_7);
      sender.sendOff(MCU::SELECT_7);
      break;
  }

  switch (btn2.update()) {
    case btn2.None: break;
    case btn2.LongPress:
      if (mode2 == EncoderMode::PitchBend) {
        Serial.println("cc");
        pb_enc2.disable();
        cc_enc2.resetPositionOffset();
        cc_enc2.enable();
        mode2 = EncoderMode::ControlChange;
      } else {
        Serial.println("pb");
        cc_enc2.disable();
        pb_enc2.resetPositionOffset();
        pb_enc2.enable();
        mode2 = EncoderMode::PitchBend;
      }
      break;
    case btn2.ShortPressRelease:
      sender.sendOn(MCU::SELECT_8);
      sender.sendOff(MCU::SELECT_8);
      break;
  }

  // Save Pitch Bend values to EEPROM
  writeIntToEEPROM(EEPROM_ADDR_PB_ENC1, pb_enc1.getValue());
  writeIntToEEPROM(EEPROM_ADDR_PB_ENC2, pb_enc2.getValue());

  Control_Surface.loop(); // Update the Control Surface
}

[tttapa]

Writing the values to EEPROM on every loop iteration will wear out your EEPROM in no time! You should use EEPROM.update instead of EEPROM.write to only perform a write operation if the value changed, and you should implement a timeout so you're not writing all intermediate values while a user is turning the encoder, only the final value once it hasn't been touched for a couple of milliseconds.