Integrations common lib

common-lib/CONTRIB.md

@@ -0,0 +1,20 @@
+
+## Panels overview
+
+All panels in this lib should implement one of the following methods: 
+
+- `panel.new(title,targets,description)` - creates new panel. List of arguments could vary;
+- `panel.stylize(allLayers=true)` - directly applies this panel style to existing panel. By default includes all layers of styles. To apply only top layer, set allLayers=false. This mode is useful to cherry-pick style layers to create new style combination.
+
+Some other methods could be found such as:
+- `panel.stylizeByRegexp(regexp)` - attaches style as panel overrides (by regexp);
+- `panel.stylizeByName(name)` - attaches style as panel overrides (by name).
+
+## Panels common groups
+
+This library consists of multiple common groups of panels for widely used resources such as CPU, memory, disks and so on.
+
+All of those groups inherit `generic` group as their base.
+
+All panels inherit `generic/base.libsonnet` via `generic/<paneltype>/base.libsonnet`.
+

common-lib/Makefile

@@ -0,0 +1,23 @@
+JSONNET_FMT := jsonnetfmt -n 2 --max-blank-lines 1 --string-style s --comment-style s
+
+.PHONY: all
+all: build
+
+vendor: jsonnetfile.json
+	jb install
+
+.PHONY: build
+build: vendor
+
+.PHONY: fmt
+fmt:
+	find . -name 'vendor' -prune -o -name '*.libsonnet' -print -o -name '*.jsonnet' -print | \
+		xargs -n 1 -- $(JSONNET_FMT) -i
+
+.PHONY: lint
+lint: build
+	find . -name 'vendor' -prune -o -name '*.libsonnet' -print -o -name '*.jsonnet' -print | \
+		while read f; do \
+			$(JSONNET_FMT) "$$f" | diff -u "$$f" -; \
+		done
+

common-lib/README.md

@@ -0,0 +1,33 @@
+# Grafana integrations common lib
+
+This common library can be used to quickly create dashboards' `panels` and `annotations`.
+
+By using this common library we can 'enforce' common style choices across multiple dashboards and mixins.
+
+## Import
+
+```sh
+jb init
+jb install https://github.com/grafana/jsonnet-libs/common-lib
+```
+
+## Use
+
+### Create new panel
+
+```jsonnet
+
+local commonlib = import 'github.com/grafana/jsonnet-libs/common-lib/common/main.libsonnet';
+local cpuUsage = commonlib.panels.cpu.timeSeries.utilization.new(targets=[targets.cpuUsage]);
+
+```
+
+### Mutate exisiting panel with style options
+
+```jsonnet
+
+local commonlib = import 'github.com/grafana/jsonnet-libs/common-lib/common/main.libsonnet';
+local cpuPanel = oldPanel + commonlib.panels.cpu.timeSeries.utilization.stylize();
+```
+
+See [windows-observ-lib](./windows-observ-lib) for full example.

common-lib/common/annotations/base.libsonnet

@@ -0,0 +1,32 @@
+local g = import '../g.libsonnet';
+local annotation = g.dashboard.annotation;
+{
+  new(
+    title,
+    target,
+  ):
+    annotation.withEnable(true)
+    + annotation.withName(title)
+    + annotation.withDatasourceMixin(target.datasource)
+      {
+      titleFormat: title,
+      expr: target.expr,
+
+    }
+    + (if std.objectHas(target, 'interval') then { step: target.interval } else {}),
+
+  withTagKeys(value):
+    {
+      tagKeys: value,
+    },
+  withValueForTime(value=false):
+    {
+      useValueForTime: value,
+    },
+  withTextFormat(value=''):
+    {
+      textFormat: value,
+    },
+
+
+}

common-lib/common/annotations/fatal.libsonnet

@@ -0,0 +1,14 @@
+local g = import '../g.libsonnet';
+local annotation = g.dashboard.annotation;
+local base = import './base.libsonnet';
+
+// Show fatal or critical events as annotations
+base {
+  new(
+    title,
+    target,
+  ):
+    super.new(title, target)
+    + annotation.withIconColor('light-purple')
+    + annotation.withHide(true),
+}

common-lib/common/annotations/main.libsonnet

@@ -0,0 +1,6 @@
+{
+  base: import './base.libsonnet',
+  reboot: import './reboot.libsonnet',
+  serviceFailed: import './service_failed.libsonnet',
+  fatal: import './fatal.libsonnet',
+}

common-lib/common/annotations/reboot.libsonnet

@@ -0,0 +1,16 @@
+local g = import '../g.libsonnet';
+local annotation = g.dashboard.annotation;
+local base = import './base.libsonnet';
+
+base {
+  new(
+    title,
+    target,
+    instanceLabels,
+  ):
+    super.new(title, target)
+    + annotation.withIconColor('light-yellow')
+    + annotation.withHide(true)
+    + { useValueForTime: 'on' }
+    + base.withTagKeys(instanceLabels),
+}

