Deserializer plug

lib/jsonapi/plugs/deserializer.ex

@@ -0,0 +1,39 @@
+defmodule JSONAPI.Deserializer do
+  @moduledoc """
+  Based on - https://github.com/vt-elixir/ja_serializer/blob/20ff32279cab00e81eba0d035951c470fdfbf82d/lib/ja_serializer/param_parser.ex
+
+  This plug "deserializes" params to underscores.
+  For example these params:
+      %{
+        "data" => %{
+          "attributes" => %{
+            "foo-bar" => true
+          }
+        }
+      }
+  are transformed to:
+      %{
+        "data" => %{
+          "attributes" => %{
+            "foo_bar" => true
+          }
+        }
+      }
+
+  ## Usage
+  Just include in your plug stack _after_ a json parser:
+      plug Plug.Parsers, parsers: [:json], json_decoder: Jason
+      plug JSONAPI.Deserializer
+
+  or a part of your Controller plug pipeline
+      plug JSONAPI.Deserializer
+  """
+
+  alias JSONAPI.Utils.ParamParser
+
+  def init(opts), do: opts
+
+  def call(conn, _opts) do
+    Map.put(conn, :params, ParamParser.parse(conn.params))
+  end
+end

lib/jsonapi/utils/param_parser.ex

@@ -0,0 +1,21 @@
+defprotocol JSONAPI.Utils.ParamParser do
+  @fallback_to_any true
+  def parse(params)
+end
+
+defimpl JSONAPI.Utils.ParamParser, for: Any do
+  def parse(data), do: data
+end
+
+defimpl JSONAPI.Utils.ParamParser, for: List do
+  def parse(list), do: Enum.map(list, &JSONAPI.Utils.ParamParser.parse/1)
+end
+
+defimpl JSONAPI.Utils.ParamParser, for: Map do
+  def parse(map) do
+    Enum.reduce(map, %{}, fn {key, val}, map ->
+      key = JSONAPI.Utils.String.underscore(key)
+      Map.put(map, key, JSONAPI.Utils.ParamParser.parse(val))
+    end)
+  end
+end

test/jsonapi/plugs/deserializer_test.exs

@@ -0,0 +1,105 @@
+defmodule JSONAPI.DeserializerTest do
+  use ExUnit.Case
+  use Plug.Test
+
+  defmodule ExamplePlug do
+    use Plug.Builder
+    plug Plug.Parsers, parsers: [:json], json_decoder: Jason
+    plug JSONAPI.Deserializer
+    plug :return
+
+    def return(conn, _opts) do
+      send_resp(conn, 200, "success")
+    end
+  end
+
+  @ct "application/vnd.api+json"
+
+  test "Ignores bodyless requests" do
+    conn =
+      Plug.Test.conn("GET", "/")
+      |> put_req_header("content-type", @ct)
+      |> put_req_header("accept", @ct)
+
+    result = ExamplePlug.call(conn, [])
+    assert result.params == %{}
+  end
+
+  test "converts non-jsonapi.org format params" do
+    req_body = Jason.encode!(%{"some-nonsense" => "yup"})
+
+    conn =
+      Plug.Test.conn("POST", "/", req_body)
+      |> put_req_header("content-type", @ct)
+      |> put_req_header("accept", @ct)
+
+    result = ExamplePlug.call(conn, [])
+    assert result.params == %{"some_nonsense" => "yup"}
+  end
+
+  test "converts attribute key names" do
+    req_body =
+      Jason.encode!(%{
+        "data" => %{
+          "attributes" => %{
+            "some-nonsense" => true,
+            "foo-bar" => true,
+            "some-map" => %{
+              "nested-key" => "unaffected-values"
+            }
+          }
+        }
+      })
+
+    conn =
+      Plug.Test.conn("POST", "/", req_body)
+      |> put_req_header("content-type", @ct)
+      |> put_req_header("accept", @ct)
+
+    result = ExamplePlug.call(conn, [])
+    assert result.params["data"]["attributes"]["some_nonsense"]
+    assert result.params["data"]["attributes"]["foo_bar"]
+    assert result.params["data"]["attributes"]["some_map"]["nested_key"]
+  end
+
+  test "converts query param key names - dasherized" do
+    req_body = Jason.encode!(%{"data" => %{}})
+
+    conn =
+      Plug.Test.conn("POST", "/?page[page-size]=2", req_body)
+      |> put_req_header("content-type", @ct)
+      |> put_req_header("accept", @ct)
+
+    result = ExamplePlug.call(conn, [])
+    assert result.params["page"]["page_size"] == "2"
+  end
+
+  test "converts query param key names - underscored" do
+    req_body = Jason.encode!(%{"data" => %{}})
+
+    conn =
+      Plug.Test.conn("POST", "/?page[page_size]=2", req_body)
+      |> put_req_header("content-type", @ct)
+      |> put_req_header("accept", @ct)
+
+    result = ExamplePlug.call(conn, [])
+    assert result.query_params["page"]["page_size"] == "2"
+  end
+
+  test "retains payload type" do
+    req_body =
+      Jason.encode!(%{
+        "data" => %{
+          "type" => "foo-bar"
+        }
+      })
+
+    conn =
+      Plug.Test.conn("POST", "/", req_body)
+      |> put_req_header("content-type", @ct)
+      |> put_req_header("accept", @ct)
+
+    result = ExamplePlug.call(conn, [])
+    assert result.params["data"]["type"] == "foo-bar"
+  end
+end