senpai: use SCFG format

modules/lib/generators.nix

@@ -99,4 +99,31 @@
     in attrs: ''
       ${concatStringsSep "\n" (mapAttrsToList convertAttributeToKDL attrs)}
     '';
+
+  toSCFG = let
+    inherit (lib)
+      concatStringsSep filterAttrs isAttrs isBool isFloat isInt isList isString
+      mapAttrsToList;
+    inherit (builtins) typeOf toJSON;
+
+    toSCFG' = v:
+      if isAttrs v then ''
+        {
+          ${toSCFG v}
+        }
+      '' else if isList v then
+        concatStringsSep " " v
+      else if isString v then
+        v
+      else if isInt v || isFloat v || isBool v then
+        toJSON v
+      else
+        abort "toSCFG: type ${typeOf v} is unsupported";
+
+    filterSCFG = filterAttrs (_: val: !isNull val && val != { });
+
+    sectionSCFG = mapAttrsToList (key: val: "${key} ${toSCFG' val}");
+
+    toSCFG = v: concatStringsSep "\n" (sectionSCFG (filterSCFG v));
+  in toSCFG;
 }

modules/programs/senpai.nix

@@ -4,7 +4,18 @@ with lib;
 
 let
   cfg = config.programs.senpai;
-  cfgFmt = pkgs.formats.yaml { };
+  imports = [
+    (mkRenamedOptionModule [ "programs" "senpai" "addr" ] [
+      "programs"
+      "senpai"
+      "address"
+    ])
+    (mkRenamedOptionModule [ "programs" "senpai" "nick" ] [
+      "programs"
+      "senpai"
+      "nickname"
+    ])
+  ];
 in {
   options.programs.senpai = {
     enable = mkEnableOption "senpai";
@@ -16,17 +27,22 @@ in {
     };
     config = mkOption {
       type = types.submodule {
-        freeformType = cfgFmt.type;
         options = {
-          addr = mkOption {
+          address = mkOption {
             type = types.str;
             description = ''
-              The address (host[:port]) of the IRC server. senpai uses TLS
-              connections by default unless you specify no-tls option. TLS
-              connections default to port 6697, plain-text use port 6667.
+              The address (<literal>host[:port]</literal>) of the IRC server. senpai uses TLS
+              connections by default unless you specify tls option to be false.
+              TLS connections default to port 6697, plain-text use port 6667.
+
+              <literal>ircs://</literal>, <literal>irc://</literal>, and
+              <literal>irc+insecure://</literal> URLs are supported, in which
+              case only the hostname and port parts will be used. If the scheme
+              is ircs/irc+insecure, tls will be overriden and set to true/false
+              accordingly.
             '';
           };
-          nick = mkOption {
+          nickname = mkOption {
             type = types.str;
             description = ''
               Your nickname, sent with a NICK IRC message. It mustn't contain
@@ -41,17 +57,37 @@ in {
               reside world-readable in the Nix store.
             '';
           };
+          # TODO: remove me for the next release
           no-tls = mkOption {
-            type = types.bool;
-            default = false;
-            description = "Disables TLS encryption.";
+            type = types.nullOr types.bool;
+            default = null;
+            description = ''
+              Specifying 'senpai.no-tls' is deprecated, Set
+              <literal>senpai.extraConfig = { tls = false; }</literal>
+              instead.
+            '';
+          };
+          password-cmd = mkOption {
+            type = types.nullOr (types.listOf types.str);
+            default = null;
+            description = ''
+              Alternatively to providing your SASL authentication password
+              directly in plaintext, you can specify a command to be run to
+              fetch the password at runtime. This is useful if you store your
+              passwords in a separate (probably encrypted) file using `gpg` or
+              a command line password manager such as <literal>pass</literal>
+              or <literal>gopass</literal>. If a password-cmd is provided, the
+              value of password will be ignored and the first line of the output
+              of <literal>password-cmd</literal> will be used
+              for login.
+            '';
           };
         };
       };
       example = literalExpression ''
         {
-          addr = "libera.chat:6697";
-          nick = "nicholas";
+          address = "libera.chat:6697";
+          nickname = "nicholas";
           password = "verysecurepassword";
         }
       '';
@@ -61,13 +97,34 @@ in {
         <manvolnum>5</manvolnum></citerefentry>.
       '';
     };
+    extraConfig = mkOption {
+      type = types.attrs;
+      default = { };
+      description = ''
+        Options that should be appended to the senpai configuration file.
+      '';
+    };
   };
 
   config = mkIf cfg.enable {
+    assertions = with cfg.config; [
+      {
+        assertion = !isNull password-cmd -> isNull password;
+        message = "senpai: password-command overrides password!";
+      }
+      {
+        # TODO: remove me for the next release
+        assertion = isNull no-tls;
+        message = ''
+          Specifying 'senpai.no-tls' is deprecated,
+          set 'senpai.extraConfig = { tls = false; }' instead.
+        '';
+      }
+    ];
     home.packages = [ cfg.package ];
-    xdg.configFile."senpai/senpai.yaml".source =
-      cfgFmt.generate "senpai.yaml" cfg.config;
+    xdg.configFile."senpai/senpai.scfg".text =
+      lib.hm.generators.toSCFG (cfg.config // cfg.extraConfig);
   };
 
-  meta.maintainers = [ hm.maintainers.malvo ];
+  meta.maintainers = [ maintainers.jleightcap ];
 }

tests/default.nix

@@ -120,6 +120,7 @@ import nmt {
     ./modules/programs/sagemath
     ./modules/programs/sbt
     ./modules/programs/scmpuff
+    ./modules/programs/senpai
     ./modules/programs/sioyek
     ./modules/programs/sm64ex
     ./modules/programs/ssh

tests/modules/programs/senpai/default.nix

@@ -0,0 +1,4 @@
+{
+  senpai-example-settings = ./example-settings.nix;
+  senpai-empty-settings = ./empty-settings.nix;
+}

tests/modules/programs/senpai/empty-settings-expected.conf

@@ -0,0 +1,2 @@
+address irc.libera.chat
+nickname Guest123456

tests/modules/programs/senpai/empty-settings.nix

@@ -0,0 +1,20 @@
+{ config, ... }:
+
+{
+  config = {
+    programs.senpai = {
+      enable = true;
+      package = config.lib.test.mkStubPackage { };
+      config = {
+        address = "irc.libera.chat";
+        nickname = "Guest123456";
+      };
+    };
+
+    nmt.script = ''
+      assertFileContent \
+        home-files/.config/senpai/senpai.scfg \
+        ${./empty-settings-expected.conf}
+    '';
+  };
+}

tests/modules/programs/senpai/example-settings-expected.conf

@@ -0,0 +1,15 @@
+address irc.libera.chat
+channel #rahxephon
+colors {
+  prompt 2
+}
+
+highlight guest senpai lenon
+nickname Guest123456
+pane-widths {
+  nicknames 16
+}
+
+password-cmd gopass show irc/guest
+realname Guest von Lenon
+username senpai

tests/modules/programs/senpai/example-settings.nix

@@ -0,0 +1,29 @@
+{ config, ... }:
+
+{
+  config = {
+    programs.senpai = {
+      enable = true;
+      package = config.lib.test.mkStubPackage { };
+      config = {
+        address = "irc.libera.chat";
+        nickname = "Guest123456";
+        password-cmd = [ "gopass" "show" "irc/guest" ];
+      };
+      extraConfig = {
+        username = "senpai";
+        realname = "Guest von Lenon";
+        channel = [ "#rahxephon" ];
+        highlight = [ "guest" "senpai" "lenon" ];
+        pane-widths = { nicknames = 16; };
+        colors = { prompt = 2; };
+      };
+    };
+
+    nmt.script = ''
+      assertFileContent \
+        home-files/.config/senpai/senpai.scfg \
+        ${./example-settings-expected.conf}
+    '';
+  };
+}