how to create a diagnostic settings related to a application gateway

[Antse]

I have some difficulties to figure out how can i translate the following ARM Template which is creating a diagnostic settings for an application gateway, in bicep file :

{
   "apiVersion": "2017-05-01-preview",
   "name": "[concat(parameters('applicationGatewayName'), '/Microsoft.Insights/diagnosticSettings')]",
   "type":"Microsoft.Network/applicationGateways/providers/diagnosticSettings",
   "location": "[resourceGroup().location]",
   "dependsOn": [
        "[concat('Microsoft.Network/ApplicationGateways/', parameters('applicationGatewayName'))]",
        "[concat('Microsoft.OperationalInsights/workspaces/',variables('logAnalyticsName'))]"
      ],
      "properties":{
        "name":"Diag",
        "workspaceId":  "[resourceId('Microsoft.OperationalInsights/workspaces/',variables('logAnalyticsName'))]",
        "logs":[
           {
             "category": "ApplicationGatewayAccessLog",
             "enabled": true,
             "retentionPolicy": {
             "enabled": true,
             "days": 365
                                }
           },
           {
              "category": "ApplicationGatewayPerformanceLog",
              "enabled": true,
              "retentionPolicy": {
                "days": 365,
                "enabled": true
              }
            },
            {
              "category": "ApplicationGatewayFirewallLog",
              "enabled": true,
              "retentionPolicy": {
                "days": 365,
                "enabled": true
              }
            }
                ],
                "metrics": [
            {
              "category": "AllMetrics",
              "enabled": true,
              "retentionPolicy": {
                "enabled": true,
                "days": 365
              }
            }
          ]
                    }
  }

[fluffy-cakes]

Have you tried using Biceps functionality to turn it from JSON to Bicep?

bicep decompile [options] <file>
    Attempts to decompile a template .json file to .bicep

[Antse]

Bicep CLI version 0.3.126 (a5e4c2e567)

i try but the decompiled resources is not compliant :

resource applicationGatewayName_Microsoft_Insights_diagnosticSettings 'Microsoft.Network/applicationGateways/providers/diagnosticSettings@2017-05-01-preview' = {
  name: '${applicationGatewayName}/Microsoft.Insights/diagnosticSettings'
  location: resourceGroup().location
  properties: {
    name: 'Diag'
    workspaceId: logAnalyticsName.id
    logs: [
      {
        category: 'ApplicationGatewayAccessLog'
        enabled: true
        retentionPolicy: {
          enabled: true
          days: 365
        }
      }
      {
        category: 'ApplicationGatewayPerformanceLog'
        enabled: true
        retentionPolicy: {
          days: 365
          enabled: true
        }
      }
      {
        category: 'ApplicationGatewayFirewallLog'
        enabled: true
        retentionPolicy: {
          days: 365
          enabled: true
        }
      }
    ]
    metrics: [
      {
        category: 'AllMetrics'
        enabled: true
        retentionPolicy: {
          enabled: true
          days: 365
        }
      }
    ]
  }
  dependsOn: [
    applicationGatewayName_resource
  ]
}

i get a compilation error :
Warning BCP174: Type validation is not available for resource types declared containing a "/providers/" segment. Please instead use the "scope" property. See https://aka.ms/BicepScopes for more information.

So i try parent child creation, but it also fail, i probably do it in the wrong way !

[anthony-c-martin]

You should be able to use the scope property as follows:

resource diagnosticSettings 'Microsoft.Insights/diagnosticSettings@2017-05-01-preview' = {
  scope: applicationGatewayName_resource
  name: 'diagnosticSettings'
  location: resourceGroup().location
  properties: {
    name: 'Diag'
    workspaceId: logAnalyticsName.id
    logs: [
      {
        category: 'ApplicationGatewayAccessLog'
        enabled: true
        retentionPolicy: {
          enabled: true
          days: 365
        }
      }
      {
        category: 'ApplicationGatewayPerformanceLog'
        enabled: true
        retentionPolicy: {
          days: 365
          enabled: true
        }
      }
      {
        category: 'ApplicationGatewayFirewallLog'
        enabled: true
        retentionPolicy: {
          days: 365
          enabled: true
        }
      }
    ]
    metrics: [
      {
        category: 'AllMetrics'
        enabled: true
        retentionPolicy: {
          enabled: true
          days: 365
        }
      }
    ]
  }
}

Here's an example doing of attaching diagnosticSettings to a different resource in a similar fashion:

bicep/docs/examples/201/log-analytics-with-solutions-and-diagnostics/main.bicep

Lines 16 to 60 in a1a3561

	resource logAnalyticsWorkspace 'Microsoft.OperationalInsights/workspaces@2020-03-01-preview' = {
	name: logAnalyticsWorkspaceName
	location: location
	tags: {
	Environment: environmentName
	CostCenter: costCenterName
	}
	properties: any({
	retentionInDays: 30
	features: {
	searchVersion: 1
	}
	sku: {
	name: 'PerGB2018'
	}
	})
	}
	resource logAnalyticsWorkspaceDiagnostics 'Microsoft.Insights/diagnosticSettings@2017-05-01-preview' = {
	scope: logAnalyticsWorkspace
	name: 'diagnosticSettings'
	properties: {
	workspaceId: logAnalyticsWorkspace.id
	logs: [
	{
	category: 'Audit'
	enabled: true
	retentionPolicy: {
	days: 7
	enabled: true
	}
	}
	]
	metrics: [
	{
	category: 'AllMetrics'
	enabled: true
	retentionPolicy: {
	days: 7
	enabled: true
	}
	}
	]
	}
	}

Documentation on using scope is available here: https://github.com/Azure/bicep/blob/main/docs/spec/resource-scopes.md#resource-scope-property

[Antse]

many thanks, it is working has expected !

[Antse]

work great