rotate scripted optic according to weapon bank

addons/optics/XEH_PREP.sqf

@@ -9,3 +9,4 @@ PREP(changeCarryHandleOpticClass);
 PREP(setOpticMagnification);
 PREP(setOpticMagnificationHelper);
 PREP(setOpticMagnificationHelperZeroing);
+PREP(gunBank);

addons/optics/fnc_animateScriptedOptic.sqf

@@ -116,6 +116,11 @@ _ctrlBody ctrlSetTextColor [1,1,1,_dayOpacity];
 _ctrlBodyNight ctrlSetTextColor [1,1,1,_nightOpacity];
 _ctrlBlackScope ctrlShow (GVAR(usePipOptics) && !isPipEnabled);
 
+private _bank = call FUNC(gunBank);
+_ctrlReticle ctrlSetAngle [_bank, 0.5, 0.5];
+_ctrlBody ctrlSetAngle [_bank, 0.5, 0.5];
+_ctrlBodyNight ctrlSetAngle [_bank, 0.5, 0.5];
+
 // zooming reticle
 if (isNull (_display displayCtrl IDC_ENABLE_ZOOM)) exitWith {};
 

addons/optics/fnc_gunBank.sqf

@@ -0,0 +1,35 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Internal Function: cba_optics_fnc_gunBank
+
+Description:
+    Reports the bank at which the primary weapon is tilted.
+
+Parameters:
+    None.
+
+Returns:
+    Leaning angle of avatar.
+
+Examples:
+    (begin example)
+        call cba_optics_fnc_gunBank;
+    (end)
+
+Author:
+    commy2
+---------------------------------------------------------------------------- */
+
+private _unit = [] call CBA_fnc_currentUnit;
+
+private _aim = _unit modelToWorldVisualWorld (_unit selectionPosition "Pelvis");
+private _cam = _unit modelToWorldVisualWorld (_unit selectionPosition "camera");
+private _up = _aim vectorFromTo _cam;
+
+private _wDir = _unit weaponDirection primaryWeapon _unit;
+private _wLat = vectorNormalized (_wDir vectorCrossProduct _up);
+private _wUp = _wLat vectorCrossProduct _wDir;
+
+private _right = AGLToASL positionCameraToWorld [0,0,0] vectorFromTo AGLToASL positionCameraToWorld [1,0,0];
+
+90 - acos (_right vectorCos _wUp) // return