Automatic execution of generic fixers always sets v:errmsg

[lifecrisis]

The following minimal configuration is necessary to reproduce this:

let g:ale_fixers = {}
let g:ale_fixers['vim'] = ['trim_whitespace']
let g:ale_fix_on_save = 1

To reproduce the problem:

1. vim foo.vim
2. :echo v:errmsg (you should see nothing)
3. :write
4. :echo v:errmsg

As you can see, ALE pollutes this variable unnecessarily.

The problem is due to this function from autoload/ale/util.vim:

function! s:LoadArgCount(function) abort
    let l:Function = a:function

    redir => l:output
        silent! function Function
    redir END

    if !exists('l:output')
        return 0
    endif

    let l:match = matchstr(split(l:output, "\n")[0], '\v\([^)]+\)')[1:-2]
    let l:arg_list = filter(split(l:match, ', '), 'v:val isnot# ''...''')

    return len(l:arg_list)
endfunction

The problem is that :silent! still sets v:errmsg.

I recommend that this function be changed to:

function! s:LoadArgCount(function) abort
    try
        let l:output = execute('function a:function')
    catch /E123/
        return 0
    endtry

    let l:match = matchstr(split(l:output, "\n")[0], '\v\([^)]+\)')[1:-2]
    let l:arg_list = filter(split(l:match, ', '), 'v:val isnot# ''...''')

    return len(l:arg_list)
endfunction

Notes...

• I removed an unnecessary local variable (l:Function).
• Also, the original if statement is useless, so it can go too (:redir always creates the variable, so it will always exist).
• Using :redir is passé. I think that execute() should be preferred here.

Let me know if you want a PR, and I'll submit one.

[lifecrisis]

This is such a simple fix... I went ahead and took the liberty of submitting a pull request.

[w0rp]

I just so happened to notice this in IRC, so I merged this. Thanks for pointing that out. 👍