Add a bunch of riscv-related packages

maintainers/maintainer-list.nix

@@ -5130,6 +5130,16 @@
     githubId = 313929;
     name = "Gabriel Ebner";
   };
+  genericnerdyusername = {
+    name = "GenericNerdyUsername";
+    email = "genericnerdyusername@proton.me";
+
+    github = "GenericNerdyUsername";
+    githubId = 111183546;
+    keys = [{
+      fingerprint = "58CE D4BE 6B10 149E DA80  A990 2F48 6356 A4CB 30F3";
+    }];
+  };
   genofire = {
     name = "genofire";
     email = "geno+dev@fireorbit.de";

pkgs/applications/virtualization/sail-riscv/default.nix

@@ -0,0 +1,47 @@
+{ stdenv
+, fetchFromGitHub
+
+, arch
+
+, ocamlPackages
+, ncurses
+, ocaml
+, zlib
+, z3
+}:
+
+
+stdenv.mkDerivation rec {
+  pname = "sail-riscv";
+  version = "0.5";
+
+  nativeBuildInputs = with ocamlPackages; [ sail ocamlbuild findlib ncurses ocaml zlib.dev z3 ];
+
+  src = fetchFromGitHub {
+    owner = "riscv";
+    repo = pname;
+    rev = version;
+    hash = "sha256-7PZNNUMaCZEBf0lOCqkquewRgZPooBOjIbGF7JlLnEo=";
+  };
+
+  ARCH = arch;
+
+  outputs = [ "out" "ocaml_emu" "isabelle_model" "coq_model" "hol4_model" ];
+
+  preConfigure = "sed 's/^SAIL:=$(/SAIL:=sail #/' -i Makefile";
+
+  SAIL_DIR = "${ocamlPackages.sail}/share/sail";
+  SAIL = "sail";
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    cp c_emulator/riscv_sim_${arch} $out/bin
+    mkdir -p $ocaml_emu/bin
+    cp ocaml_emulator/riscv_ocaml_sim_${arch} $ocaml_emu/bin
+    cp -r generated_definitions/coq/ $coq_model
+    cp -r generated_definitions/isabelle/ $isabelle_model
+    cp -r generated_definitions/hol4/ $hol4_model
+    runHook postInstall
+  '';
+}

pkgs/development/compilers/riscv-gnu-toolchain/default.nix

@@ -0,0 +1,125 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, fetchurl
+
+, gcc12
+, glibc
+, newlib
+, gdb
+, qemu
+, musl
+, spike
+, riscv-pk
+
+, autoconf
+, curl
+, automake
+, python3
+, libmpc
+, gawk
+, bison
+, flex
+, texinfo
+, gperf
+, libtool
+, expat
+, gmp
+, mpfr
+, flock
+
+, srcs ? {
+  binutils = {
+    url = "mirror://gnu/binutils/binutils-2.39.tar.bz2";
+    hash = "sha256-2iSoT+8iAQLdJAQt8G/eqFHCYUpTd/hu/6KPM7exYUg=";
+  };
+  dejagnu = {
+    url = "mirror://gnu/dejagnu/dejagnu-1.6.3.tar.gz";
+    hash = "sha256-h9rvrNeVi0pp+IxoVtvRY0JhljxBQHnQw3H1ic1mouM=";
+  };
+  gcc = {
+    url = gcc12.cc.src.url;
+    hash = gcc12.cc.src.outputHash;
+  };
+  glibc = {
+    url = glibc.src.url;
+    hash = glibc.src.outputHash;
+  };
+  newlib = {
+    url = newlib.src.url;
+    hash = "sha256-8pbjcvUTJCJNOHzBFtw3pr05cZh1Z0b5OisC6aXUAVQ=";
+  };
+  gdb = {
+    url = gdb.src.url;
+    hash = gdb.src.outputHash;
+  };
+  qemu = {
+    url = qemu.src.url;
+    hash = qemu.src.outputHash;
+  };
+  musl = {
+    url = musl.src.url;
+    hash = musl.src.outputHash;
+  };
+  spike = {
+    url = spike.src.url;
+    hash = "sha256-mynCIP7R6GfjvqS1xWXyYpI31SWk2f4WaGmcRAYAOh8=";
+  };
+  pk = {
+    url = riscv-pk.src.url;
+    hash = "sha256-Rf6ACDD0WptZK6XU/bdDo+TCEmZT+DTZBKXKuScQf/Y=";
+  };
+}
+
+, isa ? "rv64gc"
+, withLinux ? false
+}:
+with lib;
+let
+
+extract = file: stdenv.mkDerivation {
+  name = file.name + "-unpacked";
+  src = file;
+  dontPatch = true;
+  dontConfigure = true;
+  dontBuild = true;
+  installPhase = "cp -r . $out";
+  dontFixup = true;
+};
+
+srcs_fetched = mapAttrs (name: value: if value ? outPath then value else fetchurl value) srcs;
+srcs_extracted = mapAttrs (name: value: extract value) srcs_fetched;
+srcFlags = mapAttrsToList (name: value: "--with-${name}-src=${value}") srcs_extracted;
+
+in stdenv.mkDerivation rec {
+  pname = "riscv-gnu-toolchain-" + isa;
+  version = "2023.01.04";
+
+  buildInputs = [ autoconf automake flock curl python3 libmpc gawk bison flex texinfo gperf libtool expat.dev gmp.dev mpfr.dev ];
+  hardeningDisable = [ "format" ];
+
+  patches = [ ./nodotgit.patch ];
+  configureFlags = [
+      "--with-arch=${isa}"
+    ] ++
+    srcFlags ++
+    optional withLinux "--enable-linux";
+
+  preConfigure = ''
+    patchShebangs .
+  '';
+
+  src = fetchFromGitHub {
+    owner = "riscv-collab";
+    repo = pname;
+    rev = version;
+    hash = "sha256-PXPQ/ho+fOudZRErnyQZTVFdceWGBF+geo+3y0tkNm4=";
+  };
+
+  meta = with lib; {
+    homepage = "https://github.com/riscv-collab/riscv-gnu-toolchain";
+    description = "RISC-V C and C++ cross-compiler";
+    maintainers = with maintainers; [ genericnerdyusername ];
+    license = with licenses; [ bsd3 gpl2 lgpl21 ];
+  };
+}

