PKGBUILD for Arch

pkgname=aegisub-wangqr-git
pkgver=3.2.2.r530.809b789b6
pkgrel=1
pkgdesc='A general-purpose subtitle editor with ASS/SSA support (wangqr fork)'
arch=(x86_64)
url=http://www.aegisub.org
license=(
  GPL
  BSD
)
depends=(
  alsa-lib
  boost-libs
  fftw
  fontconfig
  hunspell
  icu
  libass.so
  libffms2.so
  libgl
  libpulse
  uchardet
  wxgtk3
  zlib
  avisynthplus
)
makedepends=(
  autoconf-archive
  boost
  git
  intltool
  lua
  mesa
)
provides=(aegisub)
conflicts=(aegisub)
source=(
  aegisub::git+https://github.com/wangqr/Aegisub.git
  git+https://github.com/Aegisub/assdraw.git
)
sha256sums=('SKIP' 'SKIP')

pkgver() {
  cd aegisub

  tag='v3.2.2'

  echo "${tag#v}.r$(git rev-list --count ${tag}..HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake -DwxWidgets_CONFIG_EXECUTABLE=/usr/bin/wx-config-gtk3 -DCMAKE_INSTALL_PREFIX=/usr "../aegisub"
  make
}

package() {
  cd build

  make DESTDIR="${pkgdir}" install
  install -Dm 644 "../aegisub/LICENCE" "${pkgdir}"/usr/share/licenses/aegisub-git/license
}

This uses CMake build and will NOT install the translations properly. If you just want to try this fork, use the aegisub-git in AUR instead, and simply change the source to git+https://github.com/wangqr/Aegisub.git.

Generally, I don't submit my own repository to AUR. If you have time maintaining the PKGBUILD, feel free to submit it to AUR.