forked from nats-io/nats.java
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
217 lines (192 loc) · 6.53 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
plugins {
id 'java-library'
id 'java'
id 'jacoco'
id 'maven'
id 'signing'
id 'com.github.kt3k.coveralls' version '2.6.3'
id "io.codearte.nexus-staging" version "0.11.0"
id 'osgi'
}
// Update version here, repeated check-ins not into master will have snapshot on them
// Be sure to update Nats.java with the latest version, the change log and the package-info.java
def versionMajor = 2
def versionMinor = 4
def versionPatch = 1
def versionModifier = ""
def jarVersion = "2.4.1"
def branch = System.getenv("TRAVIS_BRANCH");
def getVersionName = { ->
if ("true".equals(System.getenv("TRAVIS_PULL_REQUEST")) || !"master".equals(branch)) {
versionModifier = "-SNAPSHOT"
}
if (versionModifier != null && versionModifier.length() > 0) {
return "" + versionMajor + "." + versionMinor + "." + versionPatch + versionModifier
} else {
return "" + versionMajor + "." + versionMinor + "." + versionPatch
}
}
version = getVersionName()
archivesBaseName = 'jnats'
group = 'io.nats'
// Get signing properties set up from outside (env var can't handle the dot)
if (System.getenv('SONATYPE_USERNAME') != null) {
project.ext['ossrhUsername'] = System.getenv('SONATYPE_USERNAME')
project.ext['ossrhPassword'] = System.getenv('SONATYPE_PASSWORD')
project.ext['signing.secretKeyRingFile'] = System.getenv('GPG_KEYRING_FILE')
project.ext['signing.keyId'] = System.getenv('GPG_KEY_ID')
project.ext['signing.password'] = System.getenv('GPG_KEY_PASSPHRASE')
}
tasks.withType(Sign) {
onlyIf { "master".equals(branch) }
}
repositories {
jcenter()
}
dependencies {
compile 'net.i2p.crypto:eddsa:0.3.0'
testImplementation 'junit:junit:4.12'
}
sourceSets {
main {
java {
srcDirs = ['src/main/java','src/examples/java']
}
}
test {
java {
srcDirs = ['src/test/java']
}
}
}
osgiClasses {
exclude("io/nats/examples/**")
}
jar {
manifest {
attributes('Implementation-Title': 'Java Nats',
'Implementation-Version': jarVersion,
'Implementation-Vendor': 'nats.io')
instruction "Import-Package", "!net.i2p.crypto.eddsa.math"
instruction "Import-Package", "net.i2p*"
instruction "Import-Package", "io.nats*"
}
exclude("io/nats/examples/**")
}
test {
maxHeapSize = "2g"
if (org.gradle.internal.os.OperatingSystem.current().isLinux()) {
jvmArgs '-Djava.security.egd=file:/dev/./urandom'
}
testLogging {
exceptionFormat = 'full'
events "started", "passed", "skipped", "failed"
}
}
javadoc {
options.overview = 'src/main/javadoc/overview.html' // relative to source root
source = sourceSets.main.allJava
title = "NATS.IO Java API"
excludes = ['io/nats/client/impl', 'io/nats/examples']
classpath = sourceSets.main.runtimeClasspath
doLast {
exec {
println "Updating favicon on all html files"
workingDir 'build/docs/javadoc'
// Only on linux, mac at this point
commandLine 'find', '.', '-name', '*.html', '-exec', 'sed', '-i', '-e', 's#<head>#<head><link rel="icon" type="image/ico" href="favicon.ico">#', '{}', ';'
}
copy {
println "Copying images to javadoc folder"
from 'src/main/javadoc/images'
into 'build/docs/javadoc'
}
}
}
task examplesJar(type: Jar) {
classifier = 'examples'
manifest {
attributes('Implementation-Title': 'Java Nats Examples',
'Implementation-Version': jarVersion,
'Implementation-Vendor': 'nats.io')
}
from(sourceSets.main.output) {
include "io/nats/examples/**"
}
}
task javadocJar(type: Jar) {
classifier = 'javadoc'
from javadoc
}
task sourcesJar(type: Jar) {
classifier = 'sources'
from sourceSets.main.allSource
}
task fatJar(type: Jar) {
classifier = 'fat'
manifest {
attributes('Implementation-Title': 'Java Nats With Dependencies',
'Implementation-Version': jarVersion,
'Implementation-Vendor': 'nats.io')
}
from { configurations.compileClasspath.collect { it.isDirectory() ? it : zipTree(it) } }
with jar
}
jacocoTestReport {
reports {
xml.enabled = true // coveralls plugin depends on xml format report
html.enabled = true
}
afterEvaluate { // only report on main library not examples
classDirectories = files(classDirectories.files.collect {
fileTree(dir: it,
exclude: ['**/examples**'])
})
}
}
artifacts {
archives javadocJar, sourcesJar, examplesJar
}
signing {
sign configurations.archives
}
uploadArchives {
repositories {
mavenDeployer {
if (project.hasProperty("local_archives") || ("true".equals(System.getenv("TRAVIS_PULL_REQUEST")))) {
repository(url: "file://$buildDir/repos")
} else if (project.hasProperty('ossrhUsername') && project.hasProperty('ossrhPassword')) {
beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
authentication(userName: project.getProperty('ossrhUsername'), password: project.getProperty('ossrhPassword'))
}
snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
authentication(userName: project.getProperty('ossrhUsername'), password: project.getProperty('ossrhPassword'))
}
}
pom.project {
name 'jnats'
packaging 'jar'
description 'Client library for working with the NATS messaging system.'
url 'https://github.com/nats-io/java-nats'
licenses {
license {
name = 'The Apache License, Version 2.0'
url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
}
}
developers {
developer {
id="synadia"
name "Synadia"
email "info@synadia.com"
url "https://nats.io"
}
}
scm {
url = 'https://github.com/nats-io/java-nats'
}
}
}
}
}