common-lib/common/annotations/service_failed.libsonnet

@@ -0,0 +1,13 @@
+local g = import '../g.libsonnet';
+local annotation = g.dashboard.annotation;
+local base = import './base.libsonnet';
+
+base {
+  new(
+    title,
+    target,
+  ):
+    super.new(title, target)
+    + annotation.withIconColor('light-orange')
+    + annotation.withHide(true),
+}

common-lib/common/g.libsonnet

@@ -0,0 +1 @@
+import 'github.com/grafana/grafonnet/gen/grafonnet-v10.0.0/main.libsonnet'

common-lib/common/main.libsonnet

@@ -0,0 +1,5 @@
+{
+  annotations: import './annotations/main.libsonnet',
+  panels: import './panels.libsonnet',
+  utils: import './utils.libsonnet',
+}

common-lib/common/panels.libsonnet

@@ -0,0 +1,31 @@
+local g = import './g.libsonnet';
+
+{
+  generic: {
+    stat: import './panels/generic/stat/main.libsonnet',
+    timeSeries: import './panels/generic/timeSeries/main.libsonnet',
+    table: import './panels/generic/table/main.libsonnet',
+    statusHistory: import './panels/generic/statusHistory/main.libsonnet',
+  },
+  network: {
+    timeSeries: import './panels/network/timeSeries/main.libsonnet',
+  },
+  system: {
+    stat: import './panels/system/stat/main.libsonnet',
+    table: import './panels/system/table/main.libsonnet',
+    statusHistory: import './panels/system/statusHistory/main.libsonnet',
+  },
+  cpu: {
+    stat: import './panels/cpu/stat/main.libsonnet',
+    timeSeries: import './panels/cpu/timeSeries/main.libsonnet',
+  },
+  memory: {
+    stat: import './panels/memory/stat/main.libsonnet',
+    timeSeries: import './panels/memory/timeSeries/main.libsonnet',
+  },
+  disk: {
+    timeSeries: import './panels/disk/timeSeries/main.libsonnet',
+    table: import './panels/disk/table/main.libsonnet',
+    stat: import './panels/disk/stat/main.libsonnet',
+  },
+}

common-lib/common/panels/cpu/stat/base.libsonnet

@@ -0,0 +1,7 @@
+local g = import '../../../g.libsonnet';
+local stat = g.panel.stat;
+local base = import '../../generic/stat/base.libsonnet';
+
+base {
+
+}

common-lib/common/panels/cpu/stat/count.libsonnet

@@ -0,0 +1,21 @@
+local g = import '../../../g.libsonnet';
+local generic = import '../../generic/stat/main.libsonnet';
+local base = import './base.libsonnet';
+local stat = g.panel.stat;
+
+base {
+  new(
+    title='CPU count',
+    targets,
+    description=|||
+      CPU count is the number of processor cores or central processing units (CPUs) in a computer,
+      determining its processing capability and ability to handle tasks concurrently.
+    |||
+  ):
+    super.new(title, targets, description),
+
+  stylize(allLayers=true):
+    (if allLayers then super.stylize() else {})
+    + generic.info.stylize(allLayers=false),
+
+}

common-lib/common/panels/cpu/stat/main.libsonnet

@@ -0,0 +1,5 @@
+{
+  base: import './base.libsonnet',
+  usage: import './usage.libsonnet',
+  count: import './count.libsonnet',
+}

common-lib/common/panels/cpu/stat/usage.libsonnet

@@ -0,0 +1,22 @@
+local g = import '../../../g.libsonnet';
+local generic = import '../../generic/stat/main.libsonnet';
+local base = import './base.libsonnet';
+local stat = g.panel.stat;
+
+base {
+  new(
+    title='CPU usage',
+    targets,
+    description=|||
+      Total CPU utilization percent is a metric that indicates the overall level of central processing unit (CPU) usage in a computer system.
+      It represents the combined load placed on all CPU cores or processors.
+
+      For instance, if the total CPU utilization percent is 50%, it means that,
+      on average, half of the CPU's processing capacity is being used to execute tasks. A higher percentage indicates that the CPU is working more intensively, potentially leading to system slowdowns if it remains consistently high.
+    |||
+  ):
+    super.new(title, targets, description),
+  stylize(allLayers=true):
+    (if allLayers then super.stylize() else {})
+    + generic.percentage.stylize(allLayers=false),
+}

common-lib/common/panels/cpu/timeSeries/base.libsonnet

@@ -0,0 +1,6 @@
+local g = import '../../../g.libsonnet';
+local base = import '../../generic/timeSeries/base.libsonnet';
+
+base {
+
+}

common-lib/common/panels/cpu/timeSeries/main.libsonnet

