Add function to get standard deviation (CBA_fnc_standardDeviation)

addons/arrays/CfgFunctions.hpp

@@ -19,6 +19,7 @@ class CfgFunctions {
             PATHTO_FNC(selectRandomArray);
             PATHTO_FNC(shuffle);
             PATHTO_FNC(sortNestedArray);
+            PATHTO_FNC(standardDeviation);
         };
     };
 };

addons/arrays/fnc_standardDeviation.sqf

@@ -0,0 +1,44 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_standardDeviation
+
+Description:
+    Returns the standard deviation, a measure of the spread of a distribution,
+    of the array elements.
+
+Parameters:
+    _array  - The array from which the standard deviation is computed <ARRAY>
+    _ddof   - The delta degrees of freedom [optional] <SCALAR> (default: 0)
+              _ddof = 0 - Population standard deviation
+              _ddof = 1 - Sample standard deviation
+
+Returns:
+    _stdDev - The standard deviation <SCALAR>
+
+Examples:
+    (begin example)
+    // returns roughly 5.564
+    [[1,4,16,4,1]] call CBA_fnc_standardDeviation;
+    // returns roughly 6.221
+    [[1,4,16,4,1], 1] call CBA_fnc_standardDeviation;
+    (end)
+
+Author:
+    Kex
+---------------------------------------------------------------------------- */
+
+params [["_array", [], [[]]], ["_ddof", 0, [0]]];
+
+private _count = count _array;
+if (_count <= _ddof) exitWith {0};
+
+private _mean = 0;
+{_mean = _mean + _x} forEach _array;
+_mean = _mean / _count;
+
+private _resSumSqrs = 0;
+{
+    _resSumSqrs = _resSumSqrs + (_x - _mean)^2;
+} forEach _array;
+
+sqrt (_resSumSqrs / (_count - _ddof)) // return