MC 1.20 Overview

build.gradle.kts

@@ -1,125 +1,135 @@
 import net.ltgt.gradle.errorprone.errorprone
+import org.jetbrains.gradle.ext.delegateActions
+import org.jetbrains.gradle.ext.settings
+import org.jetbrains.gradle.ext.taskTriggers
 
 buildscript {
     dependencies {
-        classpath("fr.inria.gforge.spoon:spoon-core:10.2.0") // bump for EIG
+        classpath(libs.spoon) // bump for EIG
     }
 }
 
 plugins {
     eclipse
-    id("org.spongepowered.gradle.sponge.dev")
-    id("net.kyori.indra.checkstyle")
-    id("net.kyori.indra.crossdoc")
-    id("net.kyori.indra.publishing")
-    id("net.kyori.indra.publishing.sonatype")
-    id("org.spongepowered.gradle.event-impl-gen")
-    id("org.jetbrains.gradle.plugin.idea-ext")
-    id("net.ltgt.errorprone")
-}
-
-repositories {
-    maven("https://repo.spongepowered.org/repository/maven-public/") {
-        name = "sponge"
-    }
+    alias(libs.plugins.spongeGradle.convention)
+    alias(libs.plugins.indra.checkstyle)
+    alias(libs.plugins.indra.crossdoc)
+    alias(libs.plugins.indra.publishing)
+    alias(libs.plugins.indra.publishing.sonatype)
+    alias(libs.plugins.eventImplGen)
+    alias(libs.plugins.ideaExt)
+    alias(libs.plugins.errorprone)
+    alias(libs.plugins.nexusPublish)
 }
 
+val javaTarget: String by project
 val ap by sourceSets.registering {
     compileClasspath += sourceSets.main.get().compileClasspath + sourceSets.main.get().output
 }
 
+configurations {
+    sequenceOf(apiElements, runtimeElements).forEach {
+       it.configure {
+           exclude(group = "org.jetbrains",  module = "annotations")
+       }
+    }
+}
+
 // Project dependencies
