Extended Loadout Framework

[BrettMayson]

When merged this pull request will:

• Enable mods to store extended info about a player's loadout
• Superceed Filtered Loadouts #1270, this system can also be used to filter the loadouts, to remove radio IDs as an example

ACE Earplugs Example

["CBA_loadoutSet", {
    params ["_unit", "_loadout", "_extradata"];
    private _hasEarplugs = _extradata getOrDefault ["ace_earplugs", false];
    _unit setVariable ["ACE_hasEarPlugsIn", _hasEarplugs, true];
    [[true]] remoteExec ["ace_hearing_fnc_updateVolume", _unit];
}] call CBA_fnc_addEventHandler;

["CBA_loadoutGet", {
    params ["_unit", "_loadout", "_extradata"];
    if (_unit getVariable ["ACE_hasEarPlugsin", false]) then {
        _extradata set ["ace_earplugs", true]
    };
}] call CBA_fnc_addEventHandler;

ACRE Flagged Radio example

["CBA_loadoutGet", {
    params ["", "_loadout", ""];
    if ((_loadout select 9) select 2 == "ItemRadioAcreFlagged") then {
        (_loadout select 9) set [2, ""];
    };
    
    // Set ACRE base classes
    private _replaceRadioAcre = {
        params ["_item"];
        // Replace only if string (array can be eg. weapon inside container) and an ACRE radio
        if (!(_item isEqualType []) && {[_item] call acre_api_fnc_isRadio}) then {
            _this set [0, [_item] call acre_api_fnc_getBaseRadio];
        };
    };
    if !((_loadout select 3) isEqualTo []) then {
        {_x call _replaceRadioAcre} forEach ((_loadout select 3) select 1); // Uniform items
    };
    if !((_loadout select 4) isEqualTo []) then {
        {_x call _replaceRadioAcre} forEach ((_loadout select 4) select 1); // Vest items
    };
    if !((_loadout select 5) isEqualTo []) then {
        {_x call _replaceRadioAcre} forEach ((_loadout select 5) select 1); // Backpack items
    };
}] call CBA_fnc_addEventHandler;

Usage is very similar to the vanilla getUnitLoadout when applied to units

private _loadout = [player] call CBA_fnc_getLoadout;
[player, _loadout, true] call CBA_fnc_setLoadout

[commy2]

Very clean code.

Why do we need the whole LoadoutSet framework though? Couldn't we just raise and listen to "vanilla" CBA events?

[BrettMayson]

We'd still need to store the defaults for those somewhere, and I don't see any advantage of events over a dedicated function

[commy2]

We'd still need to store the defaults for those somewhere, and I don't see any advantage of events over a dedicated function

Maybe make it a wrapper that uses CBA events?

I would really like to avoid duplicating the events logic yet again.

[BrettMayson]

Any updates on this?

[BrettMayson]

Anyone want to take on modifying this to commy's requirements? I do not have the time.

[BrettMayson]

@commy2 Updated as discussed on Slack