Row and Column Iterator for Matrices

base/abstractarraymath.jl

@@ -406,3 +406,36 @@ _reperr(s, n, N) = throw(ArgumentError("number of " * s * " repetitions " *
 
     return R
 end
+
+"""
+    eachrow(A::AbstractVecOrMat)
+
+Creates a generator that iterates over the first dimension of matrix A, returning the rows as views.
+See also [`eachcol`](@ref) and [`eachslice`](@ref).
+"""
+eachrow(A::AbstractVecOrMat) = (view(A, i, :) for i in axes(A, 1))
+
+
+"""
+    eachcol(A::AbstractVecOrMat)
+
+Creates a generator that iterates over the second dimension of matrix A, returning the columns as views.
+See also [`eachrow`](@ref) and [`eachslice`](@ref).
+"""
+eachcol(A::AbstractVecOrMat) = (view(A, :, i) for i in axes(A, 2))
+
+"""
+    eachslice(A::AbstractArray; dims)
+
+Creates a generator that iterates over the given dims of A, returning views that select all the data from the other dimensions in A.
+
+Only a single dimension in dims is currently supported. Equivalent to (view(A,:,:,...,i,:,:,...)) for i in axes(A, dims)), where i is in position dims.
+See also [`eachrow`](@ref), [`eachcol`](@ref), and [`selectdim`](@ref).
+"""
+@inline function eachslice(A::AbstractArray; dims)
+    length(dims) == 1 || throw(ArgumentError("only single dimensions are supported"))
+    dim = first(dims)
+    dim <= ndims(A) || throw(DimensionMismatch("A doesn't have that many dimensions"))
+    idx1, idx2 = ntuple(d->(:), dim-1), ntuple(d->(:), ndims(A)-dim)
+    return (view(A, idx1..., i, idx2...) for i in axes(A, dim))
+end

base/exports.jl

@@ -366,6 +366,7 @@ export
     accumulate,
     accumulate!,
     eachindex,
+    eachslice,
     extrema,
     fill!,
     fill,

test/arrayops.jl

@@ -1932,6 +1932,22 @@ end
     @test IndexStyle(selectdim(A, 3, 1)) == IndexStyle(view(A, :, :, 1)) == IndexLinear()
 end
 
+# row/column/slice iterator tests
+using Base: eachrow, eachcol
+@testset "row/column/slice iterators" begin
+    # Simple ones
+    M = [1 2 3; 4 5 6; 7 8 9]
+    @test collect(eachrow(M)) == collect(eachslice(M, dims = 1)) == [[1, 2, 3], [4, 5, 6], [7, 8, 9]]
+    @test collect(eachcol(M)) == collect(eachslice(M, dims = 2)) == [[1, 4, 7], [2, 5, 8], [3, 6, 9]]
+    @test_throws DimensionMismatch eachslice(M, dims = 4)
+
+    # Higher-dimensional case
+    M = reshape([(1:16)...], 2, 2, 2, 2)
+    @test_throws MethodError collect(eachrow(M))
+    @test_throws MethodError collect(eachcol(M))
+    @test collect(eachslice(M, dims = 1))[1][:, :, 1] == [1 5; 3 7]
+end
+
 ###
 ### IndexCartesian workout
 ###