-
Notifications
You must be signed in to change notification settings - Fork 38
/
build.gradle.kts
92 lines (82 loc) · 2.96 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
import com.android.build.gradle.BaseExtension
import com.github.benmanes.gradle.versions.updates.DependencyUpdatesTask
import com.github.benmanes.gradle.versions.updates.gradle.GradleReleaseChannel
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
import org.jlleitschuh.gradle.ktlint.reporter.ReporterType
buildscript {
repositories {
google()
mavenCentral()
maven("https://plugins.gradle.org/m2/")
}
}
plugins {
alias(libs.plugins.agp) apply false
alias(libs.plugins.kotlin) apply false
alias(libs.plugins.compose.compiler) apply false
alias(libs.plugins.serialization) apply false
alias(libs.plugins.dependencyVersions) apply true
alias(libs.plugins.ktlint) apply true
}
allprojects {
apply(plugin = "org.jlleitschuh.gradle.ktlint")
ktlint {
reporters {
reporter(ReporterType.CHECKSTYLE)
}
filter {
include("*.kt", "*.kts")
exclude("**/generated/**")
}
tasks.withType<org.jlleitschuh.gradle.ktlint.tasks.GenerateReportsTask> {
reportsOutputDirectory.set(project.layout.buildDirectory.dir("reports/ktlint"))
}
}
}
subprojects {
afterEvaluate {
tasks.withType<KotlinCompile>().configureEach {
compilerOptions {
jvmTarget.set(JvmTarget.JVM_17)
freeCompilerArgs.add("-Xcontext-receivers")
}
}
extensions.findByType<BaseExtension>() ?: return@afterEvaluate
configure<BaseExtension> {
compileSdkVersion(libs.versions.compileSdk.get().toInt())
defaultConfig {
minSdk = libs.versions.minSdk.get().toInt()
targetSdk = libs.versions.targetSdk.get().toInt()
versionName = libs.versions.versionName.get()
versionCode = libs.versions.versionCode.get().toInt()
testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
}
compileOptions {
sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17
}
testOptions {
animationsDisabled = true
}
}
}
}
tasks.named<DependencyUpdatesTask>("dependencyUpdates").configure {
checkForGradleUpdate = true
gradleReleaseChannel = GradleReleaseChannel.RELEASE_CANDIDATE.id
revision = "integration"
outputFormatter = "plain"
outputDir = "build/dependencyUpdates"
reportfileName = "dependency_update_report"
}
tasks.withType<Test>().configureEach {
reports.html.required.set(false)
reports.junitXml.required.set(true)
maxParallelForks = Runtime.getRuntime().availableProcessors()
}
// Change gradleVersion and run gradlew wrapper to properly update gradle wrapper
tasks.named<Wrapper>("wrapper") {
distributionType = Wrapper.DistributionType.BIN
gradleVersion = "8.10.1"
}