add disposable launcher framework

addons/disposable/$PBOPREFIX$

@@ -0,0 +1 @@
+x\cba\addons\disposable

addons/disposable/CfgDisposableLaunchers.hpp

@@ -0,0 +1 @@
+class CBA_DisposableLaunchers {};

addons/disposable/CfgEventHandlers.hpp

@@ -0,0 +1,17 @@
+class Extended_PreStart_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preStart));
+    };
+};
+
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preInit));
+    };
+};
+
+class Extended_DisplayLoad_EventHandlers {
+    class RscDisplayInventory {
+        ADDON = QUOTE(_this call (uiNamespace getVariable 'FUNC(initDisplayInventory)'));
+    };
+};

addons/disposable/CfgFunctions.hpp

@@ -0,0 +1,7 @@
+class CfgFunctions {
+    class CBA {
+        class Weapons {
+            PATHTO_FNC(firedDisposable);
+        };
+    };
+};

addons/disposable/CfgMagazines.hpp

@@ -0,0 +1,9 @@
+class CfgMagazines {
+    class CA_LauncherMagazine;
+    class CBA_FakeLauncherMagazine: CA_LauncherMagazine {
+        scope = 1;
+        ammo = "RocketBase";
+        count = 0;
+        allowedSlots[] = {};
+    };
+};

addons/disposable/XEH_PREP.sqf

@@ -0,0 +1 @@
+PREP(replaceMagazineCargo);

addons/disposable/XEH_preInit.sqf

@@ -0,0 +1,58 @@
+#include "script_component.hpp"
+
+ADDON = false;
+
+if (configProperties [configFile >> "CBA_DisposableLaunchers"] isEqualTo []) exitWith {};
+
+#include "XEH_PREP.sqf"
+
+private _fnc_update = {
+    params ["_unit"];
+    if (!local _unit) exitWith {};
+    (GVAR(NormalLaunchers) getVariable secondaryWeapon _unit) params ["_launcher", "_magazine"];
+
+    if (!isNil "_launcher") then {
+        private _launcherItems = secondaryWeaponItems _unit;
+
+        _unit addWeapon _launcher;
+        {
+            _unit addSecondaryWeaponItem _x;
+        } forEach _launcherItems;
+
+        _unit addWeaponItem [_launcher, _magazine];
+    };
+};
+
+["loadout", _fnc_update] call CBA_fnc_addPlayerEventHandler;
+["CAManBase", "InitPost", _fnc_update] call CBA_fnc_addClassEventHandler;
+["CAManBase", "Take", _fnc_update] call CBA_fnc_addClassEventHandler;
+
+GVAR(NormalLaunchers) = [] call CBA_fnc_createNamespace;
+GVAR(LoadedLaunchers) = [] call CBA_fnc_createNamespace;
+GVAR(UsedLaunchers) = [] call CBA_fnc_createNamespace;
+GVAR(magazines) = [];
+GVAR(MagazineLaunchers) = [] call CBA_fnc_createNamespace;
+
+private _cfgWeapons = configFile >> "CfgWeapons";
+private _cfgMagazines = configFile >> "CfgMagazines";
+
+{
+    private _launcher = configName _x;
+    private _magazine = configName (_cfgMagazines >> (getArray (_cfgWeapons >> _launcher >> "magazines") select 0));
+    getArray _x params ["_loadedLauncher", "_usedLauncher"];
+
+    GVAR(LoadedLaunchers) setVariable [_launcher, _loadedLauncher];
+    GVAR(UsedLaunchers) setVariable [_launcher, _usedLauncher];
+
+    if (isNil {GVAR(NormalLaunchers) getVariable _loadedLauncher}) then {
+        GVAR(NormalLaunchers) setVariable [_loadedLauncher, [_launcher, _magazine]];
+    };
+
+    if (GVAR(magazines) pushBackUnique _magazine != -1) then {
+        GVAR(MagazineLaunchers) setVariable [_magazine, _loadedLauncher];
+    };
+} forEach configProperties [configFile >> "CBA_DisposableLaunchers", "isArray _x"];
+
+["All", "InitPost", FUNC(replaceMagazineCargo)] call CBA_fnc_addClassEventHandler;
+
+ADDON = true;

addons/disposable/XEH_preStart.sqf

@@ -0,0 +1,9 @@
+#include "script_component.hpp"
+
+if (configProperties [configFile >> "CBA_DisposableLaunchers"] isEqualTo []) exitWith {};
+
+#include "XEH_PREP.sqf"
+
+if (!hasInterface) exitWith {};
+
+PREP(initDisplayInventory);

addons/disposable/config.cpp

@@ -0,0 +1,20 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        author = "$STR_CBA_Author";
+        name = CSTRING(component);
+        url = "$STR_CBA_URL";
+        units[] = {};
+        weapons[] = {};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"cba_common","cba_events"};
+        version = VERSION;
+        authors[] = {"commy2"};
+    };
+};
+
+#include "CfgEventHandlers.hpp"
+#include "CfgFunctions.hpp"
+#include "CfgDisposableLaunchers.hpp"
+#include "CfgMagazines.hpp"

