add CBA_fnc_binocularMagazine

addons/common/CfgFunctions.hpp

@@ -67,6 +67,9 @@ class CfgFunctions {
             F_FILEPATH(dropWeapon);
             F_FILEPATH(dropMagazine);
             F_FILEPATH(dropItem);
+            F_FILEPATH(binocularMagazine);
+            F_FILEPATH(addBinocularMagazine);
+            F_FILEPATH(removeBinocularMagazine);
         };
 
         class Cargo {

addons/common/fnc_addBinocularMagazine.sqf

@@ -0,0 +1,40 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_addBinocularMagazine
+
+Description:
+    Adds a magazine to the units rangefinder.
+
+    Note that this breaks the unique magazine ids due to the usage of setUnitLoadout.
+
+Parameters:
+    _unit     - A unit <OBJECT>
+    _magazine - The magazine to add <STRING>
+    _ammo     - Ammo count of the magazine (optional, default: full magazine) <NUMBER>
+
+Returns:
+    None
+
+Examples:
+    (begin example)
+        player addWeapon "Laserdesignator";
+        [player, "Laserbatteries"] call CBA_fnc_addBinocularMagazine;
+    (end)
+
+Author:
+    commy2
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+SCRIPT(addBinocularMagazine);
+
+params [["_unit", objNull, [objNull]], ["_magazine", "", [""]], ["_ammo", nil, [0]]];
+
+if (!local _unit) exitWith {};
+
+if (isNil "_ammo") then {
+    _ammo = getNumber (configFile >> "CfgMagazines" >> _magazine >> "count");
+};
+
+private _loadout = getUnitLoadout _unit;
+(_loadout select 8) set [4, [_magazine, _ammo]];
+
+_unit setUnitLoadout _loadout;

addons/common/fnc_binocularMagazine.sqf

@@ -0,0 +1,36 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_binocularMagazine
+
+Description:
+    Returns the magazine of the units rangefinder.
+
+Parameters:
+    _unit - A unit <OBJECT>
+
+Returns:
+    Magazine of the units binocular <STRING>
+
+Examples:
+    (begin example)
+        player call CBA_fnc_binocularMagazine
+    (end)
+
+Author:
+    commy2
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+SCRIPT(binocularMagazine);
+
+params [["_unit", objNull, [objNull]]];
+
+private _binocular = binocular _unit;
+private _magazine = "";
+
+{
+    if ((_x select 0) isEqualTo _binocular) exitWith {
+        // note: if there is no magazine, _x(4,0) will be nil
+        _magazine = (_x select 4) param [0, ""];
+    };
+} forEach weaponsitems _unit;
+
+_magazine

addons/common/fnc_removeBinocularMagazine.sqf

@@ -0,0 +1,35 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_removeBinocularMagazine
+
+Description:
+    Removes the magazine of the units rangefinder.
+
+Parameters:
+    _unit - A unit <OBJECT>
+
+Returns:
+    None
+
+Examples:
+    (begin example)
+        player call CBA_fnc_removeBinocularMagazine
+    (end)
+
+Author:
+    commy2
+---------------------------------------------------------------------------- */
+#include "script_component.hpp"
+SCRIPT(removeBinocularMagazine);
+
+params [["_unit", objNull, [objNull]]];
+
+if (!local _unit) exitWith {};
+
+private _binocular = binocular _unit;
+private _selectBinocular = currentWeapon _unit isEqualTo _binocular;
+
+_unit addWeapon _binocular;
+
+if (_selectBinocular) then {
+    _unit selectWeapon _binocular;
+};