build.gradle

group 'name.yulong'
version '1.0-SNAPSHOT'

buildscript {
    ext{
        kotlin_version = '1.1.4-3'
        shadow_version = '2.0.1'
    }

    repositories {
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "com.github.jengelman.gradle.plugins:shadow:$shadow_version"
    }
}

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'application'
apply plugin: "com.github.johnrengelman.shadow"

sourceCompatibility = 1.8
mainClassName = 'io.vertx.core.Launcher'

def vertx_version= '3.4.2'
def mainVerticleName = 'name.yulong.web.MainVerticle'

repositories {
    jcenter()
    mavenCentral()
}

dependencies {
    //kt运行时环境
    compile "org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlin_version"

    //vertx依赖
    compile "io.vertx:vertx-core:$vertx_version"
    compile "io.vertx:vertx-web:$vertx_version"


    testCompile group: 'junit', name: 'junit', version: '4.12'
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

run {
    args = ['run', mainVerticleName,
            "--launcher-class=$mainClassName",
            "--redeploy=src/**/*.*",
            "--on-redeploy=./gradlew classes"
    ]
}

shadowJar {
    baseName = 'app'
    classifier = 'shadow'

    manifest {
        attributes 'Main-Verticle': mainVerticleName
    }
    mergeServiceFiles {
        include 'META-INF/services/io.vertx.core.spi.VerticleFactory'
    }
}