pkgs/development/compilers/riscv-gnu-toolchain/nodotgit.patch

@@ -0,0 +1,15 @@
+diff --git a/Makefile.in b/Makefile.in
+index 09c5772..a988d0d 100644
+--- a/Makefile.in
++++ b/Makefile.in
+@@ -279,9 +279,7 @@ GCCPKGVER :=
+ endif
+
+ $(srcdir)/%/.git:
+-	cd $(srcdir) && \
+-	flock `git rev-parse --git-dir`/config git submodule init $(dir $@) && \
+-	flock `git rev-parse --git-dir`/config git submodule update $(dir $@)
++	true
+
+ #
+ # GLIBC

pkgs/development/ocaml-modules/lem/default.nix

@@ -0,0 +1,46 @@
+{ stdenv
+, fetchFromGitHub
+, lib
+, ncurses
+, makeWrapper
+
+, ocamlbuild
+, findlib
+, ocaml
+, num
+, zarith
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lem";
+  version = "2022-12-10";
+
+  minimalOCamlVersion = "4.07";
+
+  nativeBuildInputs = [ makeWrapper ocamlbuild findlib ocaml ];
+  buildInputs = [ ncurses num ];
+  propagatedBuildInputs = [ zarith ];
+
+  installFlags = "INSTALL_DIR=$(out)";
+
+  preInstall = "mkdir -p $OCAMLFIND_DESTDIR";
+  postInstall = ''
+    mv $out/bin/lem $out/bin/.lem_wrapped
+    makeWrapper $out/bin/.lem_wrapped $out/bin/lem --set LEMLIB $out/share/lem/library
+  '';
+
+  src = fetchFromGitHub {
+    owner = "rems-project";
+    repo = pname;
+    rev = version;
+    hash = "sha256-ZQgcuIVRkJS0KtpzjbO4OPHGg6B0TadWA6XpRir30y8=";
+  };
+
+
+  meta = with lib; {
+    homepage = "https://github.com/rems-project/lem";
+    description = "A tool for lightweight executable mathematics";
+    maintainers = with maintainers; [ genericnerdyusername ];
+    license = with licenses; [ bsd3 gpl2 ];
+  };
+}