addons/disposable/fnc_firedDisposable.sqf

@@ -0,0 +1,101 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_firedDisposable
+
+Description:
+    Handles firing a disposable weapon.
+
+Parameters:
+    _unit       - Unit that fired the disposable weapon <OBEJCT>
+    _launcher   - Disposable weapon <STRING>
+    _muzzle     - Muzzle fired by the disposable weapon <STRING>
+    _mode       - Current weapon mode of the disposable weapon <STRING>
+    _ammo       - Ammo fired by the disposable weapon <STRING>
+    _magazine   - Current magazine of the disposable weapon <STRING>
+    _projectile - Fired projectile <OBEJCT>
+    _unit       - Always same as element 0 <OBEJCT>
+
+Returns:
+    Nothing.
+
+Examples:
+    (begin example)
+        class EventHandlers {
+            fired = "_this call CBA_fnc_firedDisposable";
+        };
+    (end)
+
+Author:
+    commy2
+---------------------------------------------------------------------------- */
+
+params ["_unit", "_launcher", "_muzzle", "", "", "", "_projectile"];
+
+private _usedLauncher = GVAR(UsedLaunchers) getVariable _launcher;
+if (isNil "_usedLauncher") exitWith {};
+
+[{
+    params ["_unit", "_launcher", "_usedLauncher", "_projectile"];
+
+    // switch to used tube
+    if (local _unit) then {
+        private _isSelected = currentWeapon _unit == _launcher;
+
+        private _launcherItems = secondaryWeaponItems _unit;
+        private _launcherMagazines = WEAPON_MAGAZINES(_unit,secondaryWeapon _unit);
+
+        _unit addWeapon _usedLauncher;
+        {
+            _unit addSecondaryWeaponItem _x;
+        } forEach _launcherItems;
+
+        {
+            _unit addWeaponItem [_usedLauncher, _x];
+        } forEach _launcherMagazines;
+
+        if (_isSelected) then {
+            _unit selectWeapon _usedLauncher;
+        };
+    };
+
+    // automatically drop
+    [{
+        params ["_unit", "_usedLauncher", "_projectile"];
+
+        // quit if dead or weapon is gone
+        if (!alive _unit || secondaryWeapon _unit != _usedLauncher) exitWith {true};
+
+        if (local _unit && {
+            if (_unit == call CBA_fnc_currentUnit) then {
+                cameraView != "GUNNER"
+            } else {
+                isNull _projectile
+            };
+        }) exitWith {
+            _unit removeWeapon _usedLauncher;
+
+            private _dir = getDir _unit - 180;
+
+            private _container = createVehicle ["WeaponHolderSimulated", [0,0,0], [], 0, "CAN_COLLIDE"];
+            _container addWeaponCargoGlobal [_usedLauncher, 1];
+
+            _container setDir (_dir + 90);
+            _container setPosASL AGLToASL (_unit modelToWorld (_unit selectionPosition "rightshoulder" vectorAdd [0, 0.2, 0.1]));
+            _container setVelocity (velocity _unit vectorAdd ([sin _dir, cos _dir, 0] vectorMultiply 1.5));
+
+            /*
+            addWeaponWithAttachmentsCargoGlobal [
+                _usedLauncher,
+                _silencer, _pointer, _optic, _bipod, [
+                    _magazine1, _ammo1,
+                    _magazine2, _ammo2
+                ],
+            1];
+            */
+
+            true // quit
+        };
+
+        false // continue
+    }, {}, [_unit, _usedLauncher, _projectile]] call CBA_fnc_waitUntilAndExecute;
+}, [_unit, _launcher, _usedLauncher, _projectile], 1] call CBA_fnc_waitAndExecute;

addons/disposable/fnc_initDisplayInventory.sqf

@@ -0,0 +1,14 @@
+#include "script_component.hpp"
+
+params ["_display"];
+
+private _fnc_update = {
+    params ["_display"];
+    private _control = _display displayCtrl IDC_FG_SW_MAGAZINE;
+
+    private _unit = call CBA_fnc_currentUnit;
+    _control ctrlEnable isNil {GVAR(LoadedLaunchers) getVariable secondaryWeapon _unit};
+};
+
+_display displayAddEventHandler ["MouseMoving", _fnc_update];
+_display displayAddEventHandler ["MouseHolding", _fnc_update];

addons/disposable/fnc_replaceMagazineCargo.sqf

@@ -0,0 +1,39 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Internal Function: cba_disposable_fnc_replaceMagazineCargo
+
+Description:
+    Replaces disposable launcher magazines with loaded disposable launchers.
+
+Parameters:
+    _box - Any object with cargo <OBJECT>
+
+Returns:
+    Nothing.
+
+Examples:
+    (begin example)
+        _box call cba_disposable_fnc_replaceMagazineCargo
+    (end)
+
+Author:
+    commy2
+---------------------------------------------------------------------------- */
+
+params ["_box"];
+if (!local _box) exitWith {};
+
+if (magazineCargo _box arrayIntersect GVAR(magazines) isEqualTo []) exitWith {};
+
+private _magazines = magazinesAmmoCargo _box;
+clearMagazineCargoGlobal _box;
+
+{
+    _x params ["_magazine", "_ammo"];
+
+    if (_magazine in GVAR(magazines)) then {
+        _box addWeaponCargoGlobal [GVAR(MagazineLaunchers) getVariable _magazine, 1];
+    } else {
+        _box addMagazineAmmoCargo [_magazine, 1, _ammo];
+    };
+} forEach _magazines;

