Define machinery so that Some can be used for broadcast

base/Base.jl

@@ -193,6 +193,8 @@ include("broadcast.jl")
 using .Broadcast
 using .Broadcast: broadcasted, broadcasted_kwsyntax, materialize, materialize!
 
+include("somebroadcast.jl")
+
 # missing values
 include("missing.jl")
 

base/some.jl

@@ -6,6 +6,8 @@
 A wrapper type used in `Union{Some{T}, Nothing}` to distinguish between the absence
 of a value ([`nothing`](@ref)) and the presence of a `nothing` value (i.e. `Some(nothing)`).
 
+`Some` is also used in broadcasting to treat it's enclosed value as a scalar.
+
 Use [`something`](@ref) to access the value wrapped by a `Some` object.
 """
 struct Some{T}

base/somebroadcast.jl

@@ -0,0 +1,19 @@
+#Methods some Some can broadcast
+getindex(s::Some) = s.value
+getindex(s::Some, ::CartesianIndex{0}) = s.value
+
+iterate(s::Some) = (s.value, nothing)
+iterate( ::Some, s) = nothing
+
+ndims(::Some) = 0
+ndims(::Type{<:Some}) = 0
+
+length(::Some) = 1
+size(::Some) = ()
+axes(::Some) = ()
+
+IteratorSize(::Type{<:Some}) = HasShape{0}()
+Broadcast.broadcastable(s::Some) = s
+
+eltype(::Some{T})       where {T} = T
+eltype(::Type{Some{T}}) where {T} = T

doc/src/manual/arrays.md

@@ -947,12 +947,9 @@ julia> string.(1:3, ". ", ["First", "Second", "Third"])
 
 Sometimes, you want a container (like an array) that would normally participate in broadcast to be "protected"
 from broadcast's behavior of iterating over all of its elements. By placing it inside another container
-(like a single element [`Tuple`](@ref)) broadcast will treat it as a single value.
+(we recommend [`Some`](@ref)), broadcast will treat it as a single value.
 ```jldoctest
-julia> ([1, 2, 3], [4, 5, 6]) .+ ([1, 2, 3],)
-([2, 4, 6], [5, 7, 9])
-
-julia> ([1, 2, 3], [4, 5, 6]) .+ tuple([1, 2, 3])
+julia> ([1, 2, 3], [4, 5, 6]) .+ Some([1, 2, 3])
 ([2, 4, 6], [5, 7, 9])
 ```
 

test/some.jl

@@ -98,3 +98,14 @@ using Base: notnothing
 # isnothing()
 @test !isnothing(1)
 @test isnothing(nothing)
+
+#Eltype
+@test eltype(Some{Int}) == Int
+@test eltype(Some(1)) == Int
+
+# Broadcast with Some
+@testset "Some Broadcast" begin
+    @test Some(1) .+ 1 == 2
+    @test Some([1, 2]) .+ [[1, 2,], [3, 4]] == [[2, 4], [4, 6]]
+    @test isa.(Some([1,2,3]), [Array, Dict, Int]) == [true, false, false]
+end