forked from affeldt-aist/monae
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathmonad.v
1706 lines (1441 loc) · 55 KB
/
monad.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
Ltac typeof X := type of X.
Require Import ssreflect ssrmatching ssrfun ssrbool.
From mathcomp Require Import eqtype ssrnat seq path div choice fintype tuple.
From mathcomp Require Import finfun bigop.
From mathcomp Require Import boolp.
Set Implicit Arguments.
Unset Strict Implicit.
Unset Printing Implicit Defensive.
(* Contents:
- generic Haskell-like functions and notations
- Module FunctorLaws/Module Functor
- Section natural_transformation.
- Section adjoint_functors.
- Module BindLaws.
definition of algebraic laws to be used with monads
- Section monad_of_adjoint.
- Module JoinLaws.
- Module Monad.
with ret and join
- Module Monad_of_bind_ret.
with bind and ret
- Section fmap_and_join.
- Section rep.
simple effect of counting
- Module MonadFail.
definition of guard
- Module MonadAlt.
non-deterministic choice
Section subsequences_of_a_list.
Section permutation_and_insertion.
examples of non-deterministic programs
- Module MonadAltCI.
- Module MonadNondet
Section permutations.
- Module MonadExcept.
example of the fast product
*)
Reserved Notation "A `2" (format "A `2", at level 3).
Reserved Notation "f ^`2" (format "f ^`2", at level 3).
Reserved Notation "l \\ p" (at level 50).
Reserved Notation "m >>= f" (at level 50).
Reserved Notation "f =<< m" (at level 50).
Reserved Notation "'do' x <- m ; e"
(at level 60, x ident, m at level 200, e at level 60).
Reserved Notation "'do' x : T <- m ; e"
(at level 60, x ident, m at level 200, e at level 60).
Reserved Notation "m >=> n" (at level 50).
Reserved Notation "n <=< m" (at level 50).
Reserved Notation "x '[~]' y" (at level 50).
Reserved Notation "'[~p]'".
Reserved Notation "f (o) g" (at level 11).
Notation "l \\ p" := ([seq x <- l | x \notin p]).
(* some Haskell-like functions *)
Definition foldr1 (A : Type) (def : A) (f : A -> A -> A) (s : seq A) :=
match s with
| [::] => def
| [:: h] => h
| h :: h' :: t => foldr f h [:: h' & t]
end.
Definition cp {A B} (x : seq A) (y : seq B) := [seq (x', y') | x' <- x, y' <- y].
Lemma cp1 A B (a : A) (s : seq B) : cp [:: a] s = map (fun b => (a, b)) s.
Proof. by elim: s => // h t /= <-. Qed.
Definition zipWith {A B C} (op : A -> B -> C) a b : seq C :=
map (fun x => op x.1 x.2) (zip a b).
Section fold.
Variables (T R : Type) (f : T -> R -> R) (r : R).
Section universal.
Variable (g : seq T -> R).
Hypothesis H1 : g nil = r.
Hypothesis H2 : forall h t, g (h :: t) = f h (g t).
Lemma foldr_universal : g = foldr f r.
Proof. rewrite funeqE; elim => // h t ih /=; by rewrite H2 ih. Qed.
Lemma foldr_universal_ext x : g x = foldr f r x.
Proof. by rewrite -(foldr_universal). Qed.
End universal.
Section fusion_law.
Variables (U : Type) (h : U -> R) (w : U) (g : T -> U -> U).
Hypothesis H1 : h w = r.
Hypothesis H2 : forall x y, h (g x y) = f x (h y).
Lemma foldr_fusion : h \o foldr g w = foldr f r.
Proof. rewrite funeqE; elim => // a b /= ih; by rewrite H2 ih. Qed.
Lemma foldr_fusion_ext x : (h \o foldr g w) x = foldr f r x.
Proof. by rewrite -foldr_fusion. Qed.
End fusion_law.
End fold.
Section curry.
Variables A B C : Type.
Implicit Types f : A -> B -> C.
Definition uncurry f := prod_curry f.
Lemma uncurryE f a b : (uncurry f) (a, b) = f a b. Proof. by []. Qed.
Definition curry (g : A * B -> C) : A -> B -> C := fun a b => g (a, b).
Lemma curryK : cancel curry uncurry.
Proof. by move=> f; rewrite funeqE; case. Qed.
Lemma uncurryK f : cancel uncurry curry.
Proof. by []. Qed.
End curry.
Definition ucat {A} := uncurry (@cat A).
Definition uaddn := uncurry addn.
Lemma uaddnE n m : uaddn (n, m) = n + m. Proof. by rewrite /uaddn uncurryE. Qed.
Definition const A B (b : B) := fun _ : A => b.
Definition wrap {A} (a : A) := [:: a].
Fixpoint scanl A B (op : B -> A -> B) (b : B) (s : seq A) : seq B :=
if s isn't x :: xs then [::] else (op b x) :: scanl op (op b x) xs.
Lemma compA {A B C D} (f : C -> D) (g : B -> C) (h : A -> B) : f \o (g \o h) = (f \o g) \o h.
Proof. by []. Qed.
Lemma compfid A B (f : A -> B) : f \o id = f. Proof. by []. Qed.
Lemma compidf A B (f : A -> B) : id \o f = f. Proof. by []. Qed.
Lemma compE A B C (g : B -> C) (f : A -> B) a : (g \o f) a = g (f a).
Proof. by []. Qed.
(* map laws of a functor *)
Module FunctorLaws.
Section def.
Variable (M : Type -> Type) (f : forall A B, (A -> B) -> M A -> M B).
Definition id := forall A, f id = id :> (M A -> M A).
Definition comp := forall A B C (g : B -> C) (h : A -> B),
f (g \o h) = f g \o f h :> (M A -> M C).
End def.
End FunctorLaws.
Module Functor.
Record class_of (m : Type -> Type) : Type := Class {
f : forall A B, (A -> B) -> m A -> m B ;
_ : FunctorLaws.id f ;
_ : FunctorLaws.comp f
}.
Structure t : Type := Pack { m : Type -> Type ; class : class_of m }.
Module Exports.
Definition Fun (F : t) : forall A B, (A -> B) -> m F A -> m F B :=
let: Pack _ (Class f _ _) := F return forall A B, (A -> B) -> m F A -> m F B in f.
Arguments Fun _ [A] [B] : simpl never.
Notation functor := t.
Coercion m : functor >-> Funclass.
End Exports.
End Functor.
Export Functor.Exports.
Notation "F # g" := (Fun F g) (at level 11).
Section functor_lemmas.
Variable F : functor.
Lemma functor_id : FunctorLaws.id (Fun F).
Proof. by case: F => [? []]. Qed.
Lemma functor_o : FunctorLaws.comp (Fun F).
Proof. by case: F => [? []]. Qed.
End functor_lemmas.
Definition Squaring (A : Type) := (A * A)%type.
Notation "A `2" := (Squaring A).
Definition squaring_f A B (f : A -> B) : A`2 -> B`2 := fun x => (f x.1, f x.2).
Lemma squaring_f_id : FunctorLaws.id squaring_f.
Proof. by move=> A /=; rewrite funeqE => -[x1 x2]. Qed.
Lemma squaring_f_comp : FunctorLaws.comp squaring_f.
Proof. by move=> A B C g h /=; rewrite funeqE => -[x1 x2]. Qed.
Definition squaring : functor (*Squaring*) :=
Functor.Pack (Functor.Class squaring_f_id squaring_f_comp).
Notation "f ^`2" := (squaring # f).
Lemma squaringE A B (f : A -> B) x : (f ^`2) x = (f x.1, f x.2).
Proof. by []. Qed.
Section functorid.
Definition id_f A B (f : A -> B) := f.
Lemma id_id : FunctorLaws.id id_f. Proof. by []. Qed.
Lemma id_comp : FunctorLaws.comp id_f. Proof. by []. Qed.
Definition FId : functor := Functor.Pack (Functor.Class id_id id_comp).
End functorid.
Section functorcomposition.
Variables f g : functor.
Definition functorcomposition A B := fun h : A -> B => f # (g # h).
Lemma functorcomposition_id : FunctorLaws.id functorcomposition.
Proof.
by rewrite /FunctorLaws.id => A; rewrite /functorcomposition 2!functor_id.
Qed.
Lemma functorcomposition_comp : FunctorLaws.comp functorcomposition.
Proof.
rewrite /FunctorLaws.comp => A B C g' h; rewrite /functorcomposition.
rewrite funeqE => m; by rewrite [in RHS]compE 2!functor_o.
Qed.
Definition FComp : functor :=
Functor.Pack (Functor.Class functorcomposition_id functorcomposition_comp).
End functorcomposition.
Section functorcomposition_lemmas.
Lemma FCompId (f : functor) : FComp f FId = f.
Proof.
destruct f as [m [f0 f1 f2]]; congr Functor.Pack; congr Functor.Class => //;
exact/Prop_irrelevance.
Qed.
Lemma FIdComp (f : functor) : FComp FId f = f.
Proof.
destruct f as [m [f0 f1 f2]]; congr Functor.Pack; congr Functor.Class => //;
exact/Prop_irrelevance.
Qed.
Lemma FIdf A B (f : A -> B) : FId # f = f.
Proof. by []. Qed.
Lemma FCompA (f g h : functor) : FComp (FComp f g) h = FComp f (FComp g h).
Proof.
destruct f as [m [f0 f1 f2]].
destruct g as [n [g0 g1 g2]].
destruct h as [o [h0 h1 h2]].
congr Functor.Pack; congr Functor.Class => //; exact/Prop_irrelevance.
Qed.
Lemma FCompE (f g : functor) A B (k : A -> B) : (FComp f g) # k = f # (g # k).
Proof. by []. Qed.
End functorcomposition_lemmas.
Section curry_functor.
Definition curry_M X : Type -> Type := fun B => (X * B)%type.
Definition curry_f X A B (f : A -> B) : curry_M X A -> curry_M X B :=
fun x : X * A => (x.1, f x.2).
Lemma curry_f_id X : FunctorLaws.id (@curry_f X).
Proof.
by rewrite /FunctorLaws.id => A; rewrite /curry_f; rewrite funeqE; case.
Qed.
Lemma curry_f_comp X : FunctorLaws.comp (@curry_f X).
Proof.
by rewrite /FunctorLaws.comp => A B C g h; rewrite /curry_f funeqE; case.
Qed.
Definition curry_F X : functor :=
Functor.Pack (Functor.Class (curry_f_id X) (curry_f_comp X)).
End curry_functor.
Section uncurry_functor.
Definition uncurry_M X : Type -> Type := fun B => X -> B.
Definition uncurry_f X A B (f : A -> B) : uncurry_M X A -> uncurry_M X B :=
fun g : X -> A => f \o g.
Lemma uncurry_f_id X : FunctorLaws.id (@uncurry_f X).
Proof.
rewrite /FunctorLaws.id => A; rewrite /uncurry_f funeqE => ?.
by rewrite compidf.
Qed.
Lemma uncurry_f_comp X : FunctorLaws.comp (@uncurry_f X).
Proof.
rewrite /FunctorLaws.comp => A B C g h; rewrite /uncurry_f funeqE => ?.
by rewrite compE compA.
Qed.
Definition uncurry_F X : functor :=
Functor.Pack (Functor.Class (uncurry_f_id X) (uncurry_f_comp X)).
End uncurry_functor.
Section natural_transformation.
Variables f g : functor.
Definition transformation_type := forall A, f A -> g A.
Definition naturalP (phi : transformation_type) :=
forall A B (h : A -> B), (g # h) \o (phi A) = (phi B) \o (f # h).
End natural_transformation.
Arguments naturalP : clear implicits.
Section natural_transformation_example.
Definition fork A (a : A) := (a, a).
(* fork is a natural transformation FId -> squaring *)
Lemma fork_natural : naturalP FId squaring fork.
Proof. by []. Qed.
End natural_transformation_example.
Section adjoint_functors.
Variables f g : functor.
Definition eta_type := forall A, A -> (g \o f) A.
Definition eps_type := forall A, (f \o g) A -> A.
Definition adjointP (eps : eps_type) (eta : eta_type) :=
naturalP (FComp f g) FId eps /\ naturalP FId (FComp g f) eta.
Definition triangular_law1 (eps : eps_type) (eta : eta_type) A :=
(eps (f A)) \o (f # eta A) = @id (f A).
Definition triangular_law2 (eps : eps_type) (eta : eta_type) A :=
(g # eps A) \o (eta (g A)) = @id (g A).
Definition phi A B (eta : eta_type) : (f A -> B) -> A -> g B :=
fun h => (g # h) \o (@eta A).
Definition psi A B (eps : eps_type) : (A -> g B) -> f A -> B :=
fun h => (@eps B) \o (f # h).
End adjoint_functors.
Section adjoint_example.
Variable (X : Type).
Definition curry_eps : eps_type (curry_F X) (uncurry_F X) :=
fun A (af : X * (X -> A)) => af.2 af.1.
Definition curry_eta : eta_type (curry_F X) (uncurry_F X) :=
fun A (a : A) => fun x : X => (x, a).
Lemma adjoint_currry : adjointP curry_eps curry_eta.
Proof.
split; rewrite /naturalP => A B h /=.
- by rewrite /id_f /curry_eps /curry_f /= /uncurry_M /uncurry_f /= funeqE; case.
- rewrite /uncurry_f /curry_f /curry_eta /id_f /= funeqE => a /=.
by rewrite funeqE.
Qed.
Lemma curry_triangular_law1 A : triangular_law1 curry_eps curry_eta A.
Proof. by rewrite /triangular_law1 funeqE; case. Qed.
Lemma curry_triangular_law2 A : triangular_law2 curry_eps curry_eta A.
Proof.
rewrite /triangular_law2 /uncurry_F /curry_eps /curry_eta /uncurry_M /=.
by rewrite /uncurry_f /= /comp /= funeqE => f; rewrite funeqE.
Qed.
End adjoint_example.
Module BindLaws.
Section bindlaws.
Variable M : Type -> Type.
Variable b : forall A B, M A -> (A -> M B) -> M B.
Local Notation "m >>= f" := (b m f).
Definition associative := forall A B C (m : M A) (f : A -> M B) (g : B -> M C),
(m >>= f) >>= g = m >>= (fun x => (f x >>= g)).
Definition right_distributive (add : forall B, M B -> M B -> M B) :=
forall A B (m : M A) (k1 k2 : A -> M B),
m >>= (fun x => add _ (k1 x) (k2 x)) = add _ (m >>= k1) (m >>= k2).
Definition left_distributive (add : forall B, M B -> M B -> M B) :=
forall A B (m1 m2 : M A) (k : A -> M B),
(add _ m1 m2) >>= k = add _ (m1 >>= k) (m2 >>= k).
Definition left_zero (f : forall A, M A) :=
forall A B (g : A -> M B), f A >>= g = f B.
Definition right_zero (f : forall A, M A) :=
forall A B (g : M B), g >>= (fun _ => f A) = f A.
Definition left_neutral (r : forall A, A -> M A) :=
forall A B (a : A) (f : A -> M B), r _ a >>= f = f a.
Definition right_neutral (r : forall A, A -> M A) :=
forall A (m : M A), m >>= r _ = m.
Definition left_id (r : forall A, M A) (op : forall B, M B -> M B -> M B) :=
forall A (m : M A), op _ (r _) m = m.
Definition right_id (r : forall A, M A) (op : forall B, M B -> M B -> M B) :=
forall A (m : M A), op _ m (r _) = m.
End bindlaws.
End BindLaws.
Section monad_of_adjoint.
Section def.
Variables f g : functor.
Variables (eps : eps_type f g) (eta : eta_type f g).
Definition M := g \o f.
Definition m : functor := FComp g f.
Definition muM A : M (M A) -> M A := g # (@eps (f A)).
Definition etaM A : A -> M A := @eta A.
Definition bind A B : M A -> (A -> M B) -> M B :=
fun x c => muM (((FComp g f) # c) x).
End def.
Section prop.
Variables f g : functor.
Variables (eps : eps_type f g) (eta : eta_type f g).
Hypothesis Had : adjointP eps eta.
Hypothesis Ht1 : forall A, triangular_law1 eps eta A.
Hypothesis Ht2 : forall A, triangular_law2 eps eta A.
Section muM_natural.
Let M := M f g.
Let m := m f g.
Let muM := muM eps.
Let mE : m = FComp g f.
Proof. by []. Qed.
Let muME : muM = fun A => g # (@eps (f A)).
Proof. by []. Qed.
Lemma muM_natural : naturalP (FComp m m) m muM.
Proof.
move: Had => [] Heps _; move: Heps; rewrite/naturalP => Heps.
rewrite !muME => A B h.
rewrite(_:FComp (FComp g f) (FComp g f) # h = g # ((FComp f g) # (f # h))) //.
rewrite(_:g # eps (A:=f B) \o g # (FComp f g # (f # h))
= g # (eps (A:=f B) \o (FComp f g # (f # h)))); last by rewrite -functor_o.
rewrite -Heps.
rewrite !FCompE /FId /id_f /=.
by rewrite functor_o.
Qed.
Lemma epsC A : @eps _ \o @eps _ =
@eps _ \o f # (g # @eps _) :> ((f \o g) ((f \o g) A) -> A).
Proof.
move:Had=>[];rewrite/naturalP=>Heps _.
by move:(Heps _ _ (eps (A:=A))) => <-.
Qed.
Lemma muMA A : muM (A:=A) \o muM (A:=M A) = muM (A:=A) \o (m # muM (A:=A)).
Proof.
rewrite muME.
have->: g # eps (A:=f A) \o g # eps (A:=f (M A)) =
g # (eps (A:=f A) \o eps (A:=f (M A))) by rewrite functor_o.
by rewrite epsC functor_o.
Qed.
End muM_natural.
Lemma bindetaf : BindLaws.left_neutral (bind eps) (etaM eta).
Proof.
rewrite /BindLaws.left_neutral => A B a h.
case: Had; rewrite /naturalP => _ /(_ _ _ h) Had2.
rewrite /bind /muM /etaM.
rewrite -(compE (FComp g f # h)).
rewrite Had2.
move: Ht2; rewrite /triangular_law2 => Ht2'.
rewrite -(compE (g # _)) compA.
by rewrite Ht2'.
Qed.
Lemma bindmeta : BindLaws.right_neutral (bind eps) (etaM eta).
Proof.
rewrite /BindLaws.right_neutral => A m.
rewrite /bind /muM /etaM.
rewrite -(compE (g # _)).
rewrite -(functor_o g).
(* NB: "rewrite -functor_o" does not work. Notation issue? *)
by rewrite Ht1 functor_id.
Qed.
Lemma law3 : BindLaws.associative (bind eps).
Proof.
rewrite /BindLaws.associative => A B C x ab bc.
rewrite /bind.
set T := FComp g f.
(*congr (muM g eps).*)
have -> : (T # (fun x : A => muM eps ((T # bc) (ab x)))) x =
(T # (muM eps (A:=C))) ((T # (T # bc)) ((T # ab) x)).
rewrite functor_o /funcomp.
congr (T # muM eps (A:=C)).
by rewrite functor_o /funcomp.
move: muMA (muM_natural bc).
set M := M f g.
set muM := muM eps.
change (monad_of_adjoint.m f g) with T.
move=> muMA.
rewrite FCompE.
have -> : (T # bc) (muM B ((T # ab) x)) = (T # bc \o muM B) ((T # ab) x) by [].
move=> ->.
rewrite compE.
change (muM C (muM (M C) ((T # (T # bc)) ((T # ab) x)))) with
((muM C \o muM (M C)) ((T # (T # bc)) ((T # ab) x))).
by rewrite muMA.
Qed.
End prop.
End monad_of_adjoint.
Module JoinLaws.
Section join_laws.
Context {M : functor}.
Variables (ret : forall A, A -> M A) (join : transformation_type (FComp M M) M).
Definition ret_naturality := naturalP FId M ret.
Definition join_naturality := naturalP (FComp M M) M join.
Definition left_unit := forall A, @join _ \o @ret _ = id :> (M A -> M A).
Definition right_unit := forall A, @join _ \o M # @ret _ = id :> (M A -> M A).
Definition associativity :=
forall A, @join _ \o M # @join _ = @join _ \o @join _ :> (M (M (M A)) -> M A).
End join_laws.
End JoinLaws.
Section from_join_laws_to_bind_laws.
Variable F : functor.
Variable (ret : forall A, A -> F A) (join : forall A, F (F A) -> F A).
Hypothesis ret_naturality : JoinLaws.ret_naturality ret.
Hypothesis join_naturality : JoinLaws.join_naturality join.
Hypothesis joinretM : JoinLaws.left_unit ret join.
Hypothesis joinMret : JoinLaws.right_unit ret join.
Hypothesis joinA : JoinLaws.associativity join.
Let bind (A B : Type) (m : F A) (f : A -> F B) : F B := join ((F # f) m).
Lemma bindretf_derived : BindLaws.left_neutral bind ret.
Proof.
move=> A B a f; rewrite /bind -(compE (@join _)) -(compE _ (@ret _)) -compA.
by rewrite ret_naturality compA joinretM compidf.
Qed.
Lemma bindmret_derived : BindLaws.right_neutral bind ret.
Proof. by move=> A m; rewrite /bind -(compE (@join _)) joinMret. Qed.
Lemma bindA_derived : BindLaws.associative bind.
Proof.
move=> A B C m f g; rewrite /bind.
rewrite [LHS](_ : _ = ((@join _ \o (F # g \o @join _) \o F # f) m)) //.
rewrite join_naturality (compA (@join C)) -joinA -(compE (@join _)).
transitivity ((@join _ \o F # (@join _ \o (F # g \o f))) m) => //.
by rewrite -2!compA 2!functor_o.
Qed.
End from_join_laws_to_bind_laws.
Module Monad.
Record mixin_of (M : functor) : Type := Mixin {
ret : forall A, A -> M A ;
join : forall A, M (M A) -> M A ;
_ : JoinLaws.ret_naturality ret ;
_ : JoinLaws.join_naturality join ;
_ : JoinLaws.left_unit ret join ;
_ : JoinLaws.right_unit ret join ;
_ : JoinLaws.associativity join
}.
Record class_of (M : Type -> Type) := Class {
base : Functor.class_of M ; mixin : mixin_of (Functor.Pack base) }.
Structure t : Type := Pack { m : Type -> Type ; class : class_of m }.
Definition baseType (M : t) := Functor.Pack (base (class M)).
Module Exports.
Definition Ret (M : t) : forall A, A -> m M A :=
let: Pack _ (Class _ (Mixin ret _ _ _ _ _ _) ) := M return forall A, A -> m M A in ret.
Arguments Ret {M A} : simpl never.
Definition Join (M : t) A : m M (m M A) -> m M A :=
let: Pack _ (Class _ (Mixin _ join _ _ _ _ _)) := M in join A.
Arguments Join {M A} : simpl never.
Notation monad := t.
Coercion baseType : monad >-> functor.
Canonical baseType.
End Exports.
End Monad.
Export Monad.Exports.
Section monad_interface.
Variable M : monad.
Lemma ret_naturality : JoinLaws.ret_naturality (@Ret M).
Proof. by case: M => ? [? []]. Qed.
Lemma join_naturality : JoinLaws.join_naturality (@Join M).
Proof. by case: M => ? [? []]. Qed.
Lemma joinretM : JoinLaws.left_unit (@Ret M) (@Join M).
Proof. by case: M => ? [? []]. Qed.
Lemma joinMret : JoinLaws.right_unit (@Ret M) (@Join M).
Proof. by case: M => ? [? []]. Qed.
Lemma joinA : JoinLaws.associativity (@Join M).
Proof. by case: M => ? [? []]. Qed.
End monad_interface.
Section monad_lemmas.
Variable M : monad.
Definition Bind A B (x : M A) (f : A -> M B) : M B := Join ((M # f) x).
Arguments Bind {A B} : simpl never.
Local Notation "m >>= f" := (Bind m f).
Lemma bindE A B : forall x (f : A -> M B), x >>= f = Join ((M # f) x).
Proof. by []. Qed.
Lemma bindretf : BindLaws.left_neutral (@Bind) (@Ret _).
Proof. apply: bindretf_derived; [exact: ret_naturality | exact: joinretM]. Qed.
Lemma bindmret : BindLaws.right_neutral (@Bind) (@Ret _).
Proof. apply: bindmret_derived; exact: joinMret. Qed.
Lemma bindA : BindLaws.associative (@Bind).
Proof. apply bindA_derived; [exact: join_naturality | exact: joinA]. Qed.
Lemma bindE' (A B:Type) : Bind = fun x (f : A -> M B) => Join ((M # f) x).
Proof. by []. Qed.
Lemma joinretM' A C (f:C->_) : @Join M A \o (@Ret M (M A) \o f) = f.
Proof. by rewrite compA joinretM. Qed.
Lemma joinMret' A C (f:C->_) : @Join M A \o (M # @Ret M A \o f) = f.
Proof. by rewrite compA joinMret. Qed.
Lemma joinA' A C (f:C->_) : @Join M A \o (M # @Join M A \o f) = @Join M A \o (@Join M (M A) \o f).
Proof. by rewrite compA joinA. Qed.
End monad_lemmas.
Arguments Bind {M A B} : simpl never.
Notation "m >>= f" := (Bind m f).
Notation "'do' x <- m ; e" := (m >>= (fun x => e)).
Notation "'do' x : T <- m ; e" := (m >>= (fun x : T => e)) (only parsing).
Notation "m >> f" := (m >>= fun _ => f) (at level 50).
Definition skip M := @Ret M _ tt.
Arguments skip {M} : simpl never.
Ltac bind_ext :=
let congr_ext m := ltac:(congr (Bind m); rewrite funeqE) in
match goal with
| |- @Bind _ _ _ ?m ?f1 = @Bind _ _ _ ?m ?f2 =>
congr_ext m
| |- @Bind _ _ _ ?m1 ?f1 = @Bind _ _ _ ?m2 ?f2 =>
first[ simpl m1; congr_ext m1 | simpl m2; congr_ext m2 ]
end.
(* experimental *)
Tactic Notation "With" tactic(tac) "Open" ssrpatternarg(pat) :=
ssrpattern pat;
let f := fresh "f" in
intro f;
let g := fresh "g" in
let typ := typeof f in
let x := fresh "x" in
evar (g : typ);
rewrite (_ : f = g);
[rewrite {}/f {}/g|
rewrite funeqE => x; rewrite {}/g {}/f; tac]; last first.
Tactic Notation "Open" ssrpatternarg(pat) :=
With (idtac) Open pat.
Tactic Notation "Inf" tactic(tac) :=
(With (tac; reflexivity) Open (X in @Bind _ _ _ _ X = _ )) ||
(With (tac; reflexivity) Open (X in _ = @Bind _ _ _ _ X)).
Tactic Notation "rewrite_" constr(lem) :=
(With (rewrite lem; reflexivity) Open (X in @Bind _ _ _ _ X = _ )) ||
(With (rewrite lem; reflexivity) Open (X in _ = @Bind _ _ _ _ X)).
Lemma bindmskip (M : monad) (m : M unit) : m >> skip = m.
Proof. rewrite -[RHS]bindmret; bind_ext; by case. Qed.
Lemma bindskipf (M : monad) A (m : M A) : skip >> m = m.
Proof. exact: bindretf. Qed.
Fixpoint sequence (M : monad) A (s : seq (M A)) : M (seq A) :=
if s isn't h :: t then Ret [::] else
do v <- h; do vs <- sequence t; Ret (v :: vs).
Lemma sequence_nil (M : monad) A : sequence [::] = Ret [::] :> M (seq A).
Proof. by []. Qed.
Lemma sequence_cons (M : monad) A h (t : seq (M A)) :
sequence (h :: t) = do x <- h ; do vs <- sequence t ; Ret (x :: vs).
Proof. by []. Qed.
Module Monad_of_bind_ret.
Section monad_of_bind_ret.
Variable M : Type -> Type.
Variable bind : forall (A B : Type), M A -> (A -> M B) -> M B.
Variable ret : forall A, A -> M A.
Hypothesis bindretf : BindLaws.left_neutral bind ret.
Hypothesis bindmret : BindLaws.right_neutral bind ret.
Hypothesis bindA : BindLaws.associative bind.
Definition fmap A B (f : A -> B) (m : M A) := bind m (ret (A:=B) \o f).
Lemma fmap_id : FunctorLaws.id fmap.
Proof. by move=> A; rewrite funeqE => m; rewrite /fmap bindmret. Qed.
Lemma fmap_o : FunctorLaws.comp fmap.
Proof.
move=> A B C g h; rewrite funeqE => m.
rewrite /fmap compE bindA; congr bind.
by rewrite funeqE => a; rewrite bindretf.
Qed.
Definition functor_mixin := Functor.Class fmap_id fmap_o.
Let M' := Functor.Pack functor_mixin.
Lemma fmapE A B (f : A -> B) m : (M' # f) m = bind m (ret (A:=B) \o f).
Proof. by []. Qed.
Let ret' : forall A, A -> M' A := ret.
Definition join A (pp : M' (M' A)) := bind pp id.
Let bind_fmap A B C (f : A -> B) (m : M A) (g : B -> M C) :
bind (fmap f m) g = bind m (g \o f).
Proof.
rewrite /fmap bindA; congr bind.
by rewrite funeqE => ?; rewrite bindretf.
Qed.
Lemma ret_naturality : naturalP FId M' ret.
Proof.
move=> A B h; rewrite FIdf funeqE => ?.
by rewrite compE /= /fmap fmapE /= bindretf.
Qed.
Let bindE A B m (f : A -> M' B) : bind m f = join ((M' # f) m).
Proof. by rewrite /join bind_fmap. Qed.
Let fmap_bind A B C (f : A -> B) m (g : C -> M A) :
(fmap f) (bind m g) = bind m (fmap f \o g).
Proof. by rewrite /fmap bindA bindE. Qed.
Lemma join_naturality : naturalP (FComp M' M') M' join.
Proof.
move=> A B h; rewrite funeqE => mma.
by rewrite /Fun 2!compE /fmap [in RHS]/join bind_fmap [in LHS]/join bindA.
Qed.
Lemma joinretM : JoinLaws.left_unit ret' join.
Proof. by rewrite /join => A; rewrite funeqE => ma; rewrite compE bindretf. Qed.
Lemma joinMret : JoinLaws.right_unit ret' join.
Proof.
rewrite /join => A; rewrite funeqE => ma;
by rewrite compE bind_fmap compidf bindmret.
Qed.
Lemma joinA : JoinLaws.associativity join.
Proof.
move=> A; rewrite funeqE => mmma.
by rewrite /join !compE bind_fmap compidf bindA.
Qed.
Definition monad_mixin := Monad.Mixin
ret_naturality join_naturality joinretM joinMret joinA.
End monad_of_bind_ret.
Module Exports.
Definition Monad_of_bind_ret M bind ret a b c :=
Monad.Pack (Monad.Class (@monad_mixin M bind ret a b c)).
End Exports.
End Monad_of_bind_ret.
Export Monad_of_bind_ret.Exports.
(* monadic counterpart of function application: applies a pure function to a monad *)
(* aka liftM in gibbons2011icfp, notation ($) in mu2017 *)
Section fmap_and_join.
Variable M : monad.
Definition fmap A B (f : A -> B) (m : M _) := (M # f) m.
Lemma fmapE A B (f : A -> B) (m : M _) : fmap f m = m >>= (Ret \o f).
Proof. by rewrite bindE functor_o compE -(compE Join) joinMret. Qed.
Lemma bind_fmap A B C (f : A -> B) (m : M A) (g : B -> M C) :
fmap f m >>= g = m >>= (g \o f).
Proof. by rewrite fmapE bindA; rewrite_ bindretf. Qed.
Lemma fmap_if A B (f : A -> B) b (m : M A) a :
fmap f (if b then m else Ret a) = if b then fmap f m else Ret (f a).
Proof. case: ifPn => Hb //; by rewrite fmapE bindretf. Qed.
(* monadic counterpart of function composition:
composes a pure function after a monadic function *)
Definition fcomp A B C (f : A -> B) (g : C -> M A) := locked ((M # f) \o g).
Arguments fcomp : simpl never.
Local Notation "f (o) g" := (fcomp f g).
Lemma fcomp_def A B C (f : A -> B) (g : C -> M A) : f (o) g = (M # f) \o g.
Proof. by rewrite /fcomp; unlock. Qed.
Lemma fcompE A B C (f : A -> B) (g : C -> M A) c : (f (o) g) c = fmap f (g c).
Proof. by rewrite /fcomp; unlock. Qed.
Lemma fmap_comp A B C (f : A -> B) (g : C -> A) (m : M C) :
fmap (f \o g) m = fmap f (fmap g m).
Proof. by rewrite 3!fmapE bindA; rewrite_ bindretf. Qed.
Lemma fcomp_comp A B C D (f : A -> B) (g : C -> A) (m : D -> M C) :
(f \o g) (o) m = f (o) (g (o) m).
Proof. by rewrite 3!fcomp_def functor_o compA. Qed.
Lemma fmap_bind A B C (f : A -> B) m (g : C -> M A) :
fmap f (m >>= g) = m >>= (f (o) g).
Proof.
rewrite fcomp_def fmapE bindA; bind_ext => c; by rewrite compE -/(fmap _ _) fmapE.
Qed.
Lemma skip_fmap A B (f : A -> B) (mb : M B) ma :
mb >> (fmap f ma) = fmap f (mb >> ma).
Proof. by rewrite fmap_bind fcomp_def. Qed.
(*Lemma rev_map A B (f : A -> B) : rev \o map f = map f \o rev.
Proof.
apply functional_extensionality.
by elim=> // h t /= IH; rewrite !rev_cons IH map_rcons.
Qed.*)
Lemma mfoldl_rev (T R : Type) (f : R -> T -> R) (z : R) (s : seq T -> M (seq T)) :
foldl f z (o) (rev (o) s) = foldr (fun x => f^~ x) z (o) s.
Proof.
rewrite funeqE => x; rewrite !fcompE 3!fmapE !bindA.
bind_ext => ?; by rewrite bindretf /= -foldl_rev.
Qed.
Lemma foldl_revE (T R : Type) (f : R -> T -> R) (z : R) :
foldl f z \o rev = foldr (fun x : T => f^~ x) z.
Proof. by rewrite funeqE => s; rewrite -foldl_rev. Qed.
Lemma joinE A (pp : M (M A)) : Join pp = pp >>= id.
Proof. rewrite bindE; congr Join; by rewrite functor_id. Qed.
Lemma join_fmap A B (f : A -> M B) m : Join (fmap f m) = m >>= f.
Proof. by rewrite bindE. Qed.
Definition kleisli A B C (m : B -> M C) (n : A -> M B) : A -> M C :=
Join \o (M # m) \o n.
Local Notation "m >=> n" := (kleisli m n).
Lemma fcomp_kleisli A B C D (f : A -> B) (g : C -> M A) (h : D -> M C) :
f (o) (g >=> h) = (f (o) g) >=> h.
Proof.
rewrite /kleisli 2!fcomp_def 2!(compA (M # f)).
by rewrite join_naturality functor_o compA.
Qed.
Lemma kleisli_fcomp A B C (f : A -> M B) (g : B -> A) (h : C -> M B) :
((f \o g) >=> h) = f >=> (g (o) h).
Proof. by rewrite /kleisli fcomp_def functor_o 2!compA. Qed.
Local Notation "m >=> n" := (kleisli m n).
Lemma bind_kleisli A B C m (f : B -> M C) (g : A -> M B) :
m >>= (f >=> g) = (m >>= g) >>= f.
Proof. by rewrite bindA; bind_ext => a; rewrite /kleisli !compE join_fmap. Qed.
End fmap_and_join.
Notation "f (o) g" := (fcomp f g) : mu_scope.
Arguments fcomp : simpl never.
Notation "m >=> n" := (kleisli m n).
(*
(* monads on Type are strong monads *)
Section strength.
Variable M : monad.
Definition strength A B (xy : (A * M B)%type) : M (A * B)%type :=
let (x,my) := xy in my >>= (fun y => Ret (x,y)).
Lemma strengthE A B (x:A) (my:M B) : strength (x,my) = my >>= (fun y => Ret (x,y)).
Proof. done. Qed.
Lemma strength_unit A : snd = M # snd \o strength (A:=unit) (B:=A).
Proof.
apply functional_extensionality => x.
case: x => i ma.
rewrite compE strengthE.
rewrite -fmapE fmap_bind fcomp_def.
rewrite bindE.
have ->: Join ((M # (M # snd \o (fun y : A => Ret (i, y)))) ma) =
((M # snd \o Join) \o M # (fun y : A => Ret (i, y))) ma
by rewrite functor_o join_naturality.
rewrite functor_o.
have ->: ((M # snd \o Join) \o (M # Ret \o M # pair i)) ma =
(M # snd \o (Join \o M # Ret) \o M # pair i) ma by done.
rewrite joinMret compfid.
rewrite -functor_o.
have ->: snd \o pair i = id by done.
by rewrite functor_id.
Qed.
End strength.
*)
Definition mpair {M : monad} {A} (xy : (M A * M A)%type) : M (A * A)%type :=
let (mx, my) := xy in
mx >>= (fun x => my >>= fun y => Ret (x, y)).
Lemma mpairE (M : monad) A (mx my : M A) :
mpair (mx, my) = mx >>= (fun x => my >>= fun y => Ret (x, y)).
Proof. by []. Qed.
Lemma naturality_mpair (M : monad) A B (f : A -> B) (g : A -> M A):
(M # f^`2) \o (mpair \o g^`2) = mpair \o ((M # f) \o g)^`2.
Proof.
rewrite funeqE => -[a0 a1].
rewrite compE -/(fmap _ _) fmap_bind.
rewrite compE mpairE compE -/(fmap _ _) bind_fmap; bind_ext => a2.
rewrite fcompE fmap_bind 2!compE -/(fmap _ _) bind_fmap; bind_ext => a3.
by rewrite fcompE -(compE (fmap f^`2)) ret_naturality.
Qed.
(*Local Notation "[ \o f , .. , g , h ]" := (f \o .. (g \o h) ..)
(at level 0) (*, format "[ \o '[' f , '/' .. , '/' g , '/' h ']' ]"
).*) : test_scope.
Local Open Scope test_scope.
Lemma naturality_mpair' (M : monad) A B (f : A -> B) (g : A -> M A):
(M # f^`2) \o (mpair \o g^`2) = mpair \o ((M # f) \o g)^`2.
Proof.
rewrite funeqE => -[a0 a1].
change ((M # f^`2 \o (mpair \o g^`2)) (a0, a1)) with
((M # f^`2) (mpair (g a0, g a1))).
change ((mpair \o (M # f \o g)^`2) (a0, a1)) with
(mpair ((M # f \o g) a0,(M # f \o g) a1)).
rewrite !mpairE.
rewrite !bindE.
evar (T : Type);evar (RHS : A -> T).
have ->: (fun x : A => do y <- g a1; Ret (x, y)) = RHS.
rewrite funeqE => x; rewrite bindE.
rewrite functor_o.
change (Join ([\o M # Ret,M # pair x] (g a1))) with
([\o Join,M # Ret,M # pair x] (g a1)).
rewrite joinMret'.
exact: erefl.
rewrite /RHS {RHS}; rewrite {T}.
change ((M # f^`2) (Join ((M # (fun x : A => (M # pair x) (g a1))) (g a0)))) with
((M # f^`2 \o Join) ((M # (fun x : A => (M # pair x) (g a1))) (g a0))).
rewrite join_naturality.
evar (T : Type);evar (RHS : T).
have->:(M # (fun x : B => do y <- (M # f \o g) a1; Ret (x, y))) = RHS.
- rewrite functor_o.
rewrite bindE'.
rewrite functor_o.
exact: erefl.
rewrite/RHS{RHS};rewrite{T}.
change
(
Join
(((M # Join \o M # (Fun M (B:=M (B * B)%type))^~ ((M # f \o g) a1)) \o
M # (fun x y : B => Ret (x, y))) ((M # f \o g) a0))
) with
(
(
[ \o Join ,
(M # Join) ,
(M # (Fun M (B:=M (B * B)%type))^~ ((M # f \o g) a1)) ,
(M # (fun x y : B => Ret (x, y))) ,
(M # f \o g) ]
) a0)
.
rewrite joinA'.
(*
rewrite fmap_bind. compE [in RHS]/= bind_fmap; bind_ext => a2.
rewrite fcompE fmap_bind compE bind_fmap; bind_ext => a3.
by rewrite fcompE -(compE (fmap M # f^`2)) fmap_ret.
Qed.
*)
Abort.
Local Close Scope test_scope.
*)
Section rep.
Variable M : monad.
Fixpoint rep (n : nat) (mx : M unit) : M unit :=
if n is n.+1 then mx >> rep n mx else skip.
Lemma repS mx n : rep n.+1 mx = rep n mx >> mx.
Proof.
elim: n => /= [|n IH]; first by rewrite bindmskip bindskipf.
by rewrite bindA IH.
Qed.
Lemma rep1 mx : rep 1 mx = mx. Proof. by rewrite repS bindskipf. Qed.
Lemma rep_addn m n mx : rep (m + n) mx = rep m mx >> rep n mx.
Proof.
elim: m n => [|m IH /=] n; by
[rewrite bindskipf add0n | rewrite -addnE IH bindA].
Qed.
End rep.
Section MonadCount.
Variable M : monad.
Variable tick : M unit.
Fixpoint hanoi n : M unit :=
if n is n.+1 then hanoi n >> tick >> hanoi n else skip.
Lemma hanoi_rep n : hanoi n = rep (2 ^ n).-1 tick.
Proof.
elim: n => // n IH /=.
rewrite IH -repS prednK ?expn_gt0 // -rep_addn.
by rewrite -subn1 addnBA ?expn_gt0 // addnn -muln2 -expnSr subn1.
Qed.
End MonadCount.
Module MonadFail.
Record mixin_of (M : monad) : Type := Mixin {
fail : forall A, M A ;
(* exceptions are left-zeros of sequential composition *)
_ : BindLaws.left_zero (@Bind M) fail (* fail A >>= f = fail B *)
}.
Record class_of (m : Type -> Type) := Class {
base : Monad.class_of m ; mixin : mixin_of (Monad.Pack base) }.
Structure t := Pack { m : Type -> Type ; class : class_of m }.
Definition baseType (M : t) := Monad.Pack (base (class M)).
Module Exports.
Definition Fail (M : t) : forall A, m M A :=
let: Pack _ (Class _ (Mixin x _)) := M return forall A, m M A in x.
Arguments Fail {M A} : simpl never.
Notation failMonad := t.
Coercion baseType : failMonad >-> monad.
Canonical baseType.
End Exports.
End MonadFail.
Export MonadFail.Exports.
Section fail_lemmas.
Variable (M : failMonad).
Lemma bindfailf : BindLaws.left_zero (@Bind M) (@Fail _).
Proof. by case : M => m [? []]. Qed.
End fail_lemmas.
Lemma fmap_fail {A B} (M : failMonad) (f : A -> B) : fmap f Fail = Fail :> M _.
Proof. by rewrite fmapE bindfailf. Qed.
Section guard_assert.
Variable M : failMonad.
Definition guard (b : bool) : M unit := if b then skip else Fail.
(* guard distributes over conjunction *)
Lemma guard_and a b : guard (a && b) = guard a >> guard b.
Proof. move: a b => -[b|b]; by [rewrite bindskipf| rewrite bindfailf]. Qed.
Definition assert {A} (p : pred A) (a : A) : M A :=