Document typical "for all" patterns

[ghost]

I cannot find in the docs how to validate every element of the array

So, now I'm using this trick as a temporary solution

everyShouldSatisfyRequirement {
  input.elements
  exceptions := [element | input.elements[i] = element; element != "foo"]
  count(exceptions) = 0
}

[ashutosh-narkar]

@almostprogrammer See this example https://play.openpolicyagent.org/p/J0i0L5snjQ

[tsandall]

@almostprogrammer your solution is correct though you can omit the first expression (input.elements) because if input.elements were undefined or empty then exceptions will be []. Note, if you want to ensure that every element satisfies some requirements AND the elements array is non-empty, you could adjust the first expression to be input.request != [].

The only other thing I'd change is to rename i to _ and use := instead of =. For example:

all_elements_satisfy_requirements {
   exceptions := [e | e := input.elements[_]; e != "foo"]
   count(exceptions) == 0
}

The alternative that @ashutosh-narkar pointed out is to use negation (not) instead of comprehensions.

all_elements_satisfy_requirements {
   not some_elements_violate_requirements
}

some_elements_violate_requirements {
   e := input.elements[_]
   e != "foo"
}

Comprehensions and negation are the two typical ways of implementing "for all" inside Rego. There is a third way which involves using the all built-in function which I'm personally not a fan of (because it requires combination of comprehensions, helper functions, and built-in calls).

all_elements_satisfy_requirements {
  satisfied := [yes | e := input.elements[_]; yes := satisfies_requirements(e)]
  all(satisfied)
}

satisfies_requirements(e) {
  e != "foo" 
} else = false {   # NOTE: bare `else` and `default` on rules with args not suppored today, hence `{ true }` is needed
   true
}

Note, this is a very common question and I don't think we have good coverage of it in the FAQ or cheat sheet. I'm going to edit the title an label the issue so that we can come back and fix the docs.