mirage-crypto-rng-eio: Eio backend of mirage-crypto-rng

.cirrus.yml

@@ -6,9 +6,37 @@ freebsd_task:
     matrix:
       - OCAML_VERSION: 4.11.1
       - OCAML_VERSION: 4.12.0
+
+  pkg_install_script: pkg install -y ocaml-opam gmp gmake pkgconf bash
+
+  ocaml_script: 
+    - opam init -a --comp=$OCAML_VERSION
+    - opam env
+
+  pin_packages_script: 
+    - opam install -y solo5-bindings-hvt zarith-freestanding opam-depext
+    - opam pin add mirage-crypto . -y --with-version=0.10.6  --with-test
+    - opam pin add mirage-crypto-rng . -y --with-version=0.10.6 --with-test
+    - opam pin add mirage-crypto-rng-mirage . -y --with-version=0.10.6 --with-test
+    - opam pin add mirage-crypto-pk . -y  --with-version=0.10.6 --with-test
+    - opam pin add mirage-crypto-ec . -y --with-version=0.10.6 --with-test
+    - opam pin add mirage-crypto-rng-async . -y --with-version=0.10.6 --with-test
+
+  test_script: opam exec -- dune runtest tests
+  test_mirage_script: eval `opam env` && ./.test-mirage.sh
+
+freebsd_eio_task: 
   pkg_install_script: pkg install -y ocaml-opam gmp gmake pkgconf bash
-  ocaml_script: opam init -a --comp=$OCAML_VERSION
-  dependencies_script: eval `opam env` && opam install -y --deps-only .
-  build_script: eval `opam env` && dune build @install
-  test_script: eval `opam env` && opam install -y -t --deps-only . && dune build @runtest
-  test_mirage_script: eval `opam env` && opam install -y solo5-bindings-hvt zarith-freestanding opam-depext && opam pin add -y . && ./.test-mirage.sh
+
+  ocaml_script: 
+    - opam init -a --bare
+    - opam update
+    - opam switch create 5.0.0~alpha0 --repositories=default,alpha=git+https://github.com/kit-ty-kate/opam-alpha-repository.git
+    - opam env
+
+  pin_packages_script: 
+    - opam pin add mirage-crypto . -y --with-version=dev
+    - opam pin add mirage-crypto-rng . -y --with-version=dev
+    - opam pin add mirage-crypto-rng-eio . -y --with-version=dev --with-test
+
+  test_script: opam exec -- dune runtest eio

.github/workflows/test.yml

@@ -21,13 +21,51 @@ jobs:
       - name: Use OCaml ${{ matrix.ocaml-version }}
         uses: ocaml/setup-ocaml@v2
         with:
+          opam-local-packages: |
+            *.opam
+            !mirage-crypto-rng-eio.opam
           ocaml-compiler: ${{ matrix.ocaml-version }}
 
       - name: Install dependencies
-        run: opam install --deps-only -t .
+        run: opam install --deps-only -t mirage-crypto mirage-crypto-rng mirage-crypto-rng-mirage mirage-crypto-pk mirage-crypto-ec mirage-crypto-rng-async
 
       - name: Build
-        run: opam exec -- dune build
+        run: opam exec -- dune build -p mirage-crypto,mirage-crypto-rng,mirage-crypto-rng-mirage,mirage-crypto-pk,mirage-crypto-ec,mirage-crypto-rng-async
 
       - name: Test
-        run: opam exec -- dune runtest
+        run: opam exec -- dune runtest tests
+
+  build-test-unix-eio:
+    name : Unix (eio)
+    strategy:
+      fail-fast: false
+      matrix:
+        ocaml-version: [ocaml-variants.5.0.0+trunk]
+        operating-system: [macos-latest, ubuntu-latest]
+
+    runs-on: ${{ matrix.operating-system }}
+
+    steps:
+      - name: Checkout code
+        uses: actions/checkout@v2
+
+      - name: Use OCaml ${{ matrix.ocaml-version }}
+        uses: ocaml/setup-ocaml@v2
+        with:
+          opam-local-packages: |
+            mirage-crypto.opam
+            mirage-crypto-rng.opam
+            mirage-crypto-rng-eio.opam
+          ocaml-compiler: ${{ matrix.ocaml-version }}
+          opam-repositories: |
+            default: https://github.com/ocaml/opam-repository.git
+            alpha: https://github.com/kit-ty-kate/opam-alpha-repository.git
+
+      - name: Install dependencies
+        run: opam install --deps-only -t mirage-crypto mirage-crypto-rng mirage-crypto-rng-eio
+
+      - name: Build
+        run: opam exec -- dune build -p mirage-crypto,mirage-crypto-rng,mirage-crypto-rng-eio
+
+      - name: Test
+        run: opam exec -- dune runtest eio

