utility/precognition: init module (#437)

* utility/precognition: init

* utility/precognition: fix priority example, add default

* utility/precognition: add files to default.nix

* utility/precognition: fix typos, manual fmt

* utility/precognition: remove useless mappings

i was going to add binds to toggle/enable/disable but ehhh
idk

* utility/precognition: fix hints option

it broke

* utility/precognition: update gutter hints, new description

* utility/precognition: add files to motion defaults

* utility/precognition: add plugin to flake

* utility/precognition: remove comment reference

oops

* utility/precognition: add precognition to maximal configuration

it does work!

* utility/precognition: update descriptions

needs docs link, desc is somewhat obscure.

* docs: add credit to release notes

* utility/precognition: format

* utility/precognition: de-linkify descriptions

* utility/precognition: no more rec

* utility/precognition: convert to setupOpts

honestly raf was cooking with this one.
it's much nicer to use compared to interpolation lol

* utility/precognition: remove unnecessary function parameter

* utility/precognition: format

* utility/precognition: add description to disabled_fts

oops

* utility/precognition: manual format

* utility/precognition: remove periods at the end of descriptions

* utility/precognition: fix configuration.nix entry

oops lol

* utility/precognition: format

* utility/precognition: expand `vim`

* precognition: consistency changes

Just my minor nits.

---------

Co-authored-by: NotAShelf <raf@notashelf.dev>

configuration.nix

@@ -165,6 +165,7 @@ isMaximal: {
       motion = {
         hop.enable = true;
         leap.enable = true;
+        precognition.enable = isMaximal;
       };
 
       images = {

docs/release-notes/rl-0.7.md

@@ -216,3 +216,7 @@ everyone.
 [Bloxx12](https://github.com/Bloxx12):
 
 - Fix internal breakage in `elixir-tools` setup.
+
+[Nowaaru](https://github.com/Nowaaru):
+
+- Add `precognition-nvim`.

flake.nix

@@ -525,6 +525,11 @@
       flake = false;
     };
 
+    plugin-precognition-nvim = {
+      url = "github:tris203/precognition.nvim";
+      flake = false;
+    };
+
     # Note-taking
     plugin-obsidian-nvim = {
       url = "github:epwalsh/obsidian.nvim";

modules/plugins/utility/motion/default.nix

@@ -2,5 +2,6 @@ _: {
   imports = [
     ./hop
     ./leap
+    ./precognition
   ];
 }

modules/plugins/utility/motion/precognition/config.nix

@@ -0,0 +1,18 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.modules) mkIf;
+
+  cfg = config.vim.utility.motion.precognition;
+in {
+  config = mkIf cfg.enable {
+    vim = {
+      startPlugins = ["precognition-nvim"];
+      luaConfigRC.precognition = lib.nvim.dag.entryAnywhere ''
+        require('precognition').setup(${lib.nvim.lua.toLuaObject cfg.setupOpts})
+      '';
+    };
+  };
+}

modules/plugins/utility/motion/precognition/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./precognition.nix
+    ./config.nix
+  ];
+}

modules/plugins/utility/motion/precognition/precognition.nix

@@ -0,0 +1,66 @@
+{lib, ...}: let
+  inherit (lib.options) mkEnableOption mkOption literalExpression;
+  inherit (lib.types) attrsOf listOf str bool int submodule;
+  inherit (lib.nvim.types) mkPluginSetupOption;
+
+  mkHintType = description:
+    mkOption {
+      inherit description;
+      default = {};
+      type = attrsOf (submodule {
+        options = {
+          text = mkOption {
+            type = str;
+            description = "The easier-to-read depiction of the motion";
+          };
+
+          prio = mkOption {
+            type = int;
+            default = 1;
+            description = "The priority of the hint";
+            example = 10;
+          };
+        };
+      });
+    };
+in {
+  options.vim.utility.motion.precognition = {
+    enable = mkEnableOption "assisted motion discovery[precognition.nvim]";
+    setupOpts = mkPluginSetupOption "precognition.nvim" {
+      startVisible = mkOption {
+        type = bool;
+        default = true;
+        description = "Whether to start 'precognition' automatically";
+      };
+
+      showBlankVirtLine = mkOption {
+        type = bool;
+        default = true;
+        description = "Whether to show a blank virtual line when no movements are shown";
+      };
+
+      highlightColor = mkOption {
+        type = attrsOf str;
+        default = {link = "Comment";};
+        example = literalExpression ''
+          { link = "Comment"; }
+          # or
+          { foreground = "#0000FF"; background = "#000000"; };
+        '';
+        description = "The highlight for the virtual text";
+      };
+
+      disabled_fts = mkOption {
+        type = listOf str;
+        default = ["startify"];
+        example = literalExpression ''["startify"]'';
+        description = "Filetypes that automatically disable 'precognition'";
+      };
+
+      hints = mkHintType "What motions display, and at what priority";
+      gutterHints = mkHintType ''
+        What motions display and at what priority. Only appears in gutters
+      '';
+    };
+  };
+}