@@ -0,0 +1,5 @@
+{
+  base: import './base.libsonnet',
+  utilization: import './utilization.libsonnet',
+  utilizationByMode: import './utilization_by_mode.libsonnet',
+}

common-lib/common/panels/cpu/timeSeries/utilization.libsonnet

@@ -0,0 +1,22 @@
+local g = import '../../../g.libsonnet';
+local generic = import '../../generic/timeSeries/main.libsonnet';
+local base = import './base.libsonnet';
+base {
+  new(
+    title='CPU usage',
+    targets,
+    description=|||
+      Total CPU utilization percent is a metric that indicates the overall level of central processing unit (CPU) usage in a computer system.
+      It represents the combined load placed on all CPU cores or processors.
+
+      For instance, if the total CPU utilization percent is 50%, it means that,
+      on average, half of the CPU's processing capacity is being used to execute tasks. A higher percentage indicates that the CPU is working more intensively, potentially leading to system slowdowns if it remains consistently high.
+    |||
+  ):
+    super.new(title, targets, description)
+    + self.stylize(),
+
+  stylize(allLayers=true):
+    (if allLayers then super.stylize() else {})
+    + generic.percentage.stylize(allLayers=false),
+}

common-lib/common/panels/cpu/timeSeries/utilization_by_mode.libsonnet

@@ -0,0 +1,45 @@
+local g = import '../../../g.libsonnet';
+local base = import './base.libsonnet';
+base {
+  new(
+    title='CPU usage by modes',
+    targets,
+    description='CPU usage by different modes.'
+  ):
+    super.new(title, targets, description)
+    + self.stylize(),
+
+  stylize(allLayers=true):
+    local timeSeries = g.panel.timeSeries;
+    local fieldOverride = g.panel.timeSeries.fieldOverride;
+
+    (if allLayers then super.stylize() else {})
+
+    + timeSeries.standardOptions.withUnit('percent')
+    + timeSeries.fieldConfig.defaults.custom.withFillOpacity(80)
+    + timeSeries.fieldConfig.defaults.custom.withStacking({ mode: 'normal' })
+    + timeSeries.standardOptions.withOverrides(
+      [
+        fieldOverride.byName.new('idle')
+        + fieldOverride.byName.withPropertiesFromOptions(
+          timeSeries.standardOptions.color.withMode('fixed')
+          + timeSeries.standardOptions.color.withFixedColor('light-blue'),
+        ),
+        fieldOverride.byName.new('interrupt')
+        + fieldOverride.byName.withPropertiesFromOptions(
+          timeSeries.standardOptions.color.withMode('fixed')
+          + timeSeries.standardOptions.color.withFixedColor('light-purple'),
+        ),
+        fieldOverride.byName.new('user')
+        + fieldOverride.byName.withPropertiesFromOptions(
+          timeSeries.standardOptions.color.withMode('fixed')
+          + timeSeries.standardOptions.color.withFixedColor('light-orange'),
+        ),
+        fieldOverride.byRegexp.new('system|privileged')
+        + fieldOverride.byRegexp.withPropertiesFromOptions(
+          timeSeries.standardOptions.color.withMode('fixed')
+          + timeSeries.standardOptions.color.withFixedColor('light-red'),
+        ),
+      ]
+    ),
+}

common-lib/common/panels/disk/stat/base.libsonnet

@@ -0,0 +1,6 @@
+local g = import '../../../g.libsonnet';
+local stat = g.panel.stat;
+local base = import '../../generic/stat/base.libsonnet';
+
+base {
+}

common-lib/common/panels/disk/stat/main.libsonnet

@@ -0,0 +1,4 @@
+{
+  base: import './base.libsonnet',
+  total: import './total.libsonnet',
+}

common-lib/common/panels/disk/stat/total.libsonnet

@@ -0,0 +1,20 @@
+local g = import '../../../g.libsonnet';
+local generic = import '../../generic/stat/main.libsonnet';
+local base = import './base.libsonnet';
+local stat = g.panel.stat;
+
+base {
+  new(
+    title,
+    targets,
+    description=''
+  ):
+    super.new(title=title, targets=targets, description=description),
+
+  stylize(allLayers=true):
+
+    (if allLayers then super.stylize() else {})
+
+    + generic.info.stylize(allLayers=false)
+    + stat.standardOptions.withUnit('bytes'),
+}

common-lib/common/panels/disk/table/base.libsonnet

@@ -0,0 +1,10 @@
+local g = import '../../../g.libsonnet';
+local base = import '../../generic/table/base.libsonnet';
+local table = g.panel.table;
+local fieldOverride = g.panel.table.fieldOverride;
+local custom = table.fieldConfig.defaults.custom;
+local defaults = table.fieldConfig.defaults;
+local options = table.options;
+base {
+
+}

common-lib/common/panels/disk/table/main.libsonnet

@@ -0,0 +1,4 @@
+{
+  base: import './base.libsonnet',
+  usage: import './usage.libsonnet',
+}