-val adventureVersion: String by project
-val configurateVersion: String by project
-val gsonVersion: String by project
-val log4jVersion: String by project
-val mathVersion: String by project
 dependencies {
-    val caffeineVersion: String by project
-    val errorproneVersion: String by project
-    val junitVersion: String by project
-    val mockitoVersion: String by project
-    val pluginSpiVersion: String by project
-
     // Directly tied to what's available from Minecraft
-    api("org.apache.logging.log4j:log4j-api:$log4jVersion")
-    api("com.google.code.gson:gson:$gsonVersion")
+    api(libs.log4j.api)
+    api(libs.gson)
 
     // Adventure
-    api(platform("net.kyori:adventure-bom:$adventureVersion"))
-    api("net.kyori:adventure-api")
-    api("net.kyori:adventure-text-serializer-gson") {
+    api(platform(libs.adventure.bom))
+    api(libs.adventure.api)
+    api(libs.adventure.textSerializer.gson) {
         exclude(group = "com.google.code.gson", module = "gson")
         exclude(group = "net.kyori", module = "adventure-api")
     }
-    api("net.kyori:adventure-text-serializer-legacy") {
+    api(libs.adventure.textSerializer.legacy) {
         exclude(group = "net.kyori", module = "adventure-api")
     }
-    api("net.kyori:adventure-text-serializer-plain") {
+    api(libs.adventure.textSerializer.plain) {
         exclude(group = "net.kyori", module = "adventure-api")
     }
-    api("net.kyori:adventure-text-minimessage") {
+    api(libs.adventure.minimessage) {
         exclude(group = "net.kyori", module = "adventure-api")
     }
 
     // Dependency injection
-    api("com.google.inject:guice:5.0.1") {
-        exclude(group ="com.google.code.findbugs", module = "jsr305") // We don't want to use jsr305, use checkerframework
+    api(libs.guice) {
+        exclude(group = "com.google.code.findbugs", module = "jsr305") // We don't want to use jsr305, use checkerframework
         exclude(group = "javax.inject", module = "javax.inject")
         exclude(group = "com.google.guava", module = "guava") // We use an older version than Guice does
+        exclude(group = "org.ow2.asm", module = "asm")
     }
 
     // High performance cache + guava - shaded guava
-    api("com.github.ben-manes.caffeine:caffeine:$caffeineVersion") {
-        exclude(group= "org.checkerframework", module = "checker-qual")
+    api(libs.caffeine) {
+        exclude(group = "org.checkerframework", module = "checker-qual")
         exclude(group = "com.google.errorprone", module = "error_prone_annotations")
+        exclude(group = "org.junit", module = "junit-bom")
+        exclude(group = "org.yaml", module = "snakeyaml")
+        exclude(group = "com.fasterxml.jackson", module = "jackson-bom")
+        exclude(group = "org.ow2.asm", module = "asm-bom")
     }
 
     // Plugin spi, includes plugin-meta
-    api("org.spongepowered:plugin-spi:$pluginSpiVersion")
+    api(libs.pluginSpi) {
+        exclude(group = "org.checkerframework", module = "checker-qual")
+        exclude(group = "com.google.code.gson", module = "gson")
+        exclude(group = "org.apache.logging.log4j", module = "log4j-api")
+    }
 
     // Configurate
-    api(platform("org.spongepowered:configurate-bom:$configurateVersion"))
-    api("org.spongepowered:configurate-core") {
+    api(platform(libs.configurate.bom))
+    api(libs.configurate.core) {
         exclude(group = "org.checkerframework", module = "checker-qual") // We use our own version
     }
-    api("org.spongepowered:configurate-hocon") {
+    api(libs.configurate.hocon) {
         exclude(group = "org.spongepowered", module = "configurate-core")
-        exclude(group= "org.checkerframework", module = "checker-qual")
+        exclude(group = "org.checkerframework", module = "checker-qual")
 
     }
-    api("org.spongepowered:configurate-gson") {
+    api(libs.configurate.gson) {
         exclude(group = "org.spongepowered", module = "configurate-core")
         exclude(group = "com.google.code.gson", module = "gson") // We have the same version technically, but use the gson we provide.
-        exclude(group= "org.checkerframework", module = "checker-qual")
+        exclude(group = "org.checkerframework", module = "checker-qual")
     }
-    api("org.spongepowered:configurate-yaml") {
+    api(libs.configurate.yaml) {
         exclude(group = "org.spongepowered", module = "configurate-core")
-        exclude(group= "org.checkerframework", module = "checker-qual")
+        exclude(group = "org.checkerframework", module = "checker-qual")
     }
-    api("org.spongepowered:configurate-extra-guice") {
+    api(libs.configurate.extraGuice) {
         exclude(group = "com.google.inject", module = "guice")
     }
 
     // Compile-time static analysis
-    compileOnly("com.google.errorprone:error_prone_annotations:$errorproneVersion")
-    errorprone("com.google.errorprone:error_prone_core:$errorproneVersion")
+    compileOnly(libs.errorprone.annotations)
+    errorprone(libs.errorprone)
 
     // Math library
-    api("org.spongepowered:math:$mathVersion")
+    api(libs.math) {
+        exclude(group = "com.google.errorprone", module = "error_prone_annotations")
+    }
 
-    testImplementation(platform("org.junit:junit-bom:$junitVersion"))
-    testImplementation("org.junit.jupiter:junit-jupiter-api")
-    testImplementation("org.junit.jupiter:junit-jupiter-params")
-    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine")
-    testImplementation("org.hamcrest:hamcrest:2.2")
-    testImplementation("org.mockito:mockito-core:$mockitoVersion")
+    compileOnlyApi(libs.checkerQual)
+
+    testImplementation(platform(libs.junit.bom))
+    testImplementation(libs.junit.api)
+    testImplementation(libs.junit.params)
+    testRuntimeOnly(libs.junit.engine)
+    testRuntimeOnly(libs.junit.launcher)
+    testImplementation(libs.hamcrest)
+    testImplementation(libs.mockito)
 }
 
 tasks {
     genEventImpl {
-        sourceCompatibility = "16"
-        destinationDir = project.layout.buildDirectory.dir("generated/event-factory").get().asFile
+        sourceCompatibility = javaTarget
+        destinationDirectory = project.layout.buildDirectory.dir("generated/event-factory")
 
         outputFactory = "org.spongepowered.api.event.SpongeEventFactory"
         include("org/spongepowered/api/event/*/**/*")
@@ -164,14 +174,14 @@ tasks {
         options {
             (this as? StandardJavadocDocletOptions)?.apply {
                 links(
-                    "https://logging.apache.org/log4j/log4j-$log4jVersion/log4j-api/apidocs/",
-                    "https://google.github.io/guice/api-docs/5.0.1/javadoc/",
-                    "https://configurate.aoeu.xyz/$configurateVersion/apidocs/",
-                    "https://www.javadoc.io/doc/com.google.code.gson/gson/$gsonVersion/",
-                    "https://jd.spongepowered.org/math/$mathVersion"
+                    "https://logging.apache.org/log4j/log4j-${libs.versions.log4j.get()}/log4j-api/apidocs/",
+                    "https://google.github.io/guice/api-docs/${libs.versions.guice.get()}/javadoc/",
+                    "https://configurate.aoeu.xyz/${libs.versions.configurate.get()}/apidocs/",
+                    "https://www.javadoc.io/doc/com.google.code.gson/gson/${libs.versions.gson.get()}/",
+                    "https://jd.spongepowered.org/math/${libs.versions.math.get()}"
                 )
                 sequenceOf("api", "key", "text-serializer-gson", "text-serializer-legacy", "text-serializer-plain").forEach {
-                    links("https://jd.advntr.dev/$it/$adventureVersion/")
+                    links("https://jd.advntr.dev/$it/${libs.versions.adventure.get()}/")
                 }
                 addBooleanOption("quiet", true)
             }
@@ -196,14 +206,12 @@ tasks {
 
 idea {
     if (project != null) {
-        (project as ExtensionAware).extensions["settings"].run {
-            require(this is ExtensionAware)
-
-            this.extensions.getByType(org.jetbrains.gradle.ext.ActionDelegationConfig::class).run {
+        project.settings.run {
+            delegateActions {
                 delegateBuildRunToGradle = false
                 testRunner = org.jetbrains.gradle.ext.ActionDelegationConfig.TestRunner.PLATFORM
             }
-            this.extensions.getByType(org.jetbrains.gradle.ext.TaskTriggersConfig::class).run {
+            taskTriggers {
                 beforeBuild(tasks.genEventImpl)
             }
         }
@@ -233,15 +241,13 @@ spongeConvention {
 }
 
 indra {
-    val checkstyleVersion: String by project
-
     javaVersions {
-        target(17)
+        target(javaTarget.toInt())
     }
-    checkstyle(checkstyleVersion)
+    checkstyle(libs.versions.checkstyle.get())
 
     configurePublications {
-        artifactId = project.name.toLowerCase()
+        artifactId = project.name.lowercase()
         pom {
             this.url.set(projectUrl)
             this.description.set(projectDescription)

gradle.properties

@@ -1,22 +1,10 @@
 group=org.spongepowered
-version=10.1.0-SNAPSHOT
+version=11.0.0-SNAPSHOT
 organization=SpongePowered
 projectUrl=https://www.spongepowered.org
 projectDescription=A plugin API for Minecraft: Java Edition
+javaTarget=17
 
 javadocPublishRoot=https://jd.spongepowered.org/
 
 org.gradle.parallel=true
-
-adventureVersion=4.12.0
-caffeineVersion=3.1.2
-checkstyleVersion=10.5.0
-configurateVersion=4.1.2
-errorproneVersion=2.16
-gsonVersion=2.10
-junitVersion=5.9.1
-log4jVersion=2.19.0
-
-mathVersion=2.0.1
-mockitoVersion=4.8.0
-pluginSpiVersion=0.3.0

gradle/libs.versions.toml

@@ -0,0 +1,67 @@
+[metadata]
+format = { version = "1.1" }
+
+[versions]
+adventure = "4.12.0"
+caffeine = "3.1.8"
+checker = "3.42.0"
+checkstyle = "10.12.7"
+configurate = "4.1.2"
+errorprone = "2.24.1"
+gson = "2.10.1"
+guice = "5.0.1"
+ideaExt = "1.1.7"
+indra = "3.1.3"
+junit = "5.10.1"
+log4j = "2.19.0"
+math = "2.0.1"
+mockito = "5.9.0"
+pluginSpi = "0.3.0"
+
+[libraries]
+adventure-bom = { module = "net.kyori:adventure-bom", version.ref = "adventure" }
+adventure-api = { module = "net.kyori:adventure-api" }
+adventure-textSerializer-gson = { module = "net.kyori:adventure-text-serializer-gson" }
+adventure-textSerializer-legacy = { module = "net.kyori:adventure-text-serializer-legacy" }
+adventure-textSerializer-plain =  { module = "net.kyori:adventure-text-serializer-plain" }
+adventure-minimessage = { module = "net.kyori:adventure-text-minimessage" }
+caffeine = { module = "com.github.ben-manes.caffeine:caffeine", version.ref = "caffeine" }
+configurate-bom = { module = "org.spongepowered:configurate-bom", version.ref = "configurate" }
+configurate-core = { module = "org.spongepowered:configurate-core" }
+configurate-hocon = { module = "org.spongepowered:configurate-hocon" }
+configurate-gson = { module = "org.spongepowered:configurate-gson" }
+configurate-yaml = { module = "org.spongepowered:configurate-yaml" }
+configurate-extraGuice = { module = "org.spongepowered:configurate-extra-guice" }
+gson = { module = "com.google.code.gson:gson", version.ref = "gson" }
+guice = { module = "com.google.inject:guice", version.ref = "guice" }
+log4j-api = { module = "org.apache.logging.log4j:log4j-api", version.ref = "log4j" }
+math = { module = "org.spongepowered:math", version.ref = "math" }
+pluginSpi = { module = "org.spongepowered:plugin-spi", version.ref = "pluginSpi" }
+
+# build-time/annotations
+
+checkerQual = { module = "org.checkerframework:checker-qual", version.ref = "checker" }
+errorprone = { module = "com.google.errorprone:error_prone_core", version.ref = "errorprone" }
+errorprone-annotations = { module = "com.google.errorprone:error_prone_annotations", version.ref = "errorprone" }
+spoon = { module = "fr.inria.gforge.spoon:spoon-core", version = "10.4.2" } # bump for EIG
+
+# testing
+
+hamcrest = { module = "org.hamcrest:hamcrest", version = "2.2" }
+junit-bom = { module = "org.junit:junit-bom", version.ref = "junit" }
+junit-api = { module = "org.junit.jupiter:junit-jupiter-api" }
+junit-params = { module = "org.junit.jupiter:junit-jupiter-params" }
+junit-engine = { module = "org.junit.jupiter:junit-jupiter-engine" }
+junit-launcher = { module = "org.junit.platform:junit-platform-launcher" }
+mockito = { module = "org.mockito:mockito-core", version.ref = "mockito" }
+
+[plugins]
+errorprone = { id = "net.ltgt.errorprone", version = "3.1.0" }
+eventImplGen = { id = "org.spongepowered.gradle.event-impl-gen", version = "7.1.0" }
+ideaExt = { id = "org.jetbrains.gradle.plugin.idea-ext", version.ref = "ideaExt" }
+indra-checkstyle = { id = "net.kyori.indra.checkstyle", version.ref = "indra" }
+indra-crossdoc = { id = "net.kyori.indra.crossdoc", version.ref = "indra" }
+indra-publishing = { id = "net.kyori.indra.publishing", version.ref = "indra" }
+indra-publishing-sonatype = { id = "net.kyori.indra.publishing.sonatype", version.ref = "indra" }
+nexusPublish = { id = "io.github.gradle-nexus.publish-plugin", version = "2.0.0-rc-1"}
+spongeGradle-convention = { id = "org.spongepowered.gradle.sponge.dev", version = "2.2.0" }

gradle/wrapper/gradle-wrapper.properties

@@ -1,6 +1,7 @@
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-7.6-bin.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-8.4-bin.zip
 networkTimeout=10000
+validateDistributionUrl=true
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists