Implement CPack for Debian/RPM

.github/workflows/build_release.yml

@@ -15,29 +15,31 @@ jobs:
       with:
         submodules: true
 
-    - name: Make setup.sh and check_capstone.sh are executable
+    - name: Configure CMake and build the project
       run: |
-        chmod +x ./packages/deb/setup.sh
-        chmod +x ./packages/deb/check_capstone.sh
-        
-    - name: Build Debian Package
-      working-directory: ./packages/deb
-      run: ./setup.sh ${{ github.event.release.tag_name }}
-
-    - name: Run sanity checks on the Debian package
-      working-directory: ./packages/deb
+        cmake -B build \
+        -DPROJECT_VERSION=${{ github.event.release.tag_name }} \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCAPSTONE_BUILD_SHARED_LIBS=1 \
+        -DCMAKE_INSTALL_PREFIX=/usr
+        cmake --build build
+
+    - name: Package DEB and RPM package
       run: |
-        ./check_capstone.sh ./libcapstone-dev_${{ github.event.release.tag_name }}_amd64.deb
-      
+        cd build
+        cpack -G DEB
+        cpack -G RPM
+
     - name: Upload debian package to release
       uses: softprops/action-gh-release@v2
       env:
         GITHUB_TOKEN: ${{ secrets.GITHUB_TOKEN }}
       with:
         tag_name: ${{ github.event.release.tag_name }}
         files: |
-          ./packages/deb/*.deb
-  
+          ./build/*.deb
+          ./build/*.rpm
+
     - name: Create archive
       id: archive
       run: |

BUILDING.md

@@ -12,6 +12,16 @@ cmake --build build
 cmake --install build --prefix "<install-prefix>"
 ```
 
+To create rpm, debian and OSX packages, run the following
+```bash
+cmake -B build -DCMAKE_BUILD_TYPE=Release -DCAPSTONE_BUILD_SHARED_LIBS=1 -DCMAKE_INSTALL_PREFIX=/usr
+cmake --build build
+cd build
+cpack -G DEB
+cpack -G RPM
+cpack -G DragNDrop
+```
+
 **Windows**
 
 ```bash

CMakeLists.txt

@@ -24,11 +24,17 @@ if(NOT DEFINED PROJECT_VERSION)
     set(PROJECT_VERSION "6.0.0")
 endif()
 
-# Extract the major, minor, and patch versions
-string(REGEX MATCH "^[0-9]+\\.[0-9]+\\.[0-9]+" PROJECT_VERSION_BASE ${PROJECT_VERSION})
+# Remove the 'v' prefix if it exists and extract the major, minor, and patch versions
+string(REGEX MATCH "^[vV]?([0-9]+\\.[0-9]+\\.[0-9]+)" _ ${PROJECT_VERSION})
+set(PROJECT_VERSION_BASE ${CMAKE_MATCH_1})
+
+# Use PROJECT_VERSION directly for CPack
+set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 
 # Set the project version without the pre-release identifier
 project(capstone VERSION ${PROJECT_VERSION_BASE})
+# Print the values of PROJECT_VERSION and PROJECT_VERSION_BASE
+message(STATUS "PROJECT_VERSION: ${CPACK_PACKAGE_VERSION} CAPSTONE_VERSION: ${PROJECT_VERSION_BASE}")
 
 set(UNIX_COMPILER_OPTIONS -Werror -Wall -Warray-bounds -Wshift-negative-value -Wreturn-type -Wformat -Wmissing-braces -Wunused-function -Warray-bounds -Wunused-variable -Wparentheses -Wint-in-bool-context -Wmisleading-indentation)
 
@@ -959,3 +965,7 @@ if(CAPSTONE_BUILD_CSTEST)
     set(TESTS_UNIT_DIR ${PROJECT_SOURCE_DIR}/tests/unit)
     add_subdirectory(${TESTS_UNIT_DIR})
 endif()
+
+# Include CPack
+set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackConfig.cmake")
+include(CPackConfig.txt)

CPackConfig.cmake

@@ -0,0 +1,13 @@
+# Used to dynamically set the package file name based on the generator
+foreach(generator ${CPACK_GENERATOR})
+    if("${generator}" STREQUAL "DEB")
+        set(CPACK_PACKAGE_FILE_NAME ${CPACK_DEBIAN_PACKAGE_FILE_NAME})
+    elseif("${generator}" STREQUAL "RPM")
+        set(CPACK_PACKAGE_FILE_NAME ${CPACK_RPM_PACKAGE_FILE_NAME})
+    elseif("${generator}" STREQUAL "DragNDrop")
+        set(CPACK_PACKAGE_FILE_NAME ${CPACK_DMG_PACKAGE_FILE_NAME})
+    else()
+        set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-unknown")
+    endif()
+    message(STATUS "Generating package for ${generator} with file name ${CPACK_PACKAGE_FILE_NAME}")
+endforeach()

CPackConfig.txt

@@ -0,0 +1,59 @@
+# Copyright © 2024 Andrew Quijano <andrewquijano92@gmail.com>
+# SPDX-License-Identifier: MIT
+
+# Set general CPack values
+set(CPACK_PACKAGE_NAME "capstone")
+set(CPACK_PACKAGE_VENDOR "Rot127")
+set(CPACK_PACKAGE_CONTACT "Rot127 <unisono@quyllur.org>")
+set(CPACK_PACKAGE_DESCRIPTION "Capstone is a lightweight multi-platform, multi-architecture disassembly framework. These are the development headers and libraries.\n Features:\n - Support hardware architectures: AArch64, ARM, Alpha, BPF, EVM, HPPA, LongArch, M680X, M68K, MOS65XX, Mips, PowerPC, RISCV, SH, Sparc, SystemZ, TMS320C64x, TriCore, WASM, x86, XCore, Xtensa.\n - Clean/simple/lightweight/intuitive architecture-neutral API.\n - Provide details on disassembled instructions (called \\\"decomposer\\\" by some others).\n - Provide some semantics of the disassembled instruction, such as list of implicit registers read & written.\n - Thread-safe by design.\n - Special support for embedding into firmware or OS kernel.\n - Distributed under the open source BSD license.")
+set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Lightweight multi-architecture disassembly framework - devel files")
+set(CPACK_PACKAGE_HOMEPAGE_URL "https://www.capstone-engine.org/")
+set(CPACK_STRIP_FILES false)
+set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/LICENSES/LICENSE.TXT")
+
+# Set Debian-specific package variables
+set(CPACK_DEBIAN_PACKAGE_NAME "libcapstone-dev")
+set(CPACK_DEBIAN_PACKAGE_SOURCE "capstone")
+set(CPACK_DEBIAN_PACKAGE_VERSION "${PROJECT_VERSION}")
+set(CPACK_DEBIAN_PACKAGE_ORIGINAL_MAINTAINER "Debian Security Tools <team+pkg-security@tracker.debian.org>")
+set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.2.5)")
+set(CPACK_DEBIAN_PACKAGE_SECTION "libdevel")
+set(CPACK_DEBIAN_PACKAGE_PRIORITY "optional")
+set(CPACK_DEBIAN_PACKAGE_MULTIARCH "same")
+
+# Determine architecture for Debian package
+if(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "x86_64")
+    set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE "amd64")
+elseif(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i386" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i686")
+    set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE "i386")
+elseif(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm")
+    if(CMAKE_SIZE_OF_VOID_P EQUAL 4)
+        set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE "armhf")
+    else()
+        set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE "arm64")
+    endif()
+else()
+    set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE ${CMAKE_SYSTEM_PROCESSOR})
+endif()
+
+# Include additional file to run 'ldconfig' after install
+set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA "${CMAKE_SOURCE_DIR}/packages/deb/triggers")
+
+# RPM package settings
+set(CPACK_RPM_PACKAGE_NAME "capstone-devel")
+set(CPACK_RPM_PACKAGE_VERSION "${PROJECT_VERSION}")
+set(CPACK_RPM_PACKAGE_ARCHITECTURE ${CMAKE_SYSTEM_PROCESSOR})
+set(CPACK_RPM_PACKAGE_GROUP "Development/Libraries")
+set(CPACK_RPM_PACKAGE_REQUIRES "glibc >= 2.2.5")
+set(CPACK_RPM_POST_INSTALL_SCRIPT_FILE "${CMAKE_SOURCE_DIR}/packages/rpm/postinstall.sh")
+set(CPACK_RPM_POST_UNINSTALL_SCRIPT_FILE "${CMAKE_SOURCE_DIR}/packages/rpm/postinstall.sh")
+set(CPACK_RPM_CHANGELOG_FILE "${CMAKE_SOURCE_DIR}/ChangeLog")
+set(CPACK_RPM_PACKAGE_LICENSE "BSD3, LLVM")
+set(CPACK_RPM_PACKAGE_DESCRIPTION "${CPACK_PACKAGE_DESCRIPTION}")
+
+# Set package file name based on the generator
+set(CPACK_DEBIAN_PACKAGE_FILE_NAME "${CPACK_DEBIAN_PACKAGE_NAME}_${CPACK_PACKAGE_VERSION}_${CPACK_DEBIAN_PACKAGE_ARCHITECTURE}")
+set(CPACK_RPM_PACKAGE_FILE_NAME "${CPACK_RPM_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}.${CMAKE_SYSTEM_PROCESSOR}")
+set(CPACK_DMG_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
+
+include(CPack)