Add Zeus module to convert drone into suicide drone

.hemtt/lints.toml

@@ -0,0 +1,4 @@
+[sqf.var_all_caps]
+options.ignore = [
+    "MTS_RECOMPILES", "MTS_PREP_RECOMPILE"
+]

addons/main/script_mod.hpp

@@ -13,8 +13,8 @@
 #define MTS_TAG MTS
 
 // MINIMAL required version for the Mod. Components can specify others..
-#define REQUIRED_VERSION 2.06
-#define REQUIRED_CBA_VERSION {3,15,2}
+#define REQUIRED_VERSION 2.18
+#define REQUIRED_CBA_VERSION {3,18,1}
 
 #ifdef COMPONENT_BEAUTIFIED
     #define COMPONENT_NAME QUOTE(PREFIX - COMPONENT_BEAUTIFIED)

addons/zeus/XEH_PREP.hpp

@@ -1,21 +1,23 @@
 PREP(add3DENCommentsDrawEH);
 PREP(addACEUnconsciousIconDrawEH);
-PREP(moduleArtillery);
+PREP(artyAirburst);
 PREP(artyFireMissionHE);
 PREP(artyFireMissionSMOKE);
 PREP(artyFireMissionILLUM);
-PREP(execArtyStrike);
-PREP(artyAirburst);
+PREP(contextMeasureDistance);
 PREP(drawACEUnconsciousIcon);
+PREP(execArtyStrike);
+PREP(getModuleDestination);
+PREP(getTargetKnowledge);
+PREP(makeIntoSuicideDrone);
+PREP(moduleArtillery);
+PREP(moduleSuicideDrone);
+PREP(moduleTargetKnowledge);
 PREP(moduleUnflipVehicle);
 PREP(on3DENMissionSave);
 PREP(onZeusDisplayOpen);
-PREP(moduleTargetKnowledge);
-PREP(setAIStance);
-PREP(switchAIPathBehaviour);
 PREP(setAIBehaviour);
 PREP(setAICombatMode);
-PREP(getModuleDestination);
-PREP(contextMeasureDistance);
+PREP(setAIStance);
 PREP(setTargetKnowledge);
-PREP(getTargetKnowledge);
+PREP(switchAIPathBehaviour);

addons/zeus/XEH_postInit.sqf

@@ -37,6 +37,7 @@ call FUNC(moduleUnflipVehicle);
 call FUNC(moduleForgetTarget);
 call FUNC(moduleRevealTarget);
 call FUNC(moduleTargetKnowledge);
+call FUNC(moduleSuicideDrone);
 
 call FUNC(contextMeasureDistance);
 

addons/zeus/XEH_preInit.sqf

@@ -10,6 +10,21 @@ ADDON = true;
 
 #include "initSettings.hpp"
 
