feat(stdlib): Add String.repeat to String module

compiler/test/stdlib/string.test.gr

@@ -551,3 +551,12 @@ assert String.toAsciiLowercase("aBc🌾12Y") == "abc🌾12y"
 
 // toAsciiUppercase
 assert String.toAsciiUppercase("aBc🌾12Y") == "ABC🌾12Y"
+
+// String.repeat
+assert String.repeat("=.", 1) == "=."
+assert String.repeat("=", 10) == "=========="
+assert String.repeat("=.", 10) == "=.=.=.=.=.=.=.=.=.=."
+assert String.repeat("=.", 0) == ""
+assert String.repeat("", 0) == ""
+assert String.repeat("=.", -1) == ".="
+assert String.repeat("=.", -10) == ".=.=.=.=.=.=.=.=.=.="

stdlib/string.gr

@@ -2338,3 +2338,45 @@ provide let toAsciiUppercase = string => {
   }
   implode(chars)
 }
+
+/**
+ * Produces a new string by repeating a given substring a given number of times.
+ *
+ * @param string: The string to repeat
+ * @param count: The number of times to repeat, negative values reverse the substring
+ * @returns A string containing the repeated input string
+ *
+ * @throws InvalidArgument(String): When the `count` is not an integer
+ *
+ * @example assert String.repeat("=", 5) == "====="
+ * @example assert String.repeat("ab", -5) == "bababababa"
+ * @example assert String.repeat(".", 0) == ""
+ *
+ * @since v0.6.7
+ */
+@unsafe
+provide let repeat = (string, count) => {
+  use WasmI32.{ (+), (*), (<), (&), (!=) }
+  if ((WasmI32.fromGrain(count) & 1n) != 1n) {
+    throw InvalidArgument("Invalid count value")
+  }
+  let mut rawCount = untagSimpleNumber(count)
+  if (WasmI32.eqz(rawCount)) return ""
+  let string = if (rawCount < 0n) {
+    rawCount *= -1n
+    reverse(string)
+  } else {
+    string
+  }
+  let mut stringPtr = WasmI32.fromGrain(string)
+  let byteLength = WasmI32.load(stringPtr, 4n)
+  if (WasmI32.eqz(byteLength)) return ""
+  stringPtr += 8n
+  let strPtr = allocateString(byteLength * rawCount)
+  let strContentPtr = strPtr + 8n
+  for (let mut i = 0n; i < rawCount; i += 1n) {
+    Memory.copy(strContentPtr + byteLength * i, stringPtr, byteLength)
+  }
+  ignore(stringPtr)
+  return WasmI32.toGrain(strPtr): String
+}

stdlib/string.md

@@ -1174,3 +1174,49 @@ Examples:
 assert String.toAsciiUppercase("aBc123") == "ABC123"
 ```
 
+### String.**repeat**
+
+<details disabled>
+<summary tabindex="-1">Added in <code>next</code></summary>
+No other changes yet.
+</details>
+
+```grain
+repeat : (string: String, count: Number) => String
+```
+
+Produces a new string by repeating a given substring a given number of times.
+
+Parameters:
+
+|param|type|description|
+|-----|----|-----------|
+|`string`|`String`|The string to repeat|
+|`count`|`Number`|The number of times to repeat, negative values reverse the substring|
+
+Returns:
+
+|type|description|
+|----|-----------|
+|`String`|A string containing the repeated input string|
+
+Throws:
+
+`InvalidArgument(String)`
+
+* When the `count` is not an integer
+
+Examples:
+
+```grain
+assert String.repeat("=", 5) == "====="
+```
+
+```grain
+assert String.repeat("ab", -5) == "bababababa"
+```
+
+```grain
+assert String.repeat(".", 0) == ""
+```
+