Overhaul activateAddons

addons/common/CfgEventHandlers.hpp

@@ -1,4 +1,10 @@
 
+class Extended_PreStart_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_FILE(XEH_preStart));
+    };
+};
+
 class Extended_PreInit_EventHandlers {
     class ADDON {
         init = QUOTE(call COMPILE_FILE(XEH_preInit));

addons/common/XEH_preInit.sqf

@@ -47,10 +47,8 @@ call COMPILE_FILE(init_perFrameHandler);
 call COMPILE_FILE(init_delayLess);
 
 // Due to activateAddons being overwritten by eachother (only the last executed command will be active), we apply this bandaid
-private _addons = ("true" configClasses (configFile >> "CfgPatches")) apply {configName _x};
-
-activateAddons _addons;
-GVAR(addons) = _addons;
+activateAddons (uiNamespace getVariable [QGVAR(addonsSparse), []]);
+GVAR(addons) = uiNamespace getVariable [QGVAR(addons), []];
 
 // BWC
 #include "backwards_comp.sqf"

addons/common/XEH_preStart.sqf

@@ -0,0 +1,24 @@
+#include "script_component.hpp"
+
+//See usage in XEH_preInit
+private _cfgPatches = configFile >> "CfgPatches";
+private _addonsFull = ("true" configClasses _cfgPatches) apply {configName _x};
+
+//Filter out addons that don't have any units defined as we don't need to activate these
+private _addonsSparse = _addonsFull select {
+    !(getArray(_cfgPatches >> _x >> "units") isEqualTo [])
+};
+
+//Filter out addons defined in CfgAddons as they are always activated
+private _cfgAddonsCategories = "true" configClasses (configFile >> "CfgAddons");
+
+private _cfgAddonsMods = [];
+
+{
+    _cfgAddonsMods append (getArray (_x >> "list"));
+} forEach _cfgAddonsCategories;
+
+_addonsSparse = _addonsSparse - _cfgAddonsMods;
+
+uiNamespace setVariable [QGVAR(addons), _addonsFull];
+uiNamespace setVariable [QGVAR(addonsSparse), _addonsSparse];