Using dFdx?

[aVersionOfReality]

I am trying to use dFdx and dFdy for some bump mapping. But they don't seem to work at all.
My test setup is very simple:

I am getting the error "unable to find compatible overloaded function "dFdx(vec3)".
Looking into this, it suggests that there may not be a vec3 version available. So I have also tried it as a float, with the vec3 split, but I get the same error. I have also tried including it as a new util node, and have tried several example code snippets, but its always the same error.

Can I get a confirmation of it its even available in Malt?

[pragma37]

The problem is that Malt uses the same source code for vertex and pixel shaders.
This is more convenient for the most part, but it also means that using some built-in GLSL functions requires some extra care.

Derivative functions are only available from pixel shaders, so to use them you have to make sure the code is only present in the generated pixel shader code:

vec3 partial_derivative_x(vec3 v)
{
    #ifdef PIXEL_SHADER
    {
        return dFdx(v);
    }
    #else
    {
        return vec3(0);
    }
    #endif
}

Another workaround could be to just define them as macros on vertex shaders. That way the compiler won't complain:

#ifndef PIXEL_SHADER
#define dFdx(a) (a)
#define dFdy(a) (a)
#endif

I have thought about adding this kind of "compatibility" macros before, but I'm not sure about it. They could end up being problematic for debugging.

[aVersionOfReality]

Great. That code is working.
Where would I put those macro definitions?

I had thought that Mesh Shader meant Pixel shader, but now I'm realizing that there is both vertex and pixel shader stuff available.
So is the problem that when it tries to compile my node, it doesn't know which it is? Or are there elements of both pixel and vertex shaders? I'm trying to get a mental image of what is going on here.

Thanks!

[pragma37]

Where would I put those macro definitions?

Anywhere before the code that uses it. On the top of your node utils, for example.

So is the problem that when it tries to compile my node, it doesn't know which it is? Or are there elements of both pixel and vertex shaders? I'm trying to get a mental image of what is going on here.

Shader APIs need separate sources for vertex and pixel shaders. So a basic example would look like this:
Vertex:

#version 410 core
layout (location = 0) in vec3 POSITION;
void main()
{
    gl_Position = vec4(POSITION, 1);
}

Pixel:

#version 410 core
layout (location = 0) out vec4 RESULT;
uniform vec4 color = vec4(1,0,0,1);
void main()
{
    RESULT = color;
}

Malt instead does something like this:

#version 410 core

#ifdef VERTEX_SHADER
layout (location = 0) in vec3 POSITION;
void main()
{
    gl_Position = vec4(POSITION, 1);
}
#endif

#ifdef PIXEL_SHADER
layout (location = 0) out vec4 RESULT;
uniform vec4 color = vec4(1,0,0,1);
void main()
{
    RESULT = color;
}
#endif

And generates vertex and shader sources from there.

The shader functions/nodes library is shared by vertex and pixel shaders, so you have to ensure that they are compilable in both, even if they are never used.