addons/disposable/script_component.hpp

@@ -0,0 +1,22 @@
+#define COMPONENT disposable
+#include "\x\cba\addons\main\script_mod.hpp"
+
+//#define DEBUG_MODE_FULL
+//#define DISABLE_COMPILE_CACHE
+//#define DEBUG_ENABLED_DISPOSABLE
+
+#ifdef DEBUG_ENABLED_DISPOSABLE
+    #define DEBUG_MODE_FULL
+#endif
+
+#ifdef DEBUG_SETTINGS_DISPOSABLE
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_DISPOSABLE
+#endif
+
+#define DEBUG_MODE_NORMAL
+#define DEBUG_SYNCHRONOUS
+#include "\x\cba\addons\main\script_macros.hpp"
+
+#include "\a3\ui_f\hpp\defineResincl.inc"
+
+#define WEAPON_MAGAZINES(unit,weapon) (weaponsItems (unit) select {_x select 0 == (weapon)} param [0, []] select {_x isEqualType []})

addons/disposable/stringtable.xml

@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="utf-8"?>
+<Project name="CBA_A3">
+    <Package name="Disposable">
+        <Key ID="STR_CBA_Disposable_Component">
+            <English>Community Base Addons - Disposable Weapons</English>
+            <German>Community Base Addons - Einwegwaffen</German>
+        </Key>
+    </Package>
+</Project>

addons/main/config.cpp

@@ -32,7 +32,8 @@ class CfgPatches {
             "cba_jam",
             "cba_ui",
             "cba_versioning",
-            "cba_optics"
+            "cba_optics",
+            "cba_disposable"
         };
         versionDesc = "C.B.A.";
         VERSION_CONFIG;

addons/optics/RscInGameUI.hpp

@@ -10,7 +10,7 @@ class RscInGameUI {
     };
 
     class CBA_ScriptedOptic: RscWeaponZeroing {
-        onLoad = QUOTE(call FUNC(loadScriptedOptic));
+        onLoad = QUOTE([ARR_2(_this select 0, true)] call FUNC(loadScriptedOptic));
         controls[] = {"CA_FOVMode","ScopeBlack","Reticle","BodyNight","BodyDay","TrippleHeadLeft","TrippleHeadRight","CA_Zeroing","Magnification","ActiveDisplayHelper"};
 
         // Idea by Taosenai. This control can be used to determine whether the scope or the collimator is used.

addons/optics/XEH_PREP.sqf

@@ -9,3 +9,4 @@ PREP(changeCarryHandleOpticClass);
 PREP(setOpticMagnification);
 PREP(setOpticMagnificationHelper);
 PREP(setOpticMagnificationHelperZeroing);
+PREP(addWeapon);

addons/optics/XEH_preInit.sqf

@@ -1,15 +1,17 @@
 #include "script_component.hpp"
 
+ADDON = false;
+
 #include "initSettings.sqf"
 
-if (!hasInterface) exitWith {};
-if (configProperties [configFile >> "CBA_PIPItems"] isEqualTo []) exitWith {};
-if (configProperties [configFile >> "CBA_CarryHandleTypes"] isEqualTo []) exitWith {};
-
-ADDON = false;
+if (configProperties [configFile >> "CBA_PIPItems"] isEqualTo [] && {
+    configProperties [configFile >> "CBA_CarryHandleTypes"] isEqualTo []
+}) exitWith {};
 
 #include "XEH_PREP.sqf"
 
+if (!hasInterface) exitWith {};
+
 QGVAR(pauseOpticLayer) cutText ["", "PLAIN"];
 
 GVAR(camera) = objNull;

addons/optics/XEH_preStart.sqf

@@ -1,11 +1,12 @@
 #include "script_component.hpp"
 
+if (configProperties [configFile >> "CBA_PIPItems"] isEqualTo [] && {
+    configProperties [configFile >> "CBA_CarryHandleTypes"] isEqualTo []
+}) exitWith {};
+
+#include "XEH_PREP.sqf"
+
 if (!hasInterface) exitWith {};
 
 // Do not move this below these checks, or this missing function can be exploited.
 PREP(initDisplayInterrupt);
-
-if (configProperties [configFile >> "CBA_PIPItems"] isEqualTo []) exitWith {};
-if (configProperties [configFile >> "CBA_CarryHandleTypes"] isEqualTo []) exitWith {};
-
-#include "XEH_PREP.sqf"

addons/optics/config.cpp

@@ -8,7 +8,7 @@ class CfgPatches {
         units[] = {};
         weapons[] = {};
         requiredVersion = REQUIRED_VERSION;
-        requiredAddons[] = {"cba_common","cba_jr"};
+        requiredAddons[] = {"cba_common","cba_events","cba_jr"};
         version = VERSION;
         authors[] = {"commy2"};
     };