2 quick questions — setting :extra_paths for jedi

[jdtsmith]

I'm trying to enable some extra paths which contain stubs for micropython. I have a .dir-locals.el in my project root with:

((python-mode
  . ((eglot-workspace-configuration
      . ((:pylsp . (:plugins (:jedi (:extra_paths [".stubs/cpython_core/"])))))))))

This works, but only for python files at the root level. Is there a way to refer to the project root generically in eglot-workspace-configuration? Also, when I try to include multiple paths (each of which work on their own):

((python-mode
  . ((eglot-workspace-configuration
      . ((:pylsp . (:plugins (:jedi (:extra_paths [".stubs/cpython_core/",".stubs/micropython-esp32-1_16/"])))))))))

pylsp complains about unhashable dict:

 File \"/usr/local/lib/python3.9/site-packages/jedi/api/project.py\", line 58, in _remove_duplicates_from_path\n    if p in used:\n"])))
[internal] (id:27) ERROR Fri Sep  3 13:44:03 2021:
(:message "error ignored, status set (TypeError: unhashable type: 'dict')" :id 27 :error -32602)

Is my syntax above for multiple :extra_paths valid?

[jdtsmith]

OK I solved this myself. It turns out Emacs 27's fast json-serialize is rather fussy, and can only serialize vectors, not lists (unlike json-encode, which it replaces). Here's how I solved both issues (in .dir-locals.el):

((python-mode
  . ((eval . (let* ((stubs '("micropython_cpython_core" ;order matters
			     "micropython-1_14-frozen/esp32/RELEASE"
			     "micropython-esp32-1_16"))
		    (project-path (expand-file-name
				   (locate-dominating-file default-directory ".dir-locals.el")))
		    (stub-paths
		     (vconcat ; json-serialize hates lists
		      (mapcar (lambda (x) (concat project-path ".stubs/" x "/")) stubs))))
	       (setq eglot-workspace-configuration ;an alist
		     `((:pylsp . (:plugins (:jedi (:extra_paths ,stub-paths)))))))))))

This allows me to symlink a full directory of stubs files (I'm using micropython-stubs) into every /my/package/.stub, then pick and choose an ordered list of stub directories for jedi to use for completion/syntax/etc. Working great.