Convert the project to gradle kotlin dsl

.gitignore

@@ -114,4 +114,6 @@ run/
 /example-plugin/build/
 /api/build/
 
-
+# Gradle
+**/build/**
+**/.gradle/**

build.gradle.kts

@@ -0,0 +1,80 @@
+import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
+import org.jetbrains.kotlin.gradle.dsl.JvmTarget
+import org.jetbrains.kotlin.gradle.dsl.KotlinJvmProjectExtension
+
+plugins {
+    id("org.jetbrains.kotlin.jvm") version "1.9.22"
+    id("com.github.johnrengelman.shadow") version "8.1.1"
+    id("maven-publish")
+}
+
+group = "org.holoeasy"
+version = "3.1.1"
+
+apply(from = "$rootDir/gradle/publish.gradle")
+
+repositories {
+    mavenCentral()
+}
+
+subprojects {
+    apply(plugin = "kotlin")
+
+    repositories {
+        mavenCentral()
+    }
+
+    dependencies {
+        compileOnly("org.jetbrains:annotations:24.0.1")
+    }
+
+    configure<JavaPluginExtension> {
+        sourceCompatibility = JavaVersion.VERSION_1_8
+        targetCompatibility = JavaVersion.VERSION_1_8
+        sourceSets {
+            getByName("main").java.srcDirs("src/main/java")
+            getByName("test").java.srcDirs("src/test/java")
+        }
+    }
+
+    configure<KotlinJvmProjectExtension> {
+        sourceSets {
+            getByName("main").kotlin.srcDirs("src/main/kotlin")
+            getByName("test").kotlin.srcDirs("src/test/kotlin")
+        }
+
+        compilerOptions {
+            jvmTarget = JvmTarget.JVM_1_8
+        }
+    }
+}
+
+dependencies {
+    implementation(project(":core"))
+}
+
+tasks {
+    withType<ShadowJar> {
+        archiveClassifier.set("")
+        relocate("kotlin.", "org.holoeasy.kotlin.")
+        relocate("org.intellij.lang.annotations", "org.holoeasy.annotations")
+        relocate("org.jetbrains.annotations", "org.holoeasy.annotations")
+    }
+
+    named("build") {
+        dependsOn("shadowJar")
+    }
+
+    named("publishToMavenLocal") {
+        dependsOn("jar", "shadowJar")
+    }
+
+    named("publishShadowPublicationToMavenLocal") {
+        dependsOn("jar", "shadowJar")
+    }
+
+    named("publish") {
+        dependsOn("shadowJar")
+    }
+
+}

core/build.gradle.kts

@@ -0,0 +1,31 @@
+plugins {
+    id("org.jetbrains.kotlin.jvm") version "1.9.22"
+}
+
+group = "org.holoeasy"
+version = "3.1.1"
+
+repositories {
+    mavenCentral()
+    maven(url = uri("https://repo.dmulloy2.net/repository/public/"))
+    maven(url = uri("https://hub.spigotmc.org/nexus/content/repositories/snapshots/"))
+}
+
+dependencies {
+    implementation("org.jetbrains.kotlin:kotlin-stdlib:1.9.22")
+    compileOnly("org.spigotmc:spigot-api:1.16.5-R0.1-SNAPSHOT")
+    compileOnly("com.comphenix.protocol:ProtocolLib:5.1.0")
+}
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_1_8
+    targetCompatibility = JavaVersion.VERSION_1_8
+}
+
+tasks.jar {
+    manifest {
+        attributes(
+            "Main-Class" to "MainKt"
+        )
+    }
+}

core/src/main/kotlin/org/holoeasy/builder/HologramBuilder.java → core/src/main/java/org/holoeasy/builder/HologramBuilder.java

@@ -8,7 +8,6 @@
 import org.holoeasy.hologram.Hologram;
 import org.holoeasy.line.ILine;
 import org.holoeasy.line.ITextLine;
-import org.holoeasy.pool.IHologramPool;
 import org.holoeasy.reactive.MutableState;
 import org.jetbrains.annotations.NotNull;
 

core/src/main/kotlin/org/holoeasy/builder/Service.kt

@@ -6,7 +6,6 @@ import org.holoeasy.builder.interfaces.HologramConfigGroup
 import org.holoeasy.hologram.TextBlockStandardLoader
 import org.holoeasy.line.*
 import org.holoeasy.reactive.MutableState
-import kotlin.math.min
 
 object Service {
 

example/build.gradle.kts

@@ -0,0 +1,24 @@
+plugins {
+    id("java")
+}
+
+repositories {
+    mavenCentral()
+    maven(url = uri("https://repo.dmulloy2.net/repository/public/"))
+    maven(url = uri("https://jitpack.io"))
+    maven(url = uri("https://hub.spigotmc.org/nexus/content/repositories/snapshots/"))
+}
+
+
+group = "org.holoeasy"
+version = "1.0-SNAPSHOT"
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_1_8
+    targetCompatibility = JavaVersion.VERSION_1_8
+}
+
+dependencies {
+    compileOnly("org.spigotmc:spigot-api:1.16.5-R0.1-SNAPSHOT")
+    compileOnly("com.github.GeorgeV220:Hologram-Lib:33cba59492")
+}