quitting a transient from code

[jave]

The code below is a little experiment that i use for emacs interaction with the i3 or sway style wm:s

you bind super-x in sway(or i3) and then an emacs frame pops up with a transient in it.
this works well.

but if i change my mind, id like to press super-x again, and kill the frame.

this also works but, now in the main emacs frame, the transient lives on, which I find counterintuitive.
If I properly quit the transient in the popup frame the transient doesn live on anywhere.

So, the feature request is that it should be possible to quit the transient from code like this.

You can see the various attempts i made in the messy code below.

heres the tries i made extracted:

    (keyboard-escape-quit)
                              ;;(transient--do-quit-all)
                              ;;(transient-suspend)
                              ;;(transient-quit-all) ;;

and heres the complete code

 ;; add this to i3/sway config

  ;;# bind s-x to the defun below
  ;;bindsym $mod+x exec "emacsclient -e '(i3wm-s-x)'"
  ;;# "emacs-super-x" matches a rule in i3wm config, so the window becomes floating
  ;;for_window [title="emacs-super-x"] floating enable, sticky enable

(require 'transient)

(transient-define-prefix my-simple-menu ()
  "A simple transient menu example."
  ["Super-X Menu"
   ["Actions"
    ("c" "Calendar" calendar)
    ("s" "Shell" shell)]
   ["Org" 
    ("os" "Orgscratch" (lambda () (interactive) (switch-to-buffer "orgscratch.org")) )    
    ("oj" "Journal" (lambda () (interactive) (org-capture '(4) "j")
                      ;;(org-capture nil "j")
                      ))
    ("ot" "Task in orgscratch" (lambda () (interactive) (org-capture nil "s")) )
    ("oa" "Agenda" (lambda () (interactive)
                     ;;(set-frame-name "new name")
                     (switch-to-or-create-agenda)
                     ;;(toggle-frame-fullscreen)
                     (set-frame-size emacs-super-x-frame 100 40)
                     )     )
    ]
   
   ["sWay stuff"
    ("w2" "ws 2" (lambda () (interactive) (shell-command "swaymsg workspace 2")))
    ;;("s3" "do sway thing" (lambda ()(interactive)(message "sway thing")))
    ;;("s2" "jump to 2" (lambda () (interactive)(shell-comand "swaymsg workspace 2")))
    ]
   
   
   ["Utils"
    ("q" "Quit" transient-quit-one)]])


;;(org-capture '(4) "j")
  (defvar emacs-super-x-frame nil)
  (defun i3wm-s-x()
    (interactive)
    ;; this starts a floating frame, and runs m-x
    ;; s-x again should close the frame i think
    (if emacs-super-x-frame (progn
                              (keyboard-escape-quit)
                              ;;(transient--do-quit-all)
                              ;;(transient-suspend)
                              ;;(transient-quit-all) ;; tried to kill the transient but didnt seem to wwok
                              (delete-frame emacs-super-x-frame)
                              (setq emacs-super-x-frame nil)
                                   
                                   )
      (progn 
        (setq emacs-super-x-frame (make-frame '((name ."emacs-super-x")
		                                (width . 160)
		                                (height . 20)
		                                ;;(minibuffer . only)
		                                )))
        (select-frame-set-input-focus emacs-super-x-frame)
        ;;(execute-extended-command "")
        ;;(sleep-for 0.1)
        ;;(hydra-termux/body)
        (my-simple-menu)
        
        )))

[tarsius]

bindsym Shift+F6 exec emacsclient -e "(call-interactively 'i3wm-menu)"
for_window [title="i3wm-menu"] floating enable, border pixel 2

;; SPDX-License-Identifier: GPL-3.0-or-later
;; Author: Jonas Bernoulli <emacs.transient@jonas.bernoulli.dev>
;; URL: https://github.com/magit/transient/discussions/318

(defvar i3wm-menu--frame nil)

(defvar i3wm-menu-frame-alist
  '((width  . 80)
    (height . 20)))

(defvar i3wm-menu-display-buffer-action
  ;; Use nil to display like other transient menus.
  '(display-buffer-full-frame))

(defvar i3wm-menu-display-menu-immediately nil)

(defun i3wm-menu--setup-menu (&optional display-frame-phase)
  (when (or (not display-frame-phase)
            i3wm-menu-display-menu-immediately)
    (let ((transient-display-buffer-action
           (or i3wm-menu-display-buffer-action
               transient-display-buffer-action)))
      (transient-setup 'i3wm-menu))))

(defun i3wm-menu--select-frame ()
  ;; Prevent i3wm from reselecting another frame the mouse may hover.
  (set-mouse-position i3wm-menu--frame 25 1)
  (select-frame-set-input-focus i3wm-menu--frame))

(transient-define-suffix i3wm-menu-scratch ()
  :description "scratch"
  (interactive)
  (switch-to-buffer (get-buffer-create "*scratch*")))

(transient-define-prefix i3wm-menu ()
  [["Show"
    ("s" i3wm-menu-scratch)
    ("c" "calendar" calendar)]
   ["Control i3wm frame/menu"
    ("C-g" "quit menu"  transient-quit-all)
    ("q  " "quit frame" make-frame-invisible)
    ("k  " "kill frame" delete-frame)]]
  (interactive)
  (cond
   ((not (frame-live-p i3wm-menu--frame))
    (setq i3wm-menu--frame
          (make-frame (cons '(name . "i3wm-menu")
                            i3wm-menu-frame-alist)))
    (i3wm-menu--select-frame)
    (i3wm-menu-scratch)
    (i3wm-menu--setup-menu 'maybe))
   ((not (eq i3wm-menu--frame (selected-frame)))
    (i3wm-menu--select-frame)
    (i3wm-menu--setup-menu 'maybe))
   ((not (transient-active-prefix 'i3wm-menu))
    (i3wm-menu--setup-menu))
   ((make-frame-invisible))))

[jave]

many thanks!

atm i dont quite see how the code works, so i will have to try it and see.

again thanks