.github/workflows/windows.yml

@@ -18,12 +18,13 @@ jobs:
       - name: Checkout code
         uses: actions/checkout@v2
 
-      - name: Use OCaml ${{ matrix.ocaml-version }}
+      - name: Use OCaml ${{ matrix.ocaml-compiler }}
         uses: ocaml/setup-ocaml@v2
         with:
           opam-local-packages: |
             *.opam
             !mirage-crypto-rng-async.opam
+            !mirage-crypto-rng-eio.opam
           ocaml-compiler: ${{ matrix.ocaml-version }}
 
       - name: Install dependencies

eio/src/dune

@@ -0,0 +1,10 @@
+(library
+ (name mirage_crypto_rng_eio)
+ (public_name mirage-crypto-rng-eio)
+ (libraries 
+   eio 
+   cstruct 
+   logs 
+   mirage-crypto-rng 
+   duration 
+   mtime.clock.os))

eio/src/mirage_crypto_rng_eio.ml

@@ -0,0 +1,81 @@
+open Mirage_crypto_rng 
+
+type env = <
+  clock: Eio.Time.clock;
+  secure_random: Eio.Flow.source;
+>
+
+let src = Logs.Src.create "mirage-crypto-rng-eio" ~doc:"Mirage crypto RNG Eio"
+module Log = (val Logs.src_log src: Logs.LOG)
+
+let getrandom env i = 
+  let buf = Cstruct.create i in
+  Eio.Flow.read_exact env#secure_random buf;
+  buf
+
+let getrandom_init env i = 
+  let data = getrandom env 128 in
+  Entropy.header i data
+
+let rec periodic env f delta =
+  f ();
+  Eio.Time.sleep env#clock (Duration.to_f delta);
+  periodic env f delta 
+
+let periodically_feed_entropy env delta source = 
+  let task () = 
+    let per_pool = 8 in
+    let size = per_pool * pools None in
+    let random = getrandom env size in
+    let idx = ref 0 in
+    let f () = 
+      incr idx;
+      Cstruct.sub random (per_pool * (pred !idx)) per_pool
+    in
+    Entropy.feed_pools None source f
+  in 
+  periodic env task delta
+
+let rdrand_task env delta = 
+  match Entropy.cpu_rng with
+  | Error `Not_supported -> []
+  | Ok cpu_rng -> [ fun () -> periodic env (cpu_rng None) delta ]
+
+let running = ref false 
+
+let run 
+    ?g
+    ?(sleep = Duration.of_sec 1) 
+    generator 
+    env
+    fn 
+  = 
+    if !running then begin 
+      Log.debug
+        (fun m -> m "Mirage_crypto_rng_eio.initialize has already been called, \
+                     ignoring this call.");
+      fn () 
+    end
+    else begin
+      running := true;
+      Fun.protect 
+        ~finally:( fun () -> running := false ) 
+        (fun () ->
+          (try
+            let _ = default_generator () in
+            Log.warn (fun m -> m "Mirage_crypto_rng.default_generator has already \
+                                  been set, check that this call is intentional");
+           with 
+            No_default_generator -> ());
+          let seed = 
+            let init = 
+              Entropy.[ bootstrap ; whirlwind_bootstrap ; bootstrap ; getrandom_init env ] in
+            List.mapi (fun i f -> f i) init |> Cstruct.concat
+          in 
+          let rng = create ?g ~seed ~time:Mtime_clock.elapsed_ns generator in
+          set_default_generator rng;
+          let source = Entropy.register_source "getrandom" in
+          let feed_entropy () = periodically_feed_entropy env (Int64.mul sleep 10L) source in
+          Eio.Fiber.any (rdrand_task env sleep @ [feed_entropy ; fn])
+        )
+    end 

eio/src/mirage_crypto_rng_eio.mli

@@ -0,0 +1,32 @@
+(** {b RNG} seeding on {b Eio backends}.
+
+    This module initializes a Fortuna RNG with [getrandom()], and CPU RNG.
+    [Eio.Stdenv.secure_random] is used as the [getrandom()] implementation.
+*)
+
+type env = <
+  clock: Eio.Time.clock;
+  secure_random: Eio.Flow.source;
+  >
+
+(** [run ~sleep env fn] will bring the RNG into a working state. The argument
+    [sleep] is measured in ns (default 1s), and used to sleep between collection
+    of entropy from the CPU RNG, every [10 * sleep] getrandom is used to collect
+    entropy.
+
+    [fn] is the main function that will have access to a running RNG.
+
+    [[
+      let () =
+        Eio_main.run @@ fun env ->
+        Mirage_crypto_rng_eio.run (module Mirage_crypto_rng.Fortuna) env @@ fun () -> 
+        let random_num = Mirage_crypto_rng.generate 32 in 
+        Printf.printf "Random number: %S%!" (Cstruct.to_string random_num)
+    ]]
+*)
+val run 
+  :  ?g:'a
+  -> ?sleep:int64 
+  -> 'a Mirage_crypto_rng.generator
+  -> <env; ..> 
+  -> (unit -> 'b) -> 'b

eio/tests/dune

@@ -0,0 +1,4 @@
+(tests
+ (names     test_eio_rng test_entropy_collection)
+ (libraries mirage-crypto-rng-eio duration eio_main)
+ (package   mirage-crypto-rng-eio))

eio/tests/test_eio_rng.ml

@@ -0,0 +1,11 @@
+open Mirage_crypto_rng
+
+let () = 
+  Eio_main.run @@ fun env -> 
+  Mirage_crypto_rng_eio.run (module Fortuna) env @@ fun () ->
+  let random_num = Mirage_crypto_rng.generate 32 in 
+  assert (Cstruct.length random_num = 32);
+  Printf.printf "32 bit random number: %S\n%!" (Cstruct.to_string random_num);
+  let random_num = Mirage_crypto_rng.generate 16 in 
+  assert (Cstruct.length random_num = 16);
+  Printf.printf "16 bit random number: %S\n%!" (Cstruct.to_string random_num);

eio/tests/test_entropy_collection.ml

@@ -0,0 +1,36 @@
+module Printing_rng = struct
+  type g = unit
+
+  let block = 16
+  let create ?time:_ () = ()
+  let generate ~g:_ _n = assert false
+  let seeded ~g:_ = true
+  let pools = 1
+
+  let reseed ~g:_ data =
+    Format.printf "reseeding: %a@.%!" Cstruct.hexdump_pp data
+
+  let accumulate ~g:_ source =
+    let print data =
+      Format.printf "accumulate: (src: %a) %a@.%!"
+        Mirage_crypto_rng.Entropy.pp_source source Cstruct.hexdump_pp data
+    in
+    `Acc print
+end
+
+let () =
+  Eio_main.run @@ fun env -> 
+  Mirage_crypto_rng_eio.run (module Printing_rng) env @@ fun () ->
+  Eio.Fiber.both 
+    begin fun () ->
+       let sleep = Duration.(of_sec 2 |> to_f) in
+       Eio.Time.sleep env#clock sleep
+    end
+    begin fun () -> 
+      Format.printf "entropy sources: %a@,%!"
+        (fun ppf -> List.iter (fun x ->
+             Mirage_crypto_rng.Entropy.pp_source ppf x;
+             Format.pp_print_space ppf ()))
+        (Mirage_crypto_rng.Entropy.sources ())
+    end
+

mirage-crypto-rng-eio.opam

@@ -0,0 +1,29 @@
+opam-version: "2.0"
+homepage:     "https://github.com/mirage/mirage-crypto"
+dev-repo:     "git+https://github.com/mirage/mirage-crypto.git"
+bug-reports:  "https://github.com/mirage/mirage-crypto/issues"
+doc:          "https://mirage.github.io/mirage-crypto/doc"
+authors:      ["Bikal Gurung <gbikal@gmail.com>" ]
+maintainer:   "Bikal Gurung <gbikal@gmail.com>"
+license:      "ISC"
+synopsis:     "Feed the entropy source in an eio-friendly way"
+
+build: [ ["dune" "subst"] {dev}
+         ["dune" "build" "-p" name "-j" jobs ]
+         ["dune" "runtest" "-p" name "-j" jobs] {with-test} ]
+
+depends: [
+  "base-domains"
+  "dune" {>= "3.0"}
+  "eio" {>= "0.3"}
+  "cstruct" {>= "6.0.0"}
+  "logs"
+  "mirage-crypto-rng" {=version}
+  "duration"
+  "mtime"
+  "eio_main" {with-test}
+]
+description: """
+Mirage-crypto-rng-eio feeds the entropy source for Mirage_crypto_rng-based
+random number genreator implementations, in an eio-friendly way.
+"""