Support ns-aliases and ns-refers

CHANGELOG.md

@@ -5,6 +5,7 @@ All notable changes to this project will be documented in this file. This change
 ### Added
 - Add `planck.core/with-in-str` ([#873](https://github.com/planck-repl/planck/issues/873))
 - Document `planck.io/resource` ([#487](https://github.com/planck-repl/planck/issues/487))`
+- Support `ns-aliases` and `ns-refers` ([#505](https://github.com/planck-repl/planck/issues/505))
 
 ### Fixed
 - Execution error instead of syntax for `08` ([#857](https://github.com/planck-repl/planck/issues/857))

planck-cljs/src/planck/core.cljs

@@ -433,6 +433,24 @@
           :name symbol?
           :val (s/? any?)))
 
+(defn ns-aliases
+  "Returns a map of the aliases for the namespace."
+  [ns]
+  (#'repl/ns-aliases ns))
+
+(s/fdef ns-aliases
+  :args (s/cat :ns (s/or :sym symbol? :ns #(instance? Namespace %)))
+  :ret (s/map-of simple-symbol? #(instance? Namespace %)))
+
+(defn ns-refers
+  "Returns a map of the refer mappings for the namespace."
+  [ns]
+  (#'repl/ns-refers ns))
+
+(s/fdef ns-refers
+  :args (s/cat :ns (s/or :sym symbol? :ns #(instance? Namespace %)))
+  :ret (s/map-of simple-symbol? var?))
+
 (defn- transfer-ns
   [state ns]
   (-> state

planck-cljs/src/planck/repl.cljs

@@ -2202,6 +2202,27 @@
    (when-let [the-ns (find-ns (cond-> ns (instance? Namespace ns) ns-name))]
      (eval `(def ~name (quote ~val)) (ns-name the-ns)))))
 
+(defn- ns-aliases
+  [ns]
+  (if-some [the-ns (find-ns (cond-> ns (instance? Namespace ns) ns-name))]
+    (->> (get-in @st [::ana/namespaces (ns-name the-ns) :requires])
+      (keep (fn [[k v]]
+              (when (not= k v)
+                [k (find-ns v)])))
+      (into {}))
+    (throw (ex-info (str "No namespace " ns " found.") {}))))
+
+(defn- ns-refers
+  [ns]
+  (if-some [the-ns (find-ns (cond-> ns (instance? Namespace ns) ns-name))]
+    (merge
+      (apply dissoc (ns-publics 'cljs.core)
+        (get-in @st [::ana/namespaces (ns-name the-ns) :excludes]))
+      (->> (get-in @st [::ana/namespaces (ns-name the-ns) :uses])
+        (map (fn [[k v]] [k (ns-resolve v k)]))
+        (into {})))
+    (throw (ex-info (str "No namespace " ns " found.") {}))))
+
 (defn- ^:export wrap-color-err
   []
   (let [orig-print-err-fn js/PLANCK_PRINT_ERR_FN]

planck-cljs/test/foo/core.cljs

@@ -1,5 +1,9 @@
-(ns foo.core)
+(ns foo.core
+  (:refer-clojure :exclude [map])
+  (:require
+   [clojure.string :as string]
+   [clojure.set :as set :refer [union intersection]]))
 
-;; A test namespace for testing interns, ns-resolve
+;; A test namespace for testing interns, ns-resolve, ns-aliases, ns-refers
 
 (def h 3)

planck-cljs/test/planck/core_test.cljs

@@ -69,6 +69,18 @@
   (is (= 'bar @(planck.core/ns-resolve 'foo.core 'd)))
   (is (= '[bar] @(planck.core/ns-resolve 'foo.core 'e))))
 
+(deftest test-ns-aliases
+  (is (= '{string clojure.string, set clojure.set}
+        (into {} (map (fn [[k v]] [k (ns-name v)])) (planck.core/ns-aliases 'foo.core))))
+  (is (thrown? js/Error (planck.core/ns-aliases 'unknown.namespace))))
+
+(deftest test-ns-refers
+  (let [refers (planck.core/ns-refers 'foo.core)]
+    (is (= ['union #'clojure.set/union] (find refers 'union)))
+    (is (= ['intersection #'clojure.set/intersection] (find refers 'intersection)))
+    (is (= ['reduce #'cljs.core/reduce] (find refers 'reduce)))
+    (is (not (contains? refers 'map)))))
+
 (defn spit-slurp [file-name content]
   (planck.core/spit file-name content)
   (planck.core/slurp file-name))

site/src/planck-core.md

@@ -26,6 +26,8 @@ _Vars_
 [line-seq](#line-seq)<br/>
 [load-reader](#load-reader)<br/>
 [load-string](#load-string)<br/>
+[ns-aliases](#ns-aliases)<br/>
+[ns-refers](#ns-refers)<br/>
 [ns-resolve](#ns-resolve)<br/>
 [read](#read)<br/>
 [read-line](#read-line)<br/>
@@ -209,6 +211,24 @@ Spec<br/>
  _args_: `(cat :s string?)`<br/>
  _ret_: `any?`
 
+### <a name="ns-aliases"></a>ns-aliases
+`([ns])`
+
+Returns a map of the aliases for the namespace.
+
+Spec<br/>
+ _args_: `(cat :ns (or :sym symbol? :ns #(instance? Namespace %)))`<br/>
+ _ret_: `(map-of simple-symbol? (instance? Namespace %))`<br/>
+
+### <a name="ns-refers"></a>ns-refers
+`([ns])`
+
+Returns a map of the refer mappings for the namespace.
+
+Spec<br/>
+ _args_: `(cat :ns (or :sym symbol? :ns #(instance? Namespace %)))`<br/>
+ _ret_: `(map-of simple-symbol? var?)`<br/>
+
 ### <a name="ns-resolve"></a>ns-resolve
 `([ns sym])`