cmake_uninstall.cmake.in

if (NOT EXISTS "@CMAKE_BINARY_DIR@/install_manifest.txt")
    message(FATAL_ERROR "Cannot find install manifest: @CMAKE_BINARY_DIR@/install_manifest.txt")
endif (NOT EXISTS "@CMAKE_BINARY_DIR@/install_manifest.txt")

file(READ "@CMAKE_BINARY_DIR@/install_manifest.txt" files)
string(REGEX REPLACE "\n" ";" files "${files}")
foreach (file ${files})
    message(STATUS "Uninstalling $ENV{DESTDIR}${file}")
    if (IS_SYMLINK "$ENV{DESTDIR}${file}" OR EXISTS "$ENV{DESTDIR}${file}")
        exec_program(
            "@CMAKE_COMMAND@" ARGS "-E remove \"$ENV{DESTDIR}${file}\""
            OUTPUT_VARIABLE rm_out
            RETURN_VALUE rm_retval
        )

        if (NOT "${rm_retval}" STREQUAL 0)
            message(FATAL_ERROR "Problem when removing $ENV{DESTDIR}${file}")
        endif (NOT "${rm_retval}" STREQUAL 0)

    else (IS_SYMLINK "$ENV{DESTDIR}${file}" OR EXISTS "$ENV{DESTDIR}${file}")
        message(STATUS "File $ENV{DESTDIR}${file} does not exist.")
    endif (IS_SYMLINK "$ENV{DESTDIR}${file}" OR EXISTS "$ENV{DESTDIR}${file}")

endforeach (file)

# Remove package-specific directories
if (UNIX)
    # Remove package-specific header directory
    if (NOT "@INSTALL_INCLUDEDIR@" STREQUAL "include" AND NOT "@INSTALL_INCLUDEDIR@" STREQUAL "")
        set(INSTALL_INCLUDEDIR $ENV{DESTDIR}@CMAKE_INSTALL_PREFIX@/@INSTALL_INCLUDEDIR@)
        if (EXISTS "${INSTALL_INCLUDEDIR}")
            exec_program(
                "@CMAKE_COMMAND@" ARGS "-E remove_directory ${INSTALL_INCLUDEDIR}")
        endif (EXISTS "${INSTALL_INCLUDEDIR}")
    endif (NOT "@INSTALL_INCLUDEDIR@" STREQUAL "include" AND NOT "@INSTALL_INCLUDEDIR@" STREQUAL "")

    # Remove package-specific cmake directory
    set(INSTALL_CMAKE_DIR $ENV{DESTDIR}@CMAKE_INSTALL_PREFIX@/@CMAKE_INSTALL_LIBDIR@/cmake/@CMAKE_PROJECT_NAME@)
    if (EXISTS "${INSTALL_CMAKE_DIR}")
        exec_program(
            "@CMAKE_COMMAND@" ARGS "-E remove_directory ${INSTALL_CMAKE_DIR}")
    endif (EXISTS "${INSTALL_CMAKE_DIR}")
endif (UNIX)