+// Cache charges for suicide drone
+private _chargeCache = +(uiNamespace getVariable "zen_modules_minesCache");
+_chargeCache params ["_configNames", "_displayNames"];
+
+private _cfgVehicles = configFile >> "CfgVehicles";
+_configNames = [
+    "DemoCharge_Remote_Ammo_Scripted",
+    "SatchelCharge_Remote_Ammo_Scripted"
+] + _configNames;
+_displayNames = [
+    getText (_cfgVehicles >> "DemoCharge_F" >> "displayName"),
+    getText (_cfgVehicles >> "SatchelCharge_F" >> "displayName")
+] + _displayNames;
+GVAR(chargeCache) = [_configNames, _displayNames];
+
 // For 3DEN comments in Zeus
 if (is3DEN) then {
     add3DENEventHandler ["OnMissionSave", {[false] call FUNC(on3DENMissionSave)}];

addons/zeus/config.cpp

@@ -6,7 +6,16 @@ class CfgPatches {
         units[] = {};
         weapons[] = {};
         requiredVersion = REQUIRED_VERSION;
-        requiredAddons[] = {"mts_main", "zen_custom_modules", "zen_dialog", "zen_common", "ace_medical", "ace_zeus"};
+        requiredAddons[] = {
+            "mts_main",
+            "zen_custom_modules",
+            "zen_dialog",
+            "zen_common",
+            "zen_context_menu",
+            "zen_modules",
+            "ace_medical",
+            "ace_zeus"
+        };
         author = ECSTRING(main,authors);
         authors[] = {"PhILoX", "Timi007"};
         url = ECSTRING(main,URL);

addons/zeus/functions/fnc_makeIntoSuicideDrone.sqf

@@ -0,0 +1,41 @@
+#include "script_component.hpp"
+/**
+ *  Author: Timi007
+ *
+ *  Description:
+ *      Turns the drone unit into a suicide drone. Must be executed where unit is local.
+ *
+ *  Parameter(s):
+ *      0: OBJECT - Unit that should get turned into a suicide drone.
+ *      1: STRING - Vehicle classname of the charge which explodes when the drone is destroyed.
+ *      2: NUMBER - Maximum ATL height where the charge does not detonate, even when the drone is destroyed.
+ *                  Negative number do not set max height. (Default: No max height.)
+ *
+ *  Returns:
+ *      Nothing.
+ *
+ *  Example:
+ *      [_unit, "DemoCharge_Remote_Ammo_Scripted"] call mts_zeus_fnc_makeIntoSuicideDrone
+ *
+ */
+
+params [["_unit", objNull, [objNull]], ["_chargeType", "", [""]], ["_maxTriggerHeight", -1, [0]]];
+TRACE_2("makeIntoSuicideDrone",_unit,_chargeType);
+
+if (isNull _unit || _chargeType isEqualTo "") exitWith {};
+if (!local _unit) exitWith {};
+if (_unit getVariable [QGVAR(isSuicideDrone), false]) exitWith {};
+
+[_unit, "Killed", {
+    _thisArgs params ["_unit", "_chargeType", "_maxTriggerHeight"];
+
+    private _posATL = getPosATLVisual _unit;
+    if ((_posATL select 2) <= _maxTriggerHeight || _maxTriggerHeight < 0) then {
+        private _charge = createVehicle [_chargeType, _posATL, [], 0, "CAN_COLLIDE"];
+        _charge setDamage 1;
+    };
+
+    _unit removeEventHandler [_thisType, _thisId];
+}, [_unit, _chargeType, _maxTriggerHeight]] call CBA_fnc_addBISEventHandler;
+
+_unit setVariable [QGVAR(isSuicideDrone), true, true];

addons/zeus/functions/fnc_moduleSuicideDrone.sqf

@@ -0,0 +1,96 @@
+#include "script_component.hpp"
+/**
+ *  Author: Timi007
+ *
+ *  Description:
+ *      Adds "Make into suicide drone" as modules and to the context menu.
+ *
+ *  Parameter(s):
+ *      None.
+ *
+ *  Returns:
+ *      Nothing.
+ *
+ *  Example:
+ *      call mts_zeus_fnc_moduleSuicideDrone
+ *
+ */
+
+[
+    LELSTRING(main,category), LLSTRING(suicideDrone),
+    {
+        params ["", ["_unit", objNull, [objNull]]];
+
+        if (isNull _unit) exitWith {
+            [LLSTRING(suicideDrone_noObject)] call zen_common_fnc_showMessage;
+        };
+
+        if (!unitIsUAV _unit || {!alive _unit} || {!isNull objectParent _unit}) exitWith {
+            [LLSTRING(suicideDrone_notADrone)] call zen_common_fnc_showMessage;
+        };
+
+        if (_unit getVariable [QGVAR(isSuicideDrone), false]) exitWith {
+            [LLSTRING(suicideDrone_isAlreadySuicideDrone)] call zen_common_fnc_showMessage;
+        };
+
+        GVAR(chargeCache) params ["_configNames", "_displayNames"];
+
+        [
+            LLSTRING(suicideDrone),
+            [
+                ["COMBO", LLSTRING(suicideDrone_charge), [_configNames, _displayNames, 0]]
+            ],
+            {
+                params ["_dialogData", "_unit"];
+                _dialogData params ["_chargeType"];
+
+                [_unit, _chargeType] remoteExecCall [QFUNC(makeIntoSuicideDrone), _unit];
+
+                [LLSTRING(suicideDrone_success)] call zen_common_fnc_showMessage;
+            },
+            {},
+            _unit
+        ] call zen_dialog_fnc_create;
+    },
+    "a3\drones_f\air_f_gamma\uav_01\data\ui\uav_01_ca.paa"
+] call zen_custom_modules_fnc_register;
+
+private _suicideDroneAction = [
+    QGVAR(suicideDrone),
+    LLSTRING(suicideDrone),
+    "a3\drones_f\air_f_gamma\uav_01\data\ui\uav_01_ca.paa",
+    {
+        params ["", "_objects"];
+
+        GVAR(chargeCache) params ["_configNames", "_displayNames"];
+
+        [
+            LLSTRING(suicideDrone),
+            [
+                ["COMBO", LLSTRING(suicideDrone_charge), [_configNames, _displayNames, 0]]
+            ],
+            {
+                params ["_dialogData", "_objects"];
+                _dialogData params ["_chargeType"];
+
+                {
+                    if (!unitIsUAV _unit || {!isNull objectParent _unit}) then {
+                        continue;
+                    };
+
+                    [_x, _chargeType] remoteExecCall [QFUNC(makeIntoSuicideDrone), _x];
+                } forEach _objects;
+
+                [LLSTRING(suicideDrone_success)] call zen_common_fnc_showMessage;
+            },
+            {},
+            _objects
+        ] call zen_dialog_fnc_create;
+    },
+    {
+        params ["", "_objects"];
+        ({unitIsUAV _x && {!(_x getVariable [QGVAR(isSuicideDrone), false])} && {alive _x} && {isNull objectParent _x}} count _objects) > 0
+    }
+] call zen_context_menu_fnc_createAction;
+[_suicideDroneAction, [], 0] call zen_context_menu_fnc_addAction;
+

addons/zeus/stringtable.xml

@@ -309,5 +309,31 @@
             <German>Feuereröffnung der Gruppe auf feuerfrei geschaltet</German>
         </Key>
     </Container>
+    <Container name="suicideDrone">
+        <Key ID="STR_mts_zeus_suicideDrone">
+            <Original>Suicide drone</Original>
+            <German>Kamikaze-Drohne</German>
+        </Key>
+        <Key ID="STR_mts_zeus_suicideDrone_charge">
+            <Original>Charge</Original>
+            <German>Ladung</German>
+        </Key>
+        <Key ID="STR_mts_zeus_suicideDrone_noObject">
+            <Original>Place the module on a drone!</Original>
+            <German>Platziere das Modul auf eine Drohne!</German>
+        </Key>
+        <Key ID="STR_mts_zeus_suicideDrone_notADrone">
+            <Original>Unit is not an active drone!</Original>
+            <German>Einheit ist keine aktive Drohne!</German>
+        </Key>
+        <Key ID="STR_mts_zeus_suicideDrone_isAlreadySuicideDrone">
+            <Original>Drone is already a suicide drone!</Original>
+            <German>Drohne ist bereits eine Kamikaze-Drohne!</German>
+        </Key>
+        <Key ID="STR_mts_zeus_suicideDrone_success">
+            <Original>Converted drone into suicide drone.</Original>
+            <German>Drohne in Kamikaze-Drohne umgewandelt.</German>
+        </Key>
+    </Container>
     </Package>
 </Project>