pkgs/development/ocaml-modules/linksem/default.nix

@@ -0,0 +1,35 @@
+{ lib
+, fetchFromGitHub
+, stdenv
+
+, findlib
+, ocaml
+, lem
+, num
+}:
+
+stdenv.mkDerivation rec {
+  pname = "linksem";
+  version = "0.8";
+
+  minimalOCamlVersion = "4.06";
+
+  nativeBuildInputs = [ findlib ocaml ];
+  buildInputs = [ lem num ];
+
+  preInstall = "mkdir -p $OCAMLFIND_DESTDIR";
+
+  src = fetchFromGitHub {
+    owner = "rems-project";
+    repo = pname;
+    rev = version;
+    hash = "sha256-7/YfDK3TruKCckMzAPLRrwBkHRJcX1S+AzXHWRxkZPA=";
+  };
+
+  meta = with lib; {
+    homepage = "https://github.com/rems-project/linksem";
+    description = "Linksem is a formalisation of substantial parts of ELF linking and DWARF debug information";
+    maintainers = with maintainers; [ genericnerdyusername ];
+    license = licenses.bsd2;
+  };
+}

pkgs/development/ocaml-modules/sail/default.nix

@@ -0,0 +1,67 @@
+{ lib
+, fetchFromGitHub
+, buildDunePackage
+
+, base64
+, omd
+, menhir
+, ott
+, linenoise
+, dune-site
+, pprint
+, makeWrapper
+, lem
+, z3
+, linksem
+, num
+}:
+
+buildDunePackage rec {
+  pname = "sail";
+  version = "0.15";
+
+  src = fetchFromGitHub {
+    owner = "rems-project";
+    repo = "sail";
+    rev = version;
+    hash = "sha256-eNdFOSzkniNvSCZeORRJ/IYAu+9P4HSouwmhd4BQLPk=";
+  };
+
+  duneVersion = "3";
+  minimalOCamlVersion = "4.08";
+
+  SAIL_DIR = "$out";
+
+  nativeBuildInputs = [ base64 omd menhir ott linenoise dune-site pprint makeWrapper ];
+
+  propagatedBuildInputs = [ lem z3 linksem num ];
+
+  buildPhase = ''
+    runHook preBuild
+    rm -r aarch*  # Remove code derived from non-bsd2 arm spec
+    rm -r snapshots  # Some of this might be derived from stuff in the aarch dir, it builds fine without it
+    dune build --release ''${enableParallelBuild:+-j $NIX_BUILD_CORES}
+    runHook postBuild
+  '';
+  checkPhase = ''
+    runHook preCheck
+    dune runtest ''${enableParallelBuild:+-j $NIX_BUILD_CORES}
+    runHook postCheck
+  '';
+  installPhase = ''
+    runHook preInstall
+    dune install --prefix $out --libdir $OCAMLFIND_DESTDIR
+    runHook postInstall
+  '';
+  postInstall = ''
+    mv $out/bin/sail $out/bin/.sail_wrapped
+    makeWrapper $out/bin/.sail_wrapped $out/bin/sail --set SAIL_DIR $out/share/sail
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/rems-project/sail";
+    description = "Sail is a language for describing the instruction-set architecture (ISA) semantics of processors";
+    maintainers = with maintainers; [ genericnerdyusername ];
+    license = licenses.bsd2;
+  };
+}

pkgs/development/python-modules/dataproperty/default.nix

@@ -0,0 +1,29 @@
+{ buildPythonPackage
+, mbstrdecoder
+, typepy
+
+, fetchFromGitHub
+, lib
+}:
+
+buildPythonPackage rec {
+  pname = "dataproperty";
+  version = "0.55.0";
+
+  propagatedBuildInputs = [ mbstrdecoder typepy ];
+  doCheck = false;
+
+  src = fetchFromGitHub {
+    owner = "thombashi";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-ODSrKZ8M/ni9r2gkVIKWaKkdr+3AVi4INkEKJ+cmb44=";
+  };
+
+  meta = with lib; {
+    homepage = "https://github.com/thombashi/dataproperty";
+    description = "A Python library for extract property from data";
+    maintainers = with maintainers; [ genericnerdyusername ];
+    license = licenses.mit;
+  };
+}