Add EIP-223: Token standard with event handling implementation

EIPS/eip-223.md

@@ -0,0 +1,389 @@
+---
+eip: 223
+title: 223 Token with communication model
+description: Token with event handling and communication model
+author: Dexaran (@Dexaran)
+discussions-to: https://ethereum-magicians.org/t/erc-223-token-standard/12894
+status: Review
+type: Standards Track
+category: ERC
+created: 2017-05-03
+---
+
+## Abstract
+
+The following describes standard functions a token contract and contract which is intended to work with specified token can implement. This standard introduces a communication model which allows for the implementation of **event handling** on the receiver's side.
+
+## Motivation
+
+1. This token introduces a communication model for contracts that can be utilized to straighten the behavior of contracts that interact with tokens as opposed to [ERC-20](./eip-20.md) where a token transfer could be ignored by the receiving contract.
+2. This token is more gas-efficient when depositing tokens to contracts.
+3. This token allows for `_data` recording for financial transfers.
+
+
+## Specification
+
+Token
+Contracts that works with tokens
+
+### Methods
+
+NOTE: An important point is that contract developers must implement `tokenReceived` if they want their contracts to work with the specified tokens.
+
+If the receiver does not implement the `tokenReceived` function, consider the contract is not designed to work with tokens, then the transaction must fail and no tokens will be transferred. An analogy with an Ether transaction that is failing when trying to send Ether to a contract that did not implement `receive() payable`.
+
+
+#### totalSupply
+
+```js
+
+function totalSupply() constant returns (uint256 totalSupply)
+
+```
+
+Get the total token supply
+
+#### name
+
+```js
+
+function name() constant returns (string _name)
+
+```
+
+Get the name of token
+
+#### symbol
+
+```js
+
+function symbol() constant returns (bytes32 _symbol)
+
+```
+
+Get the symbol of token
+
+#### decimals
+
+```js
+
+function decimals() constant returns (uint8 _decimals)
+
+```
+
+Get decimals of token
+
+#### standard
+
+```js
+
+function standard() constant returns (string _standard)
+
+```
+
+Get the standard of token contract. For some services it is important to know how to treat this particular token. If token supports [ERC-223](./eip-223.md) standard then it must explicitly tell that it does.
+
+This function **MUST** return "ERC-223" for this token standard. If no "standard()" function is implemented in the contract then the contract must be considered to be ERC-20.
+
+#### balanceOf
+
+```js
+
+function balanceOf(address _owner) constant returns (uint256 balance)
+
+```
+
+Get the account balance of another account with address _owner
+
+
+#### transfer(address, uint)
+
+```js
+
+function transfer(address _to, uint _value) returns (bool)
+
+```
+
+Needed due to backwards compatibility reasons because of ERC-20 transfer function doesn't have `bytes` parameter. This function must transfer tokens and invoke the function `tokenReceived(address, uint256, bytes calldata)` in `_to`, if _to is a contract. If the `tokenReceived` function is not implemented in `_to` (receiver contract), then the transaction must fail and the transfer of tokens should be reverted.
+
+#### transfer(address, uint, bytes)
+
+```js
+
+function transfer(address _to, uint _value, bytes calldata _data) returns (bool)
+
+```
+
+function that is always called when someone wants to transfer tokens.
+This function must transfer tokens and invoke the function `tokenReceived (address, uint256, bytes)` in `_to`, if _to is a contract. If the `tokenReceived` function is not implemented in `_to` (receiver contract), then the transaction must fail and the transfer of tokens should not occur. 
+If `_to` is an externally owned address, then the transaction must be sent without trying to execute `tokenReceived` in `_to`.
+ `_data` can be attached to this token transaction and it will stay in blockchain forever (requires more gas). `_data` can be empty.
+
+NOTE: The recommended way to check whether the `_to` is a contract or an address is to assemble the code of `_to`. If there is no code in `_to`, then this is an externally owned address, otherwise it's a contract.
+
+### Events
+
+#### Transfer
+
+```js
+
+event Transfer(address indexed _from, address indexed _to, uint256 _value)
+
+```
+
+Triggered when tokens are transferred. Compatible with ERC-20 `Transfer` event.
+
+#### TransferData
+
+```js
+
+event TransferData(bytes _data)
+
+```
+
+Triggered when tokens are transferred and logs transaction metadata. This is implemented as a separate event to keep `Transfer(address, address, uint256)` ERC-20-compatible.
+
+### Contract that is intended to receive ERC-223 tokens
+
+```js
+
+function tokenReceived(address _from, uint _value, bytes calldata _data)
+
+```
+
+A function for handling token transfers, which is called from the token contract, when a token holder sends tokens. `_from` is the address of the sender of the token, `_value` is the amount of incoming tokens, and `_data` is attached data similar to `msg.data` of Ether transactions. It works by analogy with the fallback function of Ether transactions and returns nothing.
+
+NOTE: `msg.sender` will be a token-contract inside the `tokenReceived` function. It may be important to filter which tokens are sent (by token-contract address). The token sender (the person who initiated the token transaction) will be `_from` inside the `tokenReceived` function.
+
+IMPORTANT: This function must be named `tokenReceived` and take parameters `address`, `uint256`, `bytes` to match the function signature `0xc0ee0b8a`.
+
+
+## Rationale
+
+This standard introduces a communication model by enforcing the `transfer` to execute a handler function in the destination address. This is an important security consideration as it is required that the receiver explicitly implements the token handling function. In cases where the receiver does not implements such function the transfer MUST be reverted.
+
+This standard sticks to the push transaction model where the transfer of assets is initiated on the senders side and handled on the receivers side. As the result, ERC-223 transfers are more gas-efficient while dealing with depositing to contracts as ERC-223 tokens can be deposited with just one transaction while ERC-20 tokens require at least two calls (one for `approve` and the second that will invoke `transferFrom`).
+
+- [ERC-20](./eip-20.md) deposit: `approve` ~53K gas, `transferFrom` ~80K gas
+
+- ERC-223 deposit: `transfer` and handling on the receivers side ~46K gas
+
+This standard introduces the ability to correct user errors by allowing to handle ANY transactions on the recipient side and reject incorrect or improper transactions. This tokens utilize ONE transferring method for both types of interactions with tokens and externally owned addresses which can simplify the user experience and allow to avoid possible user mistakes.
+
+One downside of the commonly used [ERC-20](./eip-20.md) standard that ERC-223 is intended to solve is that [ERC-20](./eip-20.md) implements two methods of token transferring: (1) `transfer` function and (2) `approve + transferFrom` pattern. Transfer function of [ERC-20](./eip-20.md) standard does not notify the receiver and therefore if any tokens are sent to a contract with the `transfer` function then the receiver will not recognize this transfer and the tokens can become stuck in the receivers address without any possibility of recovering them.
+
+ERC-223 standard is intended to simplify the interaction with contracts that are intended to work with tokens. ERC-223 utilizes "deposit" pattern similar to plain Ether depositing patterns - in case of ERC-223 deposit to the contract a user or a UI must simply send the tokens with the `transfer` function. This is one transaction as opposed to two step process of `approve + transferFrom` depositing.
+
+This standard allows payloads to be attached to transactions using the `bytes calldata _data` parameter, which can encode a second function call in the destination address, similar to how `msg.data` does in an Ether transaction, or allow for public loggin on chain should it be necessary for financial transactions.
+
+
+## Security Considerations
+
+This token utilizes the model similar to plain Ether behavior. Therefore replay issues must be taken into account.
+
+
+### Reference implementation
+
+```js
+
+pragma solidity ^0.8.0;
+
+// Source: https://github.com/Dexaran/ERC-223
+
+library Address {
+    /**
+     * @dev Returns true if `account` is a contract.
+     *
+     * This test is non-exhaustive, and there may be false-negatives: during the
+     * execution of a contract's constructor, its address will be reported as
+     * not containing a contract.
+     *
+     * > It is unsafe to assume that an address for which this function returns
+     * false is an externally-owned account (EOA) and not a contract.
+     */
+    function isContract(address account) internal view returns (bool) {
+        // This method relies in extcodesize, which returns 0 for contracts in
+        // construction, since the code is only stored at the end of the
+        // constructor execution.
+
+        uint256 size;
+        // solhint-disable-next-line no-inline-assembly
+        assembly { size := extcodesize(account) }
+        return size > 0;
+    }
+
+    /**
+     * @dev Converts an `address` into `address payable`. Note that this is
+     * simply a type cast: the actual underlying value is not changed.
+     */
+    function toPayable(address account) internal pure returns (address payable) {
+        return payable(account);
+    }
+}
+
+abstract contract IERC223Recipient {
+/**
+ * @dev Standard ERC223 function that will handle incoming token transfers.
+ *
+ * @param _from  Token sender address.
+ * @param _value Amount of tokens.
+ * @param _data  Transaction metadata.
+ */
+    function tokenReceived(address _from, uint _value, bytes memory _data) public virtual;
+}
+
+/**
+ * @title Reference implementation of the ERC223 standard token.
+ */
+contract ERC223Token {
+
+     /**
+     * @dev Event that is fired on successful transfer.
+     */
+    event Transfer(address indexed from, address indexed to, uint value);
+
+     /**
+     * @dev Additional event that is fired on successful transfer and logs transfer metadata,
+     *      this event is implemented to keep Transfer event compatible with ERC20.
+     */
+    event TransferData(bytes data);
+
+    string  private _name;
+    string  private _symbol;
+    uint8   private _decimals;
+    uint256 private _totalSupply;
+
+    mapping(address => uint256) public balances; // List of user balances.
+
+    /**
+     * @dev Sets the values for {name} and {symbol}, initializes {decimals} with
+     * a default value of 18.
+     *
+     * To select a different value for {decimals}, use {_setupDecimals}.
+     *
+     * All three of these values are immutable: they can only be set once during
+     * construction.
+     */
+
+    constructor(string memory new_name, string memory new_symbol, uint8 new_decimals)
+    {
+        _name     = new_name;
+        _symbol   = new_symbol;
+        _decimals = new_decimals;
+    }
+
+    /**
+     * @dev ERC223 tokens must explicitly return "erc223" on standard() function call.
+     */
+    function standard() public pure returns (string memory)
+    {
+        return "ERC-223";
+    }
+
+    /**
+     * @dev Returns the name of the token.
+     */
+    function name() public view returns (string memory)
+    {
+        return _name;
+    }
+
+    /**
+     * @dev Returns the symbol of the token, usually a shorter version of the
+     * name.
+     */
+    function symbol() public view returns (string memory)
+    {
+        return _symbol;
+    }
+
+    /**
+     * @dev Returns the number of decimals used to get its user representation.
+     * For example, if `decimals` equals `2`, a balance of `505` tokens should
+     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
+     *
+     * Tokens usually opt for a value of 18, imitating the relationship between
+     * Ether and Wei. This is the value {ERC223} uses, unless {_setupDecimals} is
+     * called.
+     *
+     * NOTE: This information is only used for _display_ purposes: it in
+     * no way affects any of the arithmetic of the contract, including
+     * {IERC223-balanceOf} and {IERC223-transfer}.
+     */
+    function decimals() public view returns (uint8)
+    {
+        return _decimals;
+    }
+
+    /**
+     * @dev See {IERC223-totalSupply}.
+     */
+    function totalSupply() public view returns (uint256)
+    {
+        return _totalSupply;
+    }
+
+
+    /**
+     * @dev Returns balance of the `_owner`.
+     *
+     * @param _owner   The address whose balance will be returned.
+     * @return balance Balance of the `_owner`.
+     */
+    function balanceOf(address _owner) public view returns (uint256)
+    {
+        return balances[_owner];
+    }
+
+    /**
+     * @dev Transfer the specified amount of tokens to the specified address.
+     *      Invokes the `tokenFallback` function if the recipient is a contract.
+     *      The token transfer fails if the recipient is a contract
+     *      but does not implement the `tokenFallback` function
+     *      or the fallback function to receive funds.
+     *
+     * @param _to    Receiver address.
+     * @param _value Amount of tokens that will be transferred.
+     * @param _data  Transaction metadata.
+     */
+    function transfer(address _to, uint _value, bytes calldata _data) public returns (bool success)
+    {
+        // Standard function transfer similar to ERC20 transfer with no _data .
+        // Added due to backwards compatibility reasons .
+        balances[msg.sender] = balances[msg.sender] - _value;
+        balances[_to] = balances[_to] + _value;
+        if(Address.isContract(_to)) {
+            IERC223Recipient(_to).tokenReceived(msg.sender, _value, _data);
+        }
+        emit Transfer(msg.sender, _to, _value);
+        emit TransferData(_data);
+        return true;
+    }
+
+    /**
+     * @dev Transfer the specified amount of tokens to the specified address.
+     *      This function works the same with the previous one
+     *      but doesn't contain `_data` param.
+     *      Added due to backwards compatibility reasons.
+     *
+     * @param _to    Receiver address.
+     * @param _value Amount of tokens that will be transferred.
+     */
+    function transfer(address _to, uint _value) public returns (bool success)
+    {
+        bytes memory _empty = hex"00000000";
+        balances[msg.sender] = balances[msg.sender] - _value;
+        balances[_to] = balances[_to] + _value;
+        if(Address.isContract(_to)) {
+            IERC223Recipient(_to).tokenReceived(msg.sender, _value, _empty);
+        }
+        emit Transfer(msg.sender, _to, _value);
+        emit TransferData(_empty);
+        return true;
+    }
+}
+
+```
+
+
+## Copyright