Add basic functions for change of basis in 3D

addons/vectors/CfgFunctions.hpp

@@ -2,6 +2,8 @@
 class CfgFunctions {
     class CBA {
         class Vectors {
+            PATHTO_FNC(matrixProduct3D);
+            PATHTO_FNC(matrixTranspose);
             PATHTO_FNC(polar2vect);
             PATHTO_FNC(scaleVect);
             PATHTO_FNC(scaleVectTo);
@@ -16,6 +18,7 @@ class CfgFunctions {
             PATHTO_FNC(vectElev);
             PATHTO_FNC(vectMagn);
             PATHTO_FNC(vectMagn2D);
+            PATHTO_FNC(vectMap3D);
             PATHTO_FNC(vectRotate2D);
             PATHTO_FNC(vectRotate3D);
             PATHTO_FNC(vectSubtract);

addons/vectors/fnc_matrixProduct3D.sqf

@@ -0,0 +1,43 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_matrixProduct3D
+
+Description:
+   Returns the resulting matrix from the matrix-matrix product.
+
+   Only accepts a 3x3 matrices.
+
+Parameters:
+    _matrixA       - first 3x3 matrix. <ARRAY>
+    _matrixB       - second 3x3 matrix. <ARRAY>
+
+Returns:
+     _returnMatrix - 3x3 matrix returned after matrix multiplication <ARRAY>
+
+Examples:
+    (begin example)
+    // point reflection at origin [0,0,0] for every vector in matrix B
+    [[[-1,0,0],[0,-1,0],[0,0,-1]], [[1,2,3], [3,1,2], [2,3,1]]] call CBA_fnc_matrixProduct3D;
+    (end)
+
+Author:
+    Kex
+---------------------------------------------------------------------------- */
+
+#include "script_component.hpp"
+
+params [["_matrixA", [], [[]], 3], ["_matrixB", [], [[]], 3]];
+
+_matrixB = [_matrixB] call CBA_fnc_matrixTranspose;
+
+private _returnMatrix = [];
+for "_i" from 0 to (count _matrixA -1) do
+{
+    private _returnRow = [];
+    private _rowA = _matrixA select _i;
+    for "_j" from 0 to (count _matrixB -1) do
+    {
+        _returnRow pushBack (_rowA vectorDotProduct ( _matrixB select _j));
+    };
+    _returnMatrix pushBack _returnRow;
+};
+_returnMatrix;

addons/vectors/fnc_matrixTranspose.sqf

@@ -0,0 +1,44 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_matrixTranspose
+
+Description:
+   Returns the transposed matrix.
+
+   Accepts any mxn matrix.
+
+Parameters:
+    _matrix        - mxn matrix to transpose. <ARRAY>
+
+Returns:
+     _returnMatrix - nxm matrix <ARRAY>
+
+Examples:
+    (begin example)
+    // returns the transposed matrix [[1,3,2], [2,1,3], [3,2,1]]
+    [[[1,2,3], [3,1,2], [2,3,1]]] call CBA_fnc_matrixTranspose;
+    (end)
+
+Author:
+    Kyle Kotowick, Kex
+---------------------------------------------------------------------------- */
+
+#include "script_component.hpp"
+
+params [["_matrix", [], [[]]]];
+
+private _m = count _matrix;
+private _n = count (_matrix select 0);
+
+private _returnMatrix = [];
+
+for "_j" from 0 to (_n - 1) do
+{
+    private _returnRow = [];
+    for "_i" from 0 to (_m - 1) do
+    {
+        _returnRow pushBack ((_matrix select _i) select _j);
+    };
+    _returnMatrix pushBack _returnRow;
+};
+
+_returnMatrix;

addons/vectors/fnc_vectMap3D.sqf

@@ -0,0 +1,29 @@
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_vectMap3D
+
+Description:
+   Returns the resulting vector of the product matrix-vector product.
+
+   Only accepts a 3x3 matrices and 3D vector.
+
+Parameters:
+    _matrix       - 3x3 matrix, which serves as a map. <ARRAY>
+    _vector       - 3D vector that is mapped. <ARRAY>
+
+Returns:
+     _returnVector - 3D vector returned after matrix multiplication <ARRAY>
+
+Examples:
+    (begin example)
+    // point reflection at origin [0,0,0]
+    [[[-1,0,0],[0,-1,0],[0,0,-1]], [1,2,3]] call CBA_fnc_vectMap3D;
+    (end)
+
+Author:
+    Kex
+---------------------------------------------------------------------------- */
+
+#include "script_component.hpp"
+
+params[["_matrix", [], [[]], 3], ["_vector", [], [[]], 3]];
+_matrix apply {_x vectorDotProduct _vector};