Feature/resolve all conflicts

resources.qrc

@@ -56,5 +56,8 @@
         <file>src/gui/tray/ListItemLineAndSubline.qml</file>
         <file>src/gui/tray/TrayFoldersMenuButton.qml</file>
         <file>src/gui/tray/TrayFolderListItem.qml</file>
+        <file>src/gui/ResolveConflictsDialog.qml</file>
+        <file>src/gui/ConflictDelegate.qml</file>
+        <file>src/gui/ConflictItemFileInfo.qml</file>
     </qresource>
 </RCC>

src/gui/CMakeLists.txt

@@ -186,6 +186,8 @@ set(client_SRCS
     userstatusselectormodel.cpp
     emojimodel.h
     emojimodel.cpp
+    syncconflictsmodel.h
+    syncconflictsmodel.cpp
     fileactivitylistmodel.h
     fileactivitylistmodel.cpp
     filedetails/filedetails.h

src/gui/ConflictDelegate.qml

@@ -0,0 +1,86 @@
+/*
+ * Copyright (C) 2023 by Matthieu Gallien <matthieu.gallien@nextcloud.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful, but
+ * WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+ * or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
+ * for more details.
+ */
+
+import QtQml 2.15
+import QtQuick 2.15
+import QtQuick.Layouts 1.15
+import QtQuick.Controls 2.15
+import Style 1.0
+import com.nextcloud.desktopclient 1.0
+import "./tray"
+
+Item {
+    id: root
+
+    required property string existingFileName
+    required property string existingSize
+    required property string conflictSize
+    required property string existingDate
+    required property string conflictDate
+    required property bool existingSelected
+    required property bool conflictSelected
+    required property url existingPreviewUrl
+    required property url conflictPreviewUrl
+    required property var model
+
+    EnforcedPlainTextLabel {
+        id: existingFileNameLabel
+
+        anchors.top: parent.top
+        anchors.left: parent.left
+
+        text: root.existingFileName
+
+        font.weight: Font.Bold
+        font.pixelSize: Style.fontPixelSizeResolveConflictsDialog
+    }
+
+    RowLayout {
+        anchors.top: existingFileNameLabel.bottom
+        anchors.bottom: parent.bottom
+        anchors.left: parent.left
+        anchors.right: parent.right
+        anchors.bottomMargin: 8
+
+        ConflictItemFileInfo {
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+
+            itemSelected: root.existingSelected
+            itemPreviewUrl: root.existingPreviewUrl
+            itemVersionLabel: qsTr('Local version')
+            itemDateLabel: root.existingDate
+            itemFileSizeLabel: root.existingSize
+
+            onSelectedChanged: function() {
+                model.existingSelected = itemSelected
+            }
+        }
+
+        ConflictItemFileInfo {
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+
+            itemSelected: root.conflictSelected
+            itemPreviewUrl: root.conflictPreviewUrl
+            itemVersionLabel: qsTr('Server version')
+            itemDateLabel: root.conflictDate
+            itemFileSizeLabel: root.conflictSize
+
+            onSelectedChanged: function() {
+                model.conflictSelected = itemSelected
+            }
+        }
+    }
+}

src/gui/ConflictItemFileInfo.qml

@@ -0,0 +1,98 @@
+/*
+ * Copyright (C) 2023 by Matthieu Gallien <matthieu.gallien@nextcloud.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful, but
+ * WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+ * or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
+ * for more details.
+ */
+
+import QtQml 2.15
+import QtQuick 2.15
+import QtQuick.Layouts 1.15
+import QtQuick.Controls 2.15
+import Style 1.0
+import "./tray"
+
+Item {
+    property alias itemSelected: selectItem.checked
+    property alias itemPreviewUrl: itemPreview.source
+    property alias itemVersionLabel: versionLabel.text
+    property alias itemDateLabel: dateLabel.text
+    property alias itemFileSizeLabel: fileSizeLabel.text
+
+    signal selectedChanged()
+
+    CheckBox {
+        id: selectItem
+
+        anchors.left: parent.left
+        anchors.verticalCenter: parent.verticalCenter
+
+        leftPadding: 0
+        spacing: 0
+
+        onToggled: function() {
+            selectedChanged()
+        }
+    }
+
+    Image {
+        id: itemPreview
+
+        anchors.left: selectItem.right
+        anchors.verticalCenter: parent.verticalCenter
+
+        width: 48
+        height: 48
+        sourceSize.width: 48
+        sourceSize.height: 48
+    }
+
+    ColumnLayout {
+        anchors.top: parent.top
+        anchors.bottom: parent.bottom
+        anchors.left: itemPreview.right
+        anchors.right: parent.right
+        anchors.leftMargin: 10
+
+        spacing: 0
+
+        Item {
+            Layout.fillHeight: true
+        }
+
+        EnforcedPlainTextLabel {
+            id: versionLabel
+
+            Layout.fillWidth: true
+
+            font.pixelSize: Style.fontPixelSizeResolveConflictsDialog
+        }
+
+        EnforcedPlainTextLabel {
+            id: dateLabel
+
+            Layout.fillWidth: true
+
+            font.pixelSize: Style.fontPixelSizeResolveConflictsDialog
+        }
+
+        EnforcedPlainTextLabel {
+            id: fileSizeLabel
+
+            Layout.fillWidth: true
+
+            font.pixelSize: Style.fontPixelSizeResolveConflictsDialog
+        }
+
+        Item {
+            Layout.fillHeight: true
+        }
+    }
+}

src/gui/ResolveConflictsDialog.qml

@@ -0,0 +1,174 @@
+/*
+ * Copyright (C) 2023 by Matthieu Gallien <matthieu.gallien@nextcloud.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful, but
+ * WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+ * or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
+ * for more details.
+ */
+
+import QtQml 2.15
+import QtQuick 2.15
+import QtQuick.Window 2.15 as QtWindow
+import QtQuick.Layouts 1.15
+import QtQuick.Controls 2.15
+import QtQml.Models 2.15
+import Style 1.0
+import com.nextcloud.desktopclient 1.0
+import "./tray"
+
+QtWindow.Window {
+    id: conflictsDialog
+
+    required property var allConflicts
+
+    flags: Qt.Window | Qt.Dialog
+    visible: true
+
+    width: Style.minimumWidthResolveConflictsDialog
+    height: Style.minimumHeightResolveConflictsDialog
+    minimumWidth: Style.minimumWidthResolveConflictsDialog
+    minimumHeight: Style.minimumHeightResolveConflictsDialog
+    title: qsTr('Solve sync conflicts')
+
+    onClosing: function(close) {
+        Systray.destroyDialog(self);
+        close.accepted = true
+    }
+
+    ColumnLayout {
+        anchors.fill: parent
+        anchors.leftMargin: 20
+        anchors.rightMargin: 20
+        anchors.bottomMargin: 20
+        anchors.topMargin: 20
+        spacing: 15
+        z: 2
+
+        EnforcedPlainTextLabel {
+            text: qsTr("%1 files in conflict", 'indicate the number of conflicts to resolve', delegateModel.count).arg(delegateModel.count)
+            font.bold: true
+            font.pixelSize: Style.bigFontPixelSizeResolveConflictsDialog
+            Layout.fillWidth: true
+        }
+
+        EnforcedPlainTextLabel {
+            text: qsTr("Choose if you want to keep the local version, server version, or both. If you choose both, the local file will have a number added to its name.")
+            wrapMode: Text.WrapAtWordBoundaryOrAnywhere
+            font.pixelSize: Style.fontPixelSizeResolveConflictsDialog
+            Layout.fillWidth: true
+            Layout.topMargin: -15
+        }
+
+        RowLayout {
+            Layout.fillWidth: true
+            Layout.topMargin: 15
+
+            CheckBox {
+                id: selectExisting
+
+                Layout.fillWidth: true
+
+                text: qsTr('All local versions')
+
+                leftPadding: 0
+                implicitWidth: 100
+
+                font.pixelSize: Style.fontPixelSizeResolveConflictsDialog
+
+                checked: realModel.allExistingsSelected
+                onToggled: function() {
+                    realModel.selectAllExisting(checked)
+                }
+            }
+
+            CheckBox {
+                id: selectConflict
+
+                Layout.fillWidth: true
+
+                text: qsTr('All server versions')
+
+                leftPadding: 0
+                implicitWidth: 100
+
+                font.pixelSize: Style.fontPixelSizeResolveConflictsDialog
+
+                checked: realModel.allConflictingSelected
+                onToggled: function() {
+                    realModel.selectAllConflicting(checked)
+                }
+            }
+        }
+
+        Rectangle {
+            Layout.fillWidth: true
+            Layout.leftMargin: 5
+            Layout.rightMargin: 5
+            color: Style.menuBorder
+            height: 1
+        }
+
+        SyncConflictsModel {
+            id: realModel
+
+            conflictActivities: conflictsDialog.allConflicts
+        }
+
+        ScrollView {
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            clip: true
+
+            ScrollBar.horizontal.policy: ScrollBar.AlwaysOff
+
+            ListView {
+                id: conflictListView
+
+                model: DelegateModel {
+                    id: delegateModel
+
+                    model: realModel
+
+                    delegate: ConflictDelegate {
+                        width: conflictListView.contentItem.width
+                        height: 100
+                    }
+                }
+            }
+        }
+
+        DialogButtonBox {
+            Layout.fillWidth: true
+
+            Button {
+                text: qsTr("Resolve conflicts")
+                DialogButtonBox.buttonRole: DialogButtonBox.AcceptRole
+            }
+            Button {
+                text: qsTr("Cancel")
+                DialogButtonBox.buttonRole: DialogButtonBox.RejectRole
+            }
+
+            onAccepted: function() {
+                realModel.applySolution()
+                Systray.destroyDialog(conflictsDialog)
+            }
+
+            onRejected: function() {
+                Systray.destroyDialog(conflictsDialog)
+            }
+        }
+    }
+
+    Rectangle {
+        color: Theme.systemPalette.window
+        anchors.fill: parent
+        z: 1
+    }
+}

src/gui/conflictsolver.h

@@ -32,6 +32,7 @@ class ConflictSolver : public QObject
         KeepRemoteVersion,
         KeepBothVersions
     };
+    Q_ENUM(Solution);
 
     explicit ConflictSolver(QWidget *parent = nullptr);