makeOverridablePythonPackage: take care of overrideAttrs

Make it possible to mix overridePythonAttrs and overrideAttrs, i.e.
((<pkg>.overrideAttrs (_: { foo = "a"; })).overridePythonAttrs (_: { })).foo now works

pkgs/development/interpreters/python/python-packages-base.nix

@@ -14,6 +14,9 @@ let
 
   # Derivations built with `buildPythonPackage` can already be overridden with `override`, `overrideAttrs`, and `overrideDerivation`.
   # This function introduces `overridePythonAttrs` and it overrides the call to `buildPythonPackage`.
+  #
+  # Overridings specified through `overridePythonAttrs` will always be applied
+  # before those specified by `overrideAttrs`, even if invoked after them.
   makeOverridablePythonPackage =
     f:
     let
@@ -33,9 +36,15 @@ let
 
         overrideWith = newArgs: args // lib.toFunction newArgs args;
         overridePythonAttrs = mirrorArgs (newArgs: makeOverridablePythonPackage f (overrideWith newArgs));
+
+        # Change the result of the function call by applying g to it
+        overrideResult = g: makeOverridablePythonPackage (mirrorArgs (args: g (f args))) origArgs;
       in
       if builtins.isAttrs result then
         result
+        // lib.optionalAttrs (result ? overrideAttrs) {
+          overrideAttrs = fdrv: overrideResult (drv: drv.overrideAttrs fdrv);
+        }
       else if builtins.isFunction result then
         {
           inherit overridePythonAttrs;

pkgs/test/overriding.nix

@@ -205,6 +205,15 @@ let
           dontWrapPythonPrograms = false;
         });
       checkOverridePythonAttrs = p: !lib.hasInfix "wrapPythonPrograms" p.postFixup;
+      overrideAttrsFooBar =
+        drv:
+        drv.overrideAttrs (
+          finalAttrs: previousAttrs: {
+            FOO = "a";
+            BAR = finalAttrs.FOO;
+          }
+        );
+      checkAttrsFooBar = drv: drv.FOO == "a" && drv.BAR == "a";
     in
     {
       overridePythonAttrs = {
@@ -215,6 +224,20 @@ let
         expr = revertOverridePythonAttrs (applyOverridePythonAttrs pip) == pip;
         expected = true;
       };
+      overrideAttrs-overridePythonAttrs-test-overrideAttrs = {
+        expr = checkAttrsFooBar (applyOverridePythonAttrs (overrideAttrsFooBar pip));
+        expected = true;
+      };
+      overrideAttrs-overridePythonAttrs-test-overridePythonAttrs = {
+        expr = checkOverridePythonAttrs (applyOverridePythonAttrs (overrideAttrsFooBar pip));
+        expected = true;
+      };
+      overrideAttrs-overridePythonAttrs-test-commutation = {
+        expr =
+          (applyOverridePythonAttrs (overrideAttrsFooBar pip))
+          == (overrideAttrsFooBar (applyOverridePythonAttrs pip));
+        expected = true;
+      };
     };
 in