Integrate mongodb-crypt module

build.gradle

@@ -55,7 +55,6 @@ ext {
     zstdVersion = '1.5.5-3'
     awsSdkV2Version = '2.18.9'
     awsSdkV1Version = '1.12.337'
-    mongoCryptVersion = '1.11.0'
     projectReactorVersion = '2022.0.0'
     junitBomVersion = '5.10.2'
     logbackVersion = '1.3.14'

driver-core/build.gradle

@@ -39,6 +39,7 @@ dependencies {
     implementation project(path: ':bson-record-codec', configuration: 'default')
     implementation project(path: ':bson-kotlin', configuration: 'default'), optional
     implementation project(path: ':bson-kotlinx', configuration: 'default'), optional
+    implementation project(path: ':mongocrypt', configuration: 'default'), optional
 
     implementation "com.github.jnr:jnr-unixsocket:$jnrUnixsocketVersion", optional
     api platform("io.netty:netty-bom:$nettyVersion")
@@ -55,7 +56,6 @@ dependencies {
 
     implementation "org.xerial.snappy:snappy-java:$snappyVersion", optional
     implementation "com.github.luben:zstd-jni:$zstdVersion", optional
-    implementation "org.mongodb:mongodb-crypt:$mongoCryptVersion", optional
 
     testImplementation project(':bson').sourceSets.test.output
     testImplementation('org.junit.jupiter:junit-jupiter-api')

graalvm-native-image-app/build.gradle

@@ -82,12 +82,12 @@ dependencies {
     implementation project(path:':driver-sync', configuration:'archives')
     implementation project(path:':driver-reactive-streams', configuration:'archives')
     implementation project(path:':driver-legacy', configuration:'archives')
+    implementation project(path: ':mongocrypt', configuration: 'archives')
     // note that as a result of these `sourceSets` dependencies, `driver-sync/src/test/resources/logback-test.xml` is used
     implementation project(':driver-core').sourceSets.test.output
     implementation project(':driver-sync').sourceSets.test.output
     implementation project(':driver-legacy').sourceSets.test.output
     implementation project(':driver-reactive-streams').sourceSets.test.output
-    implementation "org.mongodb:mongodb-crypt:$mongoCryptVersion"
     implementation 'org.slf4j:slf4j-api:2.0.12'
     implementation "ch.qos.logback:logback-classic:$logbackVersion"
     implementation platform("io.projectreactor:reactor-bom:$projectReactorVersion")

mongocrypt/.gitignore

@@ -0,0 +1,39 @@
+*~
+.#*
+.git
+*#
+
+# os x stuff
+*Thumbs.db*
+*.DS_Store
+
+# Build artifacts
+build
+out
+
+# Eclipse files
+.classpath
+.project
+.settings
+
+# Intellij IDEA files
+*.ipr
+*.iws
+*.iml
+*.idea
+workspace.xml
+atlassian-ide-plugin.xml
+
+# gradle
+.gradle
+
+# local settings
+**/gradle.properties
+local.properties
+
+# jenv
+.java-version
+
+# bin
+/bin
+/benchmarks/bin

mongocrypt/build.gradle.kts

@@ -0,0 +1,189 @@
+/*
+ * Copyright 2019-present MongoDB, Inc.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+import de.undercouch.gradle.tasks.download.Download
+import java.io.ByteArrayOutputStream
+
+buildscript {
+    repositories {
+        mavenCentral()
+        google()
+    }
+    dependencies {
+        "classpath"(group = "net.java.dev.jna", name = "jna", version = "5.11.0")
+    }
+}
+
+plugins {
+    // Needed to download libmongocrypt from s3.
+    id("de.undercouch.download") version "5.6.0"
+}
+
+group = "org.mongodb"
+base.archivesBaseName = "mongodb-crypt"
+description = "MongoDB client-side crypto support"
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_1_8
+    targetCompatibility = JavaVersion.VERSION_1_8
+}
+
+dependencies {
+    api(project(path = ":bson", configuration = "default"))
+    api("net.java.dev.jna:jna:5.11.0")
+
+    // Tests
+    testImplementation("org.junit.jupiter:junit-jupiter")
+    testRuntimeOnly("ch.qos.logback:logback-classic:1.2.11")
+}
+
+/*
+ * Git version information
+ */
+// Returns a String representing the output of `git describe`
+val gitDescribe by lazy {
+    val describeStdOut = ByteArrayOutputStream()
+    exec {
+        commandLine = listOf("git", "describe", "--tags", "--always", "--dirty")
+        standardOutput = describeStdOut
+    }
+    describeStdOut.toString().trim()
+}
+
+val isJavaTag by lazy { gitDescribe.startsWith("java") }
+val gitVersion by lazy { gitDescribe.subSequence(gitDescribe.toCharArray().indexOfFirst { it.isDigit() }, gitDescribe.length).toString() }
+
+val defaultDownloadRevision = "9a88ac5698e8e3ffcd6580b98c247f0126f26c40" // r.1.11.0
+
+/*
+ * Jna copy or download resources
+ */
+val jnaDownloadsDir = "$buildDir/jnaLibs/downloads/"
+val jnaResourcesDir = "$buildDir/jnaLibs/resources/"
+val jnaLibPlatform: String = if (com.sun.jna.Platform.RESOURCE_PREFIX.startsWith("darwin")) "darwin" else com.sun.jna.Platform.RESOURCE_PREFIX
+val jnaLibsPath: String = System.getProperty("jnaLibsPath", "${jnaResourcesDir}${jnaLibPlatform}")
+val jnaResources: String = System.getProperty("jna.library.path", jnaLibsPath)
+
+// Download jnaLibs that match the git to jnaResourcesBuildDir
+val downloadRevision: String = System.getProperties().computeIfAbsent("gitRevision") { k -> defaultDownloadRevision }.toString()
+val binariesArchiveName = "libmongocrypt-java.tar.gz"
+
+val downloadUrl: String = "https://mciuploads.s3.amazonaws.com/libmongocrypt/java/$downloadRevision/$binariesArchiveName"
+
+val jnaMapping: Map<String, String> = mapOf(
+    "rhel-62-64-bit" to "linux-x86-64",
+    "rhel72-zseries-test" to "linux-s390x",
+    "rhel-71-ppc64el" to "linux-ppc64le",
+    "ubuntu1604-arm64" to "linux-aarch64",
+    "windows-test" to "win32-x86-64",
+    "macos" to "darwin"
+)
+
+sourceSets {
+    main {
+        java {
+            resources {
+                srcDirs(jnaResourcesDir)
+            }
+        }
+    }
+}
+
+tasks.register<Download>("downloadJava") {
+    src(downloadUrl)
+    dest("${jnaDownloadsDir}/$binariesArchiveName")
+    overwrite(true)
+}
+
+// The `processResources` task (defined by the `java-library` plug-in) consumes files in the main source set.
+// Add a dependency on `unzipJava`. `unzipJava` adds libmongocrypt libraries to the main source set.
+tasks.processResources {
+    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
+    mustRunAfter(tasks.named("unzipJava"))
+}
+
+tasks.register<Copy>("unzipJava") {
+    outputs.upToDateWhen { false }
+    from(tarTree(resources.gzip("${jnaDownloadsDir}/$binariesArchiveName")))
+    include(jnaMapping.keys.flatMap {
+        listOf("${it}/nocrypto/**/libmongocrypt.so", "${it}/lib/**/libmongocrypt.dylib", "${it}/bin/**/mongocrypt.dll" )
+    })
+    eachFile {
+        path = "${jnaMapping[path.substringBefore("/")]}/${name}"
+    }
+    into(jnaResourcesDir)
+    mustRunAfter("downloadJava")
+
+    doLast {
+        println("jna.library.path contents: \n  ${fileTree(jnaResourcesDir).files.joinToString(",\n  ")}")
+    }
+}
+
+tasks.register("downloadJnaLibs") {
+    dependsOn("downloadJava", "unzipJava")
+}
+
+tasks.test {
+    systemProperty("jna.debug_load", "true")
+    systemProperty("jna.library.path", jnaResources)
+    useJUnitPlatform()
+    testLogging {
+        events("passed", "skipped", "failed")
+    }
+
+    doFirst {
+        println("jna.library.path contents:")
+        println(fileTree(jnaResources)  {
+            this.setIncludes(listOf("*.*"))
+        }.files.joinToString(",\n  ", "  "))
+    }
+    dependsOn("downloadJnaLibs", "downloadJava", "unzipJava")
+}
+
+tasks.withType<AbstractPublishToMaven> {
+    description = """$description
+        | System properties:
+        | =================
+        |
+        | jnaLibsPath    : Custom local JNA library path for inclusion into the build (rather than downloading from s3)
+        | gitRevision    : Optional Git Revision to download the built resources for from s3.
+    """.trimMargin()
+}
+
+tasks.jar {
+    manifest {
+        attributes(
+                "-exportcontents" to "com.mongodb.crypt.capi.*;-noimport:=true",
+                "Automatic-Module-Name" to "com.mongodb.crypt.capi",
+                "Import-Package" to "org.bson.*",
+                "Build-Version" to gitVersion,
+                "Bundle-Version" to gitVersion,
+                "Bundle-Name" to "MongoCrypt",
+                "Bundle-SymbolicName" to "com.mongodb.crypt.capi",
+                "Private-Package" to ""
+        )
+    }
+
+    //NOTE this enables depending on the mongocrypt from driver-core
+   dependsOn("downloadJnaLibs")
+}
+
+tasks.javadoc {
+    if (JavaVersion.current().isJava9Compatible) {
+        (options as StandardJavadocDocletOptions).addBooleanOption("html5", true)
+    }
+}

mongocrypt/src/main/com/mongodb/crypt/capi/BinaryHolder.java

@@ -0,0 +1,45 @@
+/*
+ * Copyright 2008-present MongoDB, Inc.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ */
+
+package com.mongodb.crypt.capi;
+
+import com.mongodb.crypt.capi.CAPI.mongocrypt_binary_t;
+
+import static com.mongodb.crypt.capi.CAPI.mongocrypt_binary_destroy;
+
+// Wrap JNA memory and a mongocrypt_binary_t that references that memory, in order to ensure that the JNA Memory is not GC'd before the
+// mongocrypt_binary_t is destroyed
+class BinaryHolder implements AutoCloseable {
+
+    private final DisposableMemory memory;
+    private final mongocrypt_binary_t binary;
+
+    BinaryHolder(final DisposableMemory memory, final mongocrypt_binary_t binary) {
+        this.memory = memory;
+        this.binary = binary;
+    }
+
+    mongocrypt_binary_t getBinary() {
+        return binary;
+    }
+
+    @Override
+    public void close() {
+        mongocrypt_binary_destroy(binary);
+        memory.dispose();
+    }
+}