macOS support for NixOS tests

nixos/lib/testing/default.nix

@@ -14,6 +14,7 @@ let
     ./legacy.nix
     ./meta.nix
     ./name.nix
+    ./macos-host.nix
     ./network.nix
     ./nodes.nix
     ./pkgs.nix

nixos/lib/testing/macos-host.nix

@@ -0,0 +1,18 @@
+{ config, lib, hostPkgs, ... }:
+
+{
+  config = lib.mkIf hostPkgs.stdenv.hostPlatform.isDarwin {
+    defaults = {
+      # On non-darwin, mounting the whole nix store from the host is the default because
+      # this generally makes rebuilds of the VMs faster and the VMs smaller, while reducing
+      # disk I/O.
+      # However, on macOS it currently leads to many crashing guest processes.
+      virtualisation.useNixStoreImage = true;
+
+      # Without this, the store image uses "raw" instead of "qcow2" and
+      # that throws some errors on macOS on startup of the VM
+      # TODO: remove when `raw` errors are fixed.
+      virtualisation.writableStore = true;
+    };
+  };
+}

nixos/lib/testing/nodes.nix

@@ -14,6 +14,25 @@ let
     types
     ;
 
+  inherit (hostPkgs) hostPlatform pkgsNative;
+
+  guestPkgs =
+    if hostPlatform.isLinux
+    then hostPkgs
+    else
+      let
+        hostToGuest = {
+          "x86_64-darwin" = pkgsNative.gnu64;
+          "aarch64-darwin" = pkgsNative.aarch64-multiplatform;
+        };
+
+        supportedHosts = lib.concatStringsSep ", " (lib.attrNames hostToGuest);
+
+        message =
+          "NixOS Test: don't know which VM guest system to pair with VM host system: ${hostPlatform.system}. Perhaps you intended to run the tests on a Linux host, or one of the following systems that may run NixOS tests: ${supportedHosts}";
+      in
+        hostToGuest.${hostPlatform.system} or (throw message);
+
   baseOS =
     import ../eval-config.nix {
       inherit lib;
@@ -27,13 +46,15 @@ let
           ({ config, ... }:
             {
               virtualisation.qemu.package = testModuleArgs.config.qemu.package;
+              virtualisation.host.pkgs = hostPkgs;
+              nixpkgs.pkgs = guestPkgs;
             })
           ({ options, ... }: {
             key = "nodes.nix-pkgs";
             config = optionalAttrs (!config.node.pkgsReadOnly) (
               mkIf (!options.nixpkgs.pkgs.isDefined) {
                 # TODO: switch to nixpkgs.hostPlatform and make sure containers-imperative test still evaluates.
-                nixpkgs.system = hostPkgs.stdenv.hostPlatform.system;
+                nixpkgs.system = hostPlatform.system;
               }
             );
           })

nixos/lib/testing/run.nix

@@ -41,7 +41,9 @@ in
     rawTestDerivation = hostPkgs.stdenv.mkDerivation {
       name = "vm-test-run-${config.name}";
 
-      requiredSystemFeatures = [ "kvm" "nixos-test" ];
+      requiredSystemFeatures = [ "nixos-test" ]
+        ++ lib.optionals hostPkgs.stdenv.hostPlatform.isLinux [ "kvm" ]
+        ++ lib.optionals hostPkgs.stdenv.hostPlatform.isDarwin [ "apple-virt" ];
 
       buildCommand = ''
         mkdir -p $out

pkgs/top-level/release-attrpaths-superset.nix

@@ -52,6 +52,7 @@ let
     pkgsMusl = true;
     pkgsStatic = true;
     pkgsCross = true;
+    pkgsNative = true;
     pkgsi686Linux = true;
   };
 

pkgs/top-level/stage.nix

@@ -185,10 +185,25 @@ let
     # that target system. For instance, pkgsCross.raspberryPi.hello,
     # will refer to the "hello" package built for the ARM6-based
     # Raspberry Pi.
+    #
+    # This is essentially the same thing as pkgsNative except for crossSystem
+    # instead of localSystem.
     pkgsCross = lib.mapAttrs (n: crossSystem:
                               nixpkgsFun { inherit crossSystem; })
                               lib.systems.examples;
 
+    # This maps each entry in lib.systems.examples to its own package set where
+    # packages are built and run on that system.  For example,
+    # pkgsNative.x86_64-linux.hello will refer to the "hello" package bult for
+    # x86_64-linux.
+    #
+    # This is essentially the same thing as pkgsCross except for localSystem
+    # instead of crossSystem.
+    pkgsNative =
+      lib.mapAttrs
+        (n: localSystem: nixpkgsFun { inherit localSystem; })
+        lib.systems.examples;
+
     pkgsLLVM = nixpkgsFun {
       overlays = [